I_SpecValAssgmtInstanceWthComp

@AbapCatalog.sqlViewName: 'ISPECVAINSTWCOMP'
@AbapCatalog.compiler.compareFilter: true

@AccessControl.authorizationCheck: #CHECK

@ClientHandling.algorithm: #SESSION_VARIABLE

@ObjectModel.usageType.sizeCategory: #L
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.dataClass: #TRANSACTIONAL

@VDM.lifecycle.contract.type: #SAP_INTERNAL_API
@VDM.viewType: #COMPOSITE


@EndUserText.label: 'Specification Value Assignment Instance with Composition'
define view I_SpecValAssgmtInstanceWthComp
  with parameters
    @Environment.systemField: #SYSTEM_DATE
    P_KeyDate : sydate
  as select from I_SpecValAssgmtInstance( P_KeyDate : $parameters.P_KeyDate )       as vainst
    inner join   I_SpecValAssgmtItemForKeyDate( P_KeyDate : $parameters.P_KeyDate ) as vaitem on  vainst.SpecValAssgmtRootSpecIntID   = vaitem.SpecificationInternalID
                                                                                              and vainst.SpecValAssgmtInheritanceRoot = vaitem.SpecValAssgmt
  association [1..1] to I_SpecificationForKeyDate as _SpecificationForKeyDate on  $projection.SpecificationInternalID = _SpecificationForKeyDate.SpecificationInternalID
  association [1..1] to I_SpecValAssgmtInstance   as _SpecValAssgmtInstance   on  $projection.SpecValAssgmtHdr             = _SpecValAssgmtInstance.SpecValAssgmtHdr
                                                                              and $projection.SpecValAssgmt                = _SpecValAssgmtInstance.SpecValAssgmt
                                                                              and $projection.SpecValAssgmtUsageInternalID = _SpecValAssgmtInstance.SpecValAssgmtUsageInternalID
{
  key vainst.SpecValAssgmtHdr,
  key vainst.SpecValAssgmt,
  key vainst.SpecValAssgmtUsageInternalID,
  key vaitem.ComponentSpecificationIntID,

      vainst.SpecValAssgmtIsInhtncSource,
      vainst.SpecificationInternalID,
      vainst.InhtdSpecValAssgmtIsTmpChgd,
      vainst.InhtdSpecValAssgmtIsPermChgd,
      vainst.SpecInheritanceTemplate,
      vainst.SpecValAssgmtInheritanceParent,
      vainst.SpecValAssgmtInheritanceRoot,
      vainst.SpecValAssgmtRootSpecIntID,
      vainst.SpecValAssgmtType,
      vainst.SpecValAssgmtChangeState,
      vainst.SpecValAssgmtSortSequence,
      vainst.SpecValAssgmtUnitRefDimension,
      vainst.ValueAssignmentSource,
      vainst.SpecificationRating,
      vainst.SpecificationValidityArea,

      vaitem.CompSpecComponentType,
      vaitem.CompSpecLowerLimitOperator,
      vaitem.CompSpecLowerLimit,
      vaitem.CompSpecUpperLimitOperator,
      vaitem.CompSpecUpperLimit,
      vaitem.CompSpecQuantity,
      vaitem.CompSpecUnit,
      vaitem.CompSpecSortSequence,
      vaitem.CompSpecDecimalQuantity,
      vaitem.CompSpecExceptionCode,

      _SpecificationForKeyDate,
      _ComponentSpecForKeyDate,
      _ValueAssignmentType,
      _SpecValAssgmtInstance
}
where
  SpecValAssgmtItemIsDeleted <> 'X'
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_SPECVALASSGMTINSTANCE",
"I_SPECVALASSGMTITEMFORKEYDATE"
],
"ASSOCIATED":
[
"I_SPECIFICATIONFORKEYDATE",
"I_SPECVALASSGMTINSTANCE",
"I_SPECVALASSGMTTYPE"
],
"BASE":
[
"I_SPECVALASSGMTINSTANCE",
"I_SPECVALASSGMTITEMFORKEYDATE"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/