I_SrvcDocInternalOrderVH

@AbapCatalog.sqlViewName: 'ISRVCDOCINTORDVH'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.personalData.blocking: #BLOCKED_DATA_EXCLUDED
@ClientHandling.algorithm : #SESSION_VARIABLE
@EndUserText.label: 'Internal Order Search Help'
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #S
@ObjectModel.usageType.dataClass: #MASTER
@ObjectModel.dataCategory:#VALUE_HELP
@ObjectModel.representativeKey: 'InternalOrder'
@VDM.viewType: #BASIC
@Metadata.ignorePropagatedAnnotations: true

define view I_SrvcDocInternalOrderVH
  as select from            aufk             as au
    left outer to many join iaom_assignments as ag on ag.object_no = au.objnr
    left outer to many join iaom_crmsrv_exat as ex on ex.ext_object_id = ag.ext_object_id
    left outer to many join iaom_ext_obj_inf as ob on  ob.ext_object_id   = ag.ext_object_id
                                                   and ob.bus_scenario_id = ag.bus_scenario_id
    left outer to many join kna1             as ka on ka.kunnr = ex.kunnr
  association [0..1] to I_InternalOrderSystemStatus as _SystemStatus      on $projection.ControllingObject = _SystemStatus.ControllingObject
  association [0..1] to I_InternalOrderType         as _InternalOrderType on $projection.OrderType = _InternalOrderType.OrderType
{
  key ltrim(au.aufnr, '0')                              as InternalOrder,
      au.ktext                                          as InternalOrderDescription,
      au.bukrs                                          as CompanyCode,
      au.kokrs                                          as ControllingArea,
      au.auart                                          as OrderType,
      ex.kunnr                                          as SoldToParty,
      cast ( ex.service_org as char14 preserving type ) as ServiceOrganization,
      ex.object_id                                      as ServiceDocument,
      cast ( ex.process_type as /pf1/dte_bpe_trnstype ) as TransactionType,
      ex.process_descript                               as ServiceDocumentDescription,
      au.objnr                                          as ControllingObject,
      _SystemStatus.ControllingObjectStatus             as ControllingObjectStatus,
      @Semantics.booleanIndicator: true
      _SystemStatus.StatusIsInactive                    as StatusIsInactive
}
where
  (
       au.autyp                                   = '01'
    or au.autyp                                   = '02'
    or au.autyp                                   = '03'
  )
  and  au.cckey                                   = '2'
  and  _InternalOrderType.RevenuePostingIsAllowed = 'X'
  and  _SystemStatus.StatusIsInactive             = ' '
  and  _SystemStatus.ControllingObjectStatus      = 'I0002';
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_INTERNALORDERSYSTEMSTATUS",
"I_INTERNALORDERTYPE",
"AUFK",
"IAOM_ASSIGNMENTS",
"IAOM_CRMSRV_EXAT",
"IAOM_EXT_OBJ_INF",
"KNA1"
],
"ASSOCIATED":
[
"I_INTERNALORDERSYSTEMSTATUS",
"I_INTERNALORDERTYPE"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/