I_Standardproject

@AbapCatalog.sqlViewName: 'ISTANDARDPROJECT'
@VDM.viewType: #BASIC
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #BLOCKED_DATA_EXCLUDED
//@Analytics: { dataCategory: #DIMENSION, dataExtraction.enabled: true }

@EndUserText.label: 'Standard Project Version'
@ObjectModel.representativeKey: 'Project'
@ObjectModel.usageType.serviceQuality: #D
@ObjectModel.usageType.sizeCategory: #L
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.usageType.dataClass: #MASTER
//@VDM.lifecycle.contract.type:  #SAP_INTERNAL_API

//Deprecated - Do not use this view

@VDM.lifecycle : {
        status:  #DEPRECATED
   }

define view I_Standardproject
  as select from    projs
    left outer join cnldst_shorttx on  projs.objnr             = cnldst_shorttx.objnr
                                   and cnldst_shorttx.language = $session.system_language
  association [1..1] to I_ControllingArea          as _ControllingArea        on  $projection.ControllingArea = _ControllingArea.ControllingArea
  association [1..1] to I_CompanyCode              as _CompanyCode            on  $projection.CompanyCode = _CompanyCode.CompanyCode
  association [1..*] to I_CostCenter               as _CostCenter             on  $projection.CostCenter      = _CostCenter.CostCenter
                                                                              and $projection.ControllingArea = _CostCenter.ControllingArea
  association [1..*] to I_Standardwbselement       as _WBSElement             on  $projection.ProjectInternalID = _WBSElement.ProjectInternalID
  association [1..1] to I_BusinessArea             as _BusinessArea           on  $projection.BusinessArea = _BusinessArea.BusinessArea
  association [1..1] to I_Plant                    as _Plant                  on  $projection.Plant = _Plant.Plant
  association [1..1] to I_Projectprofilecode       as _ProjectProfileCode     on  $projection.ProjectProfileCode = _ProjectProfileCode.ProjectProfileCode
  association [1..1] to I_ControllingObjectClass   as _ControllingObjectClass on  $projection.ControllingObjectClass = _ControllingObjectClass.ControllingObjectClass
  //association [0..*] to I_Projecttext            as _ProjLangBsdDescription on  $projection.ProjectObject = _ProjLangBsdDescription.ProjectObject

  // DPP Changes

  // Person in Responsible for Project

  association [0..1] to I_ProjectResponsiblePerson as _ResponsiblePerson      on  $projection.ResponsiblePerson = _ResponsiblePerson.ResponsiblePerson
  // Project Applicant

  association [0..1] to I_ProjectApplicant         as _ProjectApplicant       on  $projection.ApplicantCode = _ProjectApplicant.ApplicantCode
{
      @ObjectModel.text.element: 'ProjectDescription'
  key cast ( projs.pspid as projk_bi )                                                                             as Project,
      projs.pspid_edit                                                                                             as ProjectWithCodingMask,
      cast ( projs.pspnr as ps_s4_ispsp )                                                                             as ProjectInternalID,

      @Semantics.text: true
      cast ( projs.post1 as ppe_proj_name )                                                                        as ProjectDescription,
      //@ObjectModel.text.association:'_ProjLangBsdDescription'

      projs.objnr                                                                                                  as ProjectObject,
      cast (projs.ernam as ernam )                                                                                 as CreatedByUser,
      cast (projs.erdat as erdat)                                                                                  as CreationDate,
      cast ( projs.aenam as aenam )                                                                                as LastChangedByUser,
      cast ( projs.aedat as aedat )                                                                                as LastChangeDate,

      @UI: {
      identification: {position: 10, importance: #HIGH},
      lineItem: {position: 10, importance: #HIGH}
      }
      @ObjectModel.text.element: 'ResponsiblePersonName'
      cast ( projs.vernr as ps_s4_vernr )                                                                          as ResponsiblePerson,
      @Semantics.text: true
      @UI: {
      identification: {position: 10, importance: #HIGH},
      lineItem: {position: 10, importance: #HIGH}
      }
      cast ( projs.verna as ps_s4_verna )                                                                          as ResponsiblePersonName,
      @ObjectModel.text.element: 'ApplicantCode'
      cast ( projs.astnr as ps_s4_astnr )                                                                          as ApplicantCode,
      @Semantics.text: true
      @UI: {
      identification: {position: 10, importance: #HIGH},
      lineItem: {position: 10, importance: #HIGH}
      }
      projs.astna                                                                                                  as ApplicantName,
      @ObjectModel.foreignKey.association: '_CompanyCode'
      cast ( projs.vbukr as ps_vbukr )                                                                             as CompanyCode,
      @ObjectModel.foreignKey.association: '_BusinessArea'
      cast ( projs.vgsbr as ps_vgsbr )                                                                             as BusinessArea,
      @ObjectModel.foreignKey.association: '_ControllingArea'
      cast ( projs.vkokr as ps_vkokr )                                                                             as ControllingArea,
      projs.prctr                                                                                                  as ProfitCenter,
      cast ( projs.pwhie as ps_pwhie )                                                                             as Currency,
      projs.zuord                                                                                                  as NetworkAssignmentType,
      projs.trmeq                                                                                                  as WBSElmntDatesIsDetailed,
      @Semantics.calendar.dayOfMonth: true
      cast ( projs.plfaz as ps_plfaz )                                                                             as PlannedStartDate,
      @Semantics.calendar.dayOfMonth: true
      cast ( projs.plsez as ps_plsez )                                                                             as PlannedEndDate,
      @ObjectModel.foreignKey.association: '_Plant'
      projs.werks                                                                                                  as Plant,
      cast ( projs.kalid as appca )                                                                                as FactoryCalendar,
      projs.nzanz                                                                                                  as NetworkHdrIsVisibleToUser,
      projs.vprof                                                                                                  as NetworkProfile,
      projs.profl                                                                                                  as ProjectProfileCode,
      projs.bprof                                                                                                  as BudgetProfile,
      projs.txtsp                                                                                                  as Language,
      @ObjectModel.foreignKey.association: '_CostCenter'
      @UI: {
      identification: {position: 10, importance: #HIGH},
      lineItem: {position: 10, importance: #HIGH}
      }
      cast ( projs.kostl as kostl )                                                                                as CostCenter,
      projs.ktrg                                                                                                   as CostObject,
      @Semantics.calendar.dayOfMonth: true
      projs.aedte                                                                                                  as BasicDatesLastScheduledDate,
      @Semantics.calendar.dayOfMonth: true
      cast ( projs.aedtp as ps_aedtp )                                                                             as FcstdDatesLastScheduledDate,
      cast ( projs.besta as psb_stock )                                                                            as ProjectHasOwnStock,
      cast ( projs.scope as ps_s4_scope_cv )                                                                       as ControllingObjectClass,
      projs.xstat                                                                                                  as WBSIsStatisticalWBSElement,
      cast ( projs.txjcd as wb2_txjcd_busvol )                                                                     as TaxJurisdiction,
      cast ( projs.zschm as ps_zschm )                                                                             as ProjInterestCalcProfile,
      projs.imprf                                                                                                  as InvestmentProfile,
      projs.fmprf                                                                                                  as PaymentPlanProfile,
      projs.abgsl                                                                                                  as ResultAnalysisInternalID,
      projs.pprof                                                                                                  as PlanningProfile,
      projs.plint                                                                                                  as WBSIsMarkedForIntegratedPlng,
      cast ( projs.loevm as ps_s4_loevm )                                                                          as IsMarkedForDeletion,
      projs.kzbws                                                                                                  as InventorySpecialStockValnType,
      projs.grtop                                                                                                  as WBSIsMarkedForAutomReqmtGrpg,
      cast ( projs.stort as ps_stort )                                                                             as WorkCenterLocation,
      cast ( projs.func_area as fkber )                                                                            as FunctionalArea,
      projs.vkorg                                                                                                  as SalesOrganization,
      projs.vtweg                                                                                                  as DistributionChannel,
      projs.spart                                                                                                  as Division,
      projs.dppprof                                                                                                as DynItemProcessorPrfl,
      projs.vname                                                                                                  as JointVenture,
      projs.recid                                                                                                  as JointVentureCostRecoveryCode,
      projs.etype                                                                                                  as JointVentureEquityType,
      projs.otype                                                                                                  as JointVentureObjectType,
      projs.jibcl                                                                                                  as JointVentureClass,
      projs.jibsa                                                                                                  as JointVentureSubClass,

      //cnldst_shorttx.shorttext as ProjLangBasedDesc,

      _ControllingArea,
      _CompanyCode,
      _BusinessArea,
      _CostCenter,
      _Plant,
      _WBSElement,
      _ProjectProfileCode,
      _ControllingObjectClass,
      @UI.hidden: true
      @Consumption.hidden: true
      _ResponsiblePerson,
      @UI.hidden: true
      @Consumption.hidden: true
      _ProjectApplicant
      //_ProjLangBsdDescription


}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"CNLDST_SHORTTX",
"PROJS"
],
"ASSOCIATED":
[
"I_BUSINESSAREA",
"I_COMPANYCODE",
"I_CONTROLLINGAREA",
"I_CONTROLLINGOBJECTCLASS",
"I_COSTCENTER",
"I_PLANT",
"I_PROJECTAPPLICANT",
"I_PROJECTPROFILECODE",
"I_PROJECTRESPONSIBLEPERSON",
"I_STANDARDWBSELEMENT"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/