I_SpecChangeNumberValueHelp

@AbapCatalog.sqlViewName: 'ISPECECNVH'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey:true

@AccessControl.authorizationCheck: #CHECK
@AccessControl.privilegedAssociations: [
  '_ChangeMasterLogAccMActive'   ,
  '_ChgMstrLogAccMSecureIDAssgmt',
  '_ChangeMstrLogAccMUserAuthzn' ]

@ClientHandling.algorithm: #SESSION_VARIABLE

@Consumption.ranked: true

@ObjectModel.usageType.sizeCategory: #L
@ObjectModel.usageType.serviceQuality: #A
@ObjectModel.usageType.dataClass: #MASTER

@ObjectModel.semanticKey:  [ 'ChangeNumber' ]
@ObjectModel.dataCategory:#VALUE_HELP
@ObjectModel.representativeKey: 'ChangeNumber'

@Search.searchable: true

@VDM.lifecycle.contract.type: #SAP_INTERNAL_API
@VDM.viewType: #COMPOSITE

@EndUserText.label: 'Value Help for Change Numbers in Specification'
define view I_SpecChangeNumberValueHelp
  as select from I_ChangeMasterObjTypeAssgmt
{
      @ObjectModel.text.element: 'ChangeNumberDescription'
      @Search.defaultSearchElement: true
      @Search.fuzzinessThreshold: 0.8
      @Search.ranking: #HIGH
  key _ChangeMaster.ChangeNumber,
      @Search.defaultSearchElement: true
      @Search.fuzzinessThreshold: 0.8
      @Search.ranking: #LOW
      @Semantics.text: true
      _ChangeMaster.ChangeNumberDescription,

      _ChangeMaster.ChangeNumberValidFromDate,
      _ChangeMaster.ChangeNumberStatus,

      _ChangeMaster.ChangeNumberCreatedByUser,
      _ChangeMaster.ChangeNumberCreationDate,
      _ChangeMaster.ChangeNumberLastChangedByUser,
      _ChangeMaster.ChangeNumberLastChangedDate,

      _ChangeMaster._ChangeNumberStatus,
      _ChangeMaster._CreatedByUser,
      _ChangeMaster._LastChangedByUser,

      @Consumption.hidden: true
      _ChangeMaster.AuthorizationGroup,
      @Consumption.hidden: true
      _ChangeMaster.ChangeNumberFunction,
      @Consumption.hidden: true
      _ChangeMaster.ChangeNumberReleaseKey,

      // Access Control Management, used in DCL

      @Consumption.hidden:true
      _ChangeMaster._ChangeMasterLogAccMActive,
      @Consumption.hidden:true
      _ChangeMaster._ChgMstrLogAccMSecureIDAssgmt,
      @Consumption.hidden:true
      _ChangeMaster._ChangeMstrLogAccMUserAuthzn
}
where
      ChangeNumberObjectType  = '60'
  and IsActiveForChangeNumber = 'X'
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_CHANGEMASTER",
"I_CHANGEMASTEROBJTYPEASSGMT"
],
"ASSOCIATED":
[
"I_CHANGEMASTERLOGACCMACTIVE",
"I_CHANGEMASTERSTATUS",
"I_CHANGEMSTRLOGACCMUSERAUTHZN",
"I_CHGMSTRLOGACCMSECUREIDASSGMT",
"I_USER"
],
"BASE":
[
"I_CHANGEMASTER"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/