I_StandardWBSElement_2

@AbapCatalog.sqlViewName: 'ISTDWBSELE2'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey:true

@AccessControl.personalData.blocking: #BLOCKED_DATA_EXCLUDED
@AccessControl.authorizationCheck: #MANDATORY

@VDM.viewType: #BASIC
@VDM.lifecycle.contract.type: #PUBLIC_LOCAL_API

@ObjectModel.representativeKey: 'StandardWBSElementInternalID'
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory : #L
@ObjectModel.usageType.dataClass: #MASTER
@ObjectModel.supportedCapabilities: [ #SQL_DATA_SOURCE, #CDS_MODELING_DATA_SOURCE, #CDS_MODELING_ASSOCIATION_TARGET, #ANALYTICAL_DIMENSION, #EXTRACTION_DATA_SOURCE ]

@ClientHandling.algorithm: #SESSION_VARIABLE
@EndUserText.label: 'Standard WBS Element Details'
@Metadata.allowExtensions: true

@Metadata.ignorePropagatedAnnotations: true

@Analytics: {
      dataCategory: #DIMENSION,
      internalName: #LOCAL,
      dataExtraction : {
        enabled: true,
        delta:{
         changeDataCapture:{
           mapping: [
                      { table: 'PRPSS',
                        role: #MAIN,
                        viewElement: ['StandardWBSElementInternalID'],
                        tableElement: ['PSPNR']
                      }          
                    ]
              } 
           }
       }
}

define view I_StandardWBSElement_2 as select from prpss
                                        
  association [1..1] to I_StandardProject_2          as _Project                    on  $projection.StandardProjectInternalID = _Project.StandardProjectInternalID
  association [1..1] to I_ControllingArea            as _ControllingArea            on  $projection.ControllingArea = _ControllingArea.ControllingArea
  association [1..1] to I_CompanyCode                as _CompanyCode                on  $projection.CompanyCode = _CompanyCode.CompanyCode
  association [1..*] to I_CostCenter                 as _CostCenter                 on  $projection.CostCenter      = _CostCenter.CostCenter
                                                                                    and $projection.ControllingArea = _CostCenter.ControllingArea
  association [1..1] to I_BusinessArea               as _BusinessArea               on  $projection.BusinessArea = _BusinessArea.BusinessArea
  association [1..1] to I_Plant                      as _Plant                      on  $projection.Plant = _Plant.Plant
  association [1..*] to I_ProfitCenter               as _ProfitCenter               on  $projection.ProfitCenter    = _ProfitCenter.ProfitCenter
                                                                                    and $projection.ControllingArea = _ProfitCenter.ControllingArea
  association [1..1] to I_ControllingObjectClass     as _ControllingObjectClass     on  $projection.ControllingObjectClass = _ControllingObjectClass.ControllingObjectClass
  association [1..1] to I_Projecttype                as _ProjectType                on  $projection.ProjectType = _ProjectType.ProjectType
  association [1..1] to I_Prioritycode               as _PriorityCode               on  $projection.PriorityCode = _PriorityCode.PriorityCode
  association [0..1] to I_Location                   as _Location                   on  $projection.Location = _Location.Location
                                                                                    and $projection.Plant    = _Location.Plant
  association [0..1] to I_Equipment                  as _Equipment                  on  $projection.Equipment = _Equipment.Equipment
  association [0..1] to I_FunctionalLocation         as _FunctionalLocation         on  $projection.FunctionalLocation = _FunctionalLocation.FunctionalLocation
  association [0..1] to I_FunctionalArea             as _FunctionalArea             on  $projection.FunctionalArea = _FunctionalArea.FunctionalArea
  association [0..1] to I_Interestcalculationprofile as _InterestCalculationProfile on  $projection.ProjInterestCalcProfile = _InterestCalculationProfile.ProjInterestCalcProfile
  association [0..1] to I_FactoryCalendar            as _FactoryCalendar            on  $projection.FactoryCalendar = _FactoryCalendar.FactoryCalendar
  association [0..1] to I_TaxJurisdiction            as _TaxJurisdiction            on  $projection.TaxJurisdiction = _TaxJurisdiction.TaxJurisdiction
                                                                                    and $projection.CostingSheet    = _TaxJurisdiction.TaxJurisdictionCalcProcedure
  association [0..1] to I_ProjectResponsiblePerson   as _ResponsiblePerson          on  $projection.ResponsiblePerson = _ResponsiblePerson.ResponsiblePerson
  association [0..1] to I_ProjectApplicant           as _ProjectApplicant           on  $projection.ApplicantCode = _ProjectApplicant.ApplicantCode

  association [0..1] to I_ProjectObjectShortText     as _StdWBSElementShortText     on  _StdWBSElementShortText.Language   = $session.system_language
                                                                                    and _StdWBSElementShortText.ProjectApplicationIdentifier = 'PS'
                                                                                    and _StdWBSElementShortText.ProjectObjectType = 'PT'
                                                                                    and $projection.StandardWBSElementObject = _StdWBSElementShortText.ProjectObjectNode
                                  
{      
  key cast ( prpss.pspnr as ps_s4_pspnr preserving type )                    as StandardWBSElementInternalID,
  
      @ObjectModel.text.element: ['StdWBSDescription']
      cast ( prpss.posid as ps_s4_posid preserving type )                    as StdWBSElement,
      
      cast ( prpss.psphi as ps_s4_ispsp preserving type )                    as StandardProjectInternalID,
   
      @Semantics.text: true
      case
        when _StdWBSElementShortText.LanguageBasedShortText is not initial
        then _StdWBSElementShortText.LanguageBasedShortText
        else cast ( prpss.post1 as ps_s4_post1 preserving type ) 
      end                                                                    as StdWBSDescription,
      
      prpss.objnr                                                            as StandardWBSElementObject,
      @Semantics.user.createdBy: true
      cast ( prpss.ernam as ernam preserving type )                          as CreatedByUser,
      @Semantics.systemDate.createdAt: true
      cast ( prpss.erdat as erdat preserving type )                          as CreationDate,
      @Semantics.user.lastChangedBy: true
      cast ( prpss.aenam as ps_s4_aenam preserving type )                    as LastChangedByUser,
      @Semantics.systemDate.lastChangedAt: true
      cast ( prpss.aedat as ps_s4_updat preserving type )                    as LastChangeDate,
      cast ( prpss.vernr as ps_s4_vernr preserving type )                    as ResponsiblePerson,
      cast ( prpss.verna as ps_s4_verna preserving type )                    as ResponsiblePersonName,
      cast ( prpss.astnr as ps_s4_astnr preserving type )                    as ApplicantCode,
      prpss.astna                                                            as ApplicantName,
      cast ( prpss.pbukr as bukrs preserving type )                          as CompanyCode,
      cast ( prpss.pgsbr as gsber preserving type )                          as BusinessArea,
      cast ( prpss.pkokr as logbr_kokrs preserving type )                    as ControllingArea,
      prpss.prctr                                                            as ProfitCenter,
      cast ( prpss.prart as ps_s4_prart preserving type )                    as ProjectType,
      @Semantics.booleanIndicator: true
      cast ( prpss.plakz as ps_plakz preserving type )                       as WBSElementIsPlanningElement,
      @Semantics.booleanIndicator: true
      cast ( prpss.belkz as ps_s4_belkz preserving type )                    as WBSIsAccountAssignmentElement,
      @Semantics.booleanIndicator: true
      cast ( prpss.fakkz as ps_fakkz preserving type )                       as WBSElementIsBillingElement,
      prpss.kalsm                                                            as CostingSheet,
      cast ( prpss.akstl as ps_s4_akstl preserving type )                    as RequestingCostCenter,
      cast ( prpss.fkstl as ps_s4_fkstl preserving type )                    as ResponsibleCostCenter,
      cast ( prpss.fabkl as stkal preserving type )                          as FactoryCalendar,
      cast ( prpss.pspri as nw_prio preserving type )                        as PriorityCode,
      cast ( prpss.pwpos as ps_pwpos preserving type )                       as Currency,
      prpss.werks                                                            as Plant,
      prpss.slwid                                                            as FreeDefinedTableFieldSemantic,
      @Semantics.booleanIndicator: true
      prpss.xstat                                                            as WBSIsStatisticalWBSElement,
      cast( prpss.txjcd as ps_s4_txjcd preserving type )                     as TaxJurisdiction,
      @Semantics.booleanIndicator: true
      cast ( prpss.plint as plint_t preserving type )                        as WBSIsMarkedForIntegratedPlng,
      cast ( prpss.func_area as fkber preserving type )                      as FunctionalArea,
      cast ( prpss.stort as /sapapo/locno )                                  as Location,
      prpss.equnr                                                            as Equipment,
      prpss.tplnr                                                            as FunctionalLocation,
      prpss.aennr                                                            as ProjectObjectChangeNumber,
      cast ( prpss.adpsp as addcompare_core )                                as ReferenceElement,
      prpss.zschm                                                            as ProjInterestCalcProfile,
      prpss.imprf                                                            as InvestmentProfile,
      @EndUserText.label: 'Level'
      prpss.stufe                                                            as WBSElementHierarchyLevel,
      cast ( prpss.zschl as fin_ovhkey preserving type )                     as OverheadCode,
      cast ( prpss.abgsl as psb_bo_abgr_schl_de preserving type )            as ResultAnalysisInternalID,
      cast ( prpss.evgew as ev_weightd preserving type )                     as ProgressAnlysAggregationWeight,
      prpss.poski                                                            as WBSElementShortID,
      prpss.akokr                                                            as ReqgCostCenterControllingArea,
      prpss.fkokr                                                            as RespCostCenterControllingArea,
      prpss.txtsp                                                            as Language,
      cast ( prpss.kostl as ps_kostl preserving type )                       as CostCenter,     
      @Semantics.booleanIndicator: true
      prpss.clasf                                                            as WBSElementIsUsedInProjSmmry,
      @Semantics.booleanIndicator: true
      prpss.grpkz                                                            as WBSElementIsGroupingWBSElement,
      prpss.vname                                                            as JointVenture,
      prpss.recid                                                            as JointVentureRecoveryCode,
      prpss.etype                                                            as JointVentureEquityType,
      cast ( prpss.otype as jv_otype preserving type )                       as JointVentureObjectType,
      prpss.jibcl                                                            as JointVentureClass,
      prpss.jibsa                                                            as JointVentureSubClass,          
      cast ( prpss.scope as ps_s4_scope_cv )                                 as ControllingObjectClass,     
      prpss.posid_edit                                                       as StdWBSElementWithCodingMask,
      
      cast ( prpss.usr00 as usr00prps preserving type )                      as FreeDefinedAttribute01,
      cast ( prpss.usr01 as usr01prps preserving type )                      as FreeDefinedAttribute02,
      cast ( prpss.usr02 as usr02prps preserving type )                      as FreeDefinedAttribute03,
      cast ( prpss.usr03 as usr03prps preserving type )                      as FreeDefinedAttribute04,
      
      @Semantics.quantity.unitOfMeasure: 'FreeDefinedQuantity1Unit'
      cast ( prpss.usr04 as usr04prps preserving type )                      as FreeDefinedQuantity1,
      cast ( prpss.use04 as use04prps preserving type )                      as FreeDefinedQuantity1Unit,
      
      @Semantics.quantity.unitOfMeasure: 'FreeDefinedQuantity2Unit'
      cast ( prpss.usr05 as usr05prps preserving type )                      as FreeDefinedQuantity2,
      cast ( prpss.use05 as use05prps preserving type )                      as FreeDefinedQuantity2Unit,
      
      @Semantics.amount.currencyCode: 'FreeDefinedAmount1Currency' 
      cast ( prpss.usr06 as usr06prps preserving type )                      as FreeDefinedAmount1,
      cast ( prpss.use06 as use06prps preserving type )                      as FreeDefinedAmount1Currency,
      
      @Semantics.amount.currencyCode: 'FreeDefinedAmount2Currency'
      cast ( prpss.usr07 as usr07prps preserving type )                      as FreeDefinedAmount2,
      cast ( prpss.use07 as use07prps preserving type )                      as FreeDefinedAmount2Currency,
      
      cast ( prpss.usr08 as usr08prps preserving type )                      as FreeDefinedDate1,
      cast ( prpss.usr09 as usr09prps preserving type )                      as FreeDefinedDate2,
      cast ( prpss.usr10 as usr10prps preserving type )                      as FreeDefinedIndicator1,
      cast ( prpss.usr11 as usr11prps preserving type )                      as FreeDefinedIndicator2,

      prpss.subpr                                                            as SubProject,

      _Project,
      _ControllingArea,
      _Plant,
      _CostCenter,
      _BusinessArea,
      _CompanyCode,
      _ProfitCenter,
      _ControllingObjectClass,
      _ProjectType,
      _PriorityCode,
      _Location,
      _Equipment,
      _FunctionalLocation,
      _FunctionalArea,
      _InterestCalculationProfile,
      _FactoryCalendar,
      _TaxJurisdiction,
      _ResponsiblePerson,
      _ProjectApplicant,
      _StdWBSElementShortText
};
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_PROJECTOBJECTSHORTTEXT",
"PRPSS"
],
"ASSOCIATED":
[
"I_BUSINESSAREA",
"I_COMPANYCODE",
"I_CONTROLLINGAREA",
"I_CONTROLLINGOBJECTCLASS",
"I_COSTCENTER",
"I_EQUIPMENT",
"I_FACTORYCALENDAR",
"I_FUNCTIONALAREA",
"I_FUNCTIONALLOCATION",
"I_INTERESTCALCULATIONPROFILE",
"I_LOCATION",
"I_PLANT",
"I_PRIORITYCODE",
"I_PROFITCENTER",
"I_PROJECTAPPLICANT",
"I_PROJECTOBJECTSHORTTEXT",
"I_PROJECTRESPONSIBLEPERSON",
"I_PROJECTTYPE",
"I_STANDARDPROJECT_2",
"I_TAXJURISDICTION"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/