I_SourcingProjectQuotationTP

@AccessControl.authorizationCheck: #MANDATORY

@Metadata.ignorePropagatedAnnotations:true

@ObjectModel:{representativeKey:      'SourcingProjectQuotationUUID',
              semanticKey:           ['SourcingProjectQuotation'],
              sapObjectNodeType.name: 'SourcingProjectQuotation',

              modelingPattern:        #TRANSACTIONAL_INTERFACE,
              supportedCapabilities: [#TRANSACTIONAL_PROVIDER],

              usageType: {
                dataClass:      #TRANSACTIONAL,
                serviceQuality: #C,
                sizeCategory:   #L
              }
}

@VDM:{
  viewType:                #TRANSACTIONAL,
  lifecycle.contract.type: #PUBLIC_LOCAL_API
}

@EndUserText.label: 'Quotation for Sourcing Project - TP'
@AbapCatalog.extensibility: {
  extensible: true,
  dataSources: ['SourcingProjectQuotationTP'],
  allowNewDatasources: false,
  elementSuffix: 'SQH',
  quota: { maximumFields: 204,
           maximumBytes: 4080 },
  allowNewCompositions: true }
  
define root view entity I_SourcingProjectQuotationTP
  provider contract transactional_interface
  as projection on R_SourcingProjectQuotationTP as SourcingProjectQuotationTP
{

  key SourcingProjectQuotationUUID,
      SourcingProjectQuotation,
      SrcgProjQuotationVersion,
      SourcingProjectQuotationType,
      SourcingProjectQuotationName,
      SrcgProjQuotationIsSimulated,
      Bidder,
      CompanyCode,
      PurchasingGroup,
      PurchasingOrganization,
      SrcgProjQtnOfferCurrency,
      @Semantics.amount.currencyCode: 'SrcgProjQtnOfferCurrency'
      SrcgProjQtnTotNetAmt,
      SrcgProjQtnLifecycleStatus,
      SrcgProjQtnRevisionSts,
      SrcgProjQtnActvtnSts,
      SrcgProjQtnSubmsnSts,
      SrcgProjQtnAwardingStatus,
      SourcingProjectUUID,
      SourcingProjectNegotiationUUID,
      PricingProcedure,
      LastChangedByUser,
      CreatedByUser,
      LastChangeDateTime,
      CreationDateTime,
      SrcgProjAttchsAreForbidden,
      SrcgProjNotesAreForbidden,
      SourcingOrigin,
      ExternalSourcingProjectQtnRef,
      QtnLatestSubmissionDateTime,
      LogicalSystem,
      @Semantics.booleanIndicator: true
      IsEndOfPurposeBlocked,
      CashDiscount1Days,
      CashDiscount2Days,
      CashDiscount1Percent,
      CashDiscount2Percent,
      NetPaymentDays,
      MaterialGroup,
      SourcingAwardingDate,
      SourcingProjectNegotiationType,


      /* Compositions */
      _SrcgProjQtnAllowedCurrency : redirected to composition child I_SrcgProjQtnAllowedCurrencyTP,
      _SrcgProjQtnItem            : redirected to composition child I_SrcgProjQtnItemTP,
      _SrcgProjQtnSupplierContact : redirected to composition child I_SrcgProjQtnSupplierContactTP

}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"R_SOURCINGPROJECTQUOTATIONTP"
],
"ASSOCIATED":
[
"I_SRCGPROJQTNALLOWEDCURRENCYTP",
"I_SRCGPROJQTNITEMTP",
"I_SRCGPROJQTNSUPPLIERCONTACTTP",
"R_SRCGPROJQTNALLOWEDCURRENCYTP",
"R_SRCGPROJQTNITEMTP",
"R_SRCGPROJQTNSUPPLIERCONTACTTP"
],
"BASE":
[
"R_SOURCINGPROJECTQUOTATIONTP"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/