I_SpecValAssgmtWithHeader

@AbapCatalog.sqlViewName: 'ISPECVAWHDR'
@AbapCatalog.compiler.compareFilter: true

@AccessControl.authorizationCheck: #CHECK

@ClientHandling.algorithm: #SESSION_VARIABLE

@ObjectModel.usageType.sizeCategory: #L
@ObjectModel.usageType.serviceQuality: #B
@ObjectModel.usageType.dataClass: #TRANSACTIONAL

@VDM.lifecycle.contract.type: #SAP_INTERNAL_API
@VDM.viewType: #COMPOSITE

@EndUserText.label: 'Specification Value Assignment Instance with Header'
define view I_SpecValAssgmtWithHeader
  with parameters
    @Environment.systemField: #SYSTEM_DATE
    P_KeyDate : sydate
  as select from    P_SpecValAssgmtInstanceNormal( P_KeyDate : $parameters.P_KeyDate ) as header
    left outer join I_SpecValAssgmtUsage                                               as usg on  header.SpecValAssgmtRootSpecIntID   = usg.SpecificationInternalID
                                                                                              and header.SpecValAssgmtInheritanceRoot = usg.MasterTableElementInternalID
                                                                                              and usg.SpecValAssgmtUsgeValdtyStrtDte  <= $parameters.P_KeyDate
                                                                                              and usg.SpecValAssgmtUsgeValdtyEndDte   >= $parameters.P_KeyDate
                                                                                              and usg.SpecValAssgmtUsageIsDeleted != 'X'

  association [0..1] to I_SpecRating              as _Rating                  on $projection.SpecificationRating = _Rating.SpecificationRating
  association [0..1] to I_SpecValidityArea        as _ValidityArea            on $projection.SpecificationValidityArea = _ValidityArea.SpecificationValidityArea
  association [0..1] to I_SpecificationForKeyDate as _SpecificationForKeyDate on $projection.SpecificationInternalID = _SpecificationForKeyDate.SpecificationInternalID
{
      //header

  key SpecValAssgmtHdr,
  key SpecValAssgmt,
  key usg.SpecValAssgmtUsageInternalID,
      header.SpecificationInternalID,
      SpecValAssgmtType,
      SpecValAssgmtHdrIsDeleted,
      SpecValAssgmtChangeState,
      SpecValAssgmtValidityStartDate,
      SpecValAssgmtValidityEndDate,
      SpecValAssgmtChangeNumber,
      SpecValAssgmtCreationDate,
      SpecValAssgmtCreatedByUser,
      SpecValAssgmtLastChangeDate,
      SpecValAssgmtLastChangedByUser,
      SpecValAssgmtSortSequence,
      SpecValAssgmtUnitRefDimension,
      SpecValAssgmtIsInhtncSource,
      InhtdSpecValAssgmtIsTmpChgd,
      InhtdSpecValAssgmtIsPermChgd,
      SpecInheritanceTemplate,
      SpecValAssgmtInheritanceParent,
      SpecValAssgmtInheritanceRoot,
      SpecValAssgmtRootSpecIntID,
      SpecValAssgmtIsDeleted,

      usg.SpecificationRating,
      usg.SpecificationValidityArea,
      usg.SpecValAssgmtUsageIsExcluded,
      usg.SpecValAssgmtUsageIsActive,
      usg.SpecValAssgmtUsageIsRelevant,

      /* Associations */
      //header

      _ValueAssignmentType,
      _SpecificationForKeyDate
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_SPECVALASSGMTUSAGE",
"P_SPECVALASSGMTINSTANCENORMAL"
],
"ASSOCIATED":
[
"I_SPECIFICATIONFORKEYDATE",
"I_SPECRATING",
"I_SPECVALASSGMTTYPE",
"I_SPECVALIDITYAREA"
],
"BASE":
[
"P_SPECVALASSGMTINSTANCENORMAL"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/