I_SrvcMgmtOrganizationUnitText

@EndUserText.label: 'Srvc Mgmt Organizational Unit - Text'
@ClientHandling.algorithm: #SESSION_VARIABLE
@AbapCatalog: {
  sqlViewName: 'ISRVCORGUNITTXT',
  compiler.compareFilter: true,
  preserveKey: true
}
@VDM: {
  viewType: #BASIC,
  lifecycle.contract.type: #PUBLIC_LOCAL_API
}
@AccessControl.authorizationCheck: #NOT_REQUIRED

@ObjectModel: {
   dataCategory: #TEXT,
   representativeKey: 'OrgUnitTypeIDConcatenated',
   usageType: {
     dataClass:      #CUSTOMIZING,
     serviceQuality: #A,
     sizeCategory:   #L
   },
   supportedCapabilities: [#LANGUAGE_DEPENDENT_TEXT, #SQL_DATA_SOURCE,
   #CDS_MODELING_DATA_SOURCE, #CDS_MODELING_ASSOCIATION_TARGET],
   modelingPattern: #LANGUAGE_DEPENDENT_TEXT
}

@Search.searchable: true
@Metadata.ignorePropagatedAnnotations: true

define view I_SrvcMgmtOrganizationUnitText
  as select from hrp1000
    inner join            t77s0   as systemtable on  grpid = 'PLOGI'
                                                 and semid = 'PLOGI'
                                                 and gsval = hrp1000.plvar
  association [1]    to I_SrvcMgmtOrganizationUnit as _SrvcMgmtOrganizationUnit on $projection.OrgUnitTypeIDConcatenated = _SrvcMgmtOrganizationUnit.OrgUnitTypeIDConcatenated
  association [0..1] to I_Language                 as _Language                 on $projection.Language = _Language.Language

{
        @ObjectModel.foreignKey.association: '_SrvcMgmtOrganizationUnit'
  key   otjid as OrgUnitTypeIDConcatenated,
        @Semantics.language: true
        @ObjectModel.foreignKey.association: '_Language'
  key   langu as Language,
        objid as OrganizationalUnit,
        begda as StartDate,
        endda as EndDate,
        short as OrganizationalUnitShortName,
        @Search.defaultSearchElement: true
        @Search.fuzzinessThreshold: 0.8
        @Semantics.text: true
        stext as OrganizationalUnitName,

        _SrvcMgmtOrganizationUnit,
        _Language

}
where
      hrp1000.otype = 'O'
  and hrp1000.istat = '1'
  and begda         <= $session.system_date
  and endda         >= $session.system_date
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"HRP1000",
"T77S0"
],
"ASSOCIATED":
[
"I_LANGUAGE",
"I_SRVCMGMTORGANIZATIONUNIT"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/