I_SponsoredClassHierarchyNode

@AbapCatalog.sqlViewName: 'IGMSPCLASSHN'
@ClientHandling.algorithm: #SESSION_VARIABLE
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #PRIVILEGED_ONLY
@EndUserText.label: 'Sponsored Class Hierarchy Node'

@VDM.viewType: #BASIC
@Hierarchy.parentChild:[
{ recurse:          {   parent: 'ParentNode',   child:  'HierarchyNode'   },
  siblingsOrder:    {   by: 'HierarchyNodeSequence',    direction: 'ASC'   },
  directory:        '_Hierarchy'
  }]
@Analytics: { dataExtraction: {enabled:true} }
@ObjectModel: {
     dataCategory: #HIERARCHY,
     usageType: {
         dataClass: #MASTER,
         serviceQuality: #A,
         sizeCategory: #XL
     }
}

define view I_SponsoredClassHierarchyNode
  as select from hrrp_node

  association [0..*] to I_SponsoredClassHierarchyNodeT as _Text               on  $projection.SponsoredClassHierarchy = _Text.SponsoredClassHierarchy
                                                                              and $projection.HierarchyNode           = _Text.HierarchyNode
  //and $projection.SposnoredClass        = '' // just to show that this association is only to be followed if Grants center is blank


  association [0..1] to I_SponsoredClassCore           as _SponsoredClassCore on  $projection.SponsoredClass = _SponsoredClassCore.SponsoredClass

  association [1..1] to I_SponsoredClassHierarchy      as _Hierarchy          on  $projection.SponsoredClassHierarchy = _Hierarchy.SponsoredClassHierarchy
                                                                              and $projection.ValidityEndDate         = _Hierarchy.ValidityEndDate

{
      @Consumption.filter: {mandatory : true, selectionType : #SINGLE, multipleSelections : false }
      @ObjectModel.foreignKey.association: '_Hierarchy'
  key cast( hrrp_node.hryid as gmis_hryid_sponsoredclass preserving type ) as SponsoredClassHierarchy,
      @ObjectModel.text.association: '_Text'
  key hrrp_node.hrynode                                                    as HierarchyNode,
      @Consumption.filter: {mandatory : true, selectionType : #SINGLE, multipleSelections : false }
      @Semantics.businessDate.to: true
  key cast( hrrp_node.hryvalto as fis_datbi preserving type )              as ValidityEndDate,
      hrrp_node.parnode                                                    as ParentNode,
      hrrp_node.hryver                                                     as HierarchyVersion,
      @Semantics.businessDate.from: true
      cast( hrrp_node.hryvalfrom as fis_datab preserving type)             as ValidityStartDate,
      @ObjectModel.foreignKey.association: '_SponsoredClassCore'
      @Consumption.filter.businessDate.at:true
      cast ( case nodetype
        when 'L' then  hrrp_node.nodevalue
        else  ''
      end as gm_sponsored_class )                                          as SponsoredClass,
      hrrp_node.hryseqnbr                                                  as HierarchyNodeSequence,
      hrrp_node.hrylevel                                                   as HierarchyNodeLevel,
      hrrp_node.nodetype                                                   as NodeType,

      _Text,
      _SponsoredClassCore,
      _Hierarchy

}
where
      hrrp_node.nodetype <> 'D'
  and hrrp_node.hrytype  =  '0116';
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"HRRP_NODE"
],
"ASSOCIATED":
[
"I_SPONSOREDCLASSCORE",
"I_SPONSOREDCLASSHIERARCHY",
"I_SPONSOREDCLASSHIERARCHYNODET"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/