I_SlsPrcgKeyCombinationText

DDL: I_SLSPRCGKEYCOMBINATIONTEXT SQL: ISLSPRCGKEYCTXT Type: view BASIC

Text of Key Combination for Pricing in Sales

I_SlsPrcgKeyCombinationText is a Basic CDS View that provides data about "Text of Key Combination for Pricing in Sales" in SAP S/4HANA. It reads from 3 data sources (t681, t685, tmc1t) and exposes 7 fields with key fields ConditionType, AccessNumberOfAccessSequence, ConditionTable, Language. It has 2 associations to related views.

3 data source(s) 7 fields

Data Sources (3)

SourceAliasJoin Type
t681 t681 inner
t685 t685 inner
tmc1t tmc1t inner

Associations (2)

CardinalityTargetAliasCondition
[0..1] I_SlsPrcgKeyCombination _SlsPrcgKeyCombination $projection.ConditionType = _SlsPrcgKeyCombination.ConditionType and $projection.AccessNumberOfAccessSequence = _SlsPrcgKeyCombination.AccessNumberOfAccessSequence and $projection.ConditionTable = _SlsPrcgKeyCombination.ConditionTable
[0..1] I_Language _Language $projection.Language = _Language.Language

Annotations (17)

NameValueLevelField
AbapCatalog.sqlViewName ISLSPRCGKEYCTXT view
AbapCatalog.compiler.compareFilter true view
AbapCatalog.preserveKey true view
AbapCatalog.buffering.status #ACTIVE view
AbapCatalog.buffering.type #FULL view
AccessControl.authorizationCheck #MANDATORY view
EndUserText.label Text of Key Combination for Pricing in Sales view
VDM.viewType #BASIC view
ObjectModel.representativeKey ConditionTable view
ObjectModel.usageType.dataClass #CUSTOMIZING view
ObjectModel.usageType.serviceQuality #A view
ObjectModel.usageType.sizeCategory #S view
ObjectModel.dataCategory #TEXT view
ClientHandling.algorithm #SESSION_VARIABLE view
UI.headerInfo.typeName Text of Key Combination for Pricing in Sales view
UI.headerInfo.typeNamePlural Text of Key Combination for Pricing in Sales view
Search.searchable true view

Fields (7)

KeyFieldSource TableSource FieldDescription
KEY ConditionType t685 kschl
KEY AccessNumberOfAccessSequence t682i kolnr
KEY ConditionTable
KEY Language tmc1t spras
PrcgKeyCombinationDescription tmc1t gstxt
_SlsPrcgKeyCombination _SlsPrcgKeyCombination
_Language _Language 
@AbapCatalog.sqlViewName: 'ISLSPRCGKEYCTXT'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AbapCatalog.buffering.status: #ACTIVE
@AbapCatalog.buffering.type: #FULL
@AccessControl.authorizationCheck: #MANDATORY
@EndUserText.label: 'Text of Key Combination for Pricing in Sales'
@VDM: {
  viewType: #BASIC
}
@ObjectModel.representativeKey: 'ConditionTable'
@ObjectModel:{
   usageType:{
     dataClass: #CUSTOMIZING,
     serviceQuality: #A,
     sizeCategory: #S
   },
   dataCategory: #TEXT
}

@ClientHandling.algorithm: #SESSION_VARIABLE
@UI.headerInfo:{
  typeName:       'Text of Key Combination for Pricing in Sales',
  typeNamePlural: 'Text of Key Combination for Pricing in Sales'
}

@Search.searchable: true
define view I_SlsPrcgKeyCombinationText
  as select distinct from t682i
    inner join            t685  on  t682i.kvewe = t685.kvewe
                                and t682i.kappl = t685.kappl
                                and t682i.kozgf = t685.kozgf
    inner join            t681  on  t682i.kvewe   = t681.kvewe
                                and t682i.kotabnr = t681.kotabnr
    inner join            tmc1t on t681.kotab = tmc1t.gstru

  association [0..1] to I_SlsPrcgKeyCombination as _SlsPrcgKeyCombination on  $projection.ConditionType                = _SlsPrcgKeyCombination.ConditionType
                                                                          and $projection.AccessNumberOfAccessSequence = _SlsPrcgKeyCombination.AccessNumberOfAccessSequence
                                                                          and $projection.ConditionTable               = _SlsPrcgKeyCombination.ConditionTable
  association [0..1] to I_Language              as _Language              on  $projection.Language = _Language.Language


{
      
      @Search:      { defaultSearchElement: true, fuzzinessThreshold: 0.8, ranking: #HIGH }
  key t685.kschl                           as ConditionType,
      @Search:      { defaultSearchElement: true, fuzzinessThreshold: 0.8, ranking: #HIGH }
  key t682i.kolnr                          as AccessNumberOfAccessSequence,
      @Search:      { defaultSearchElement: true, fuzzinessThreshold: 0.8, ranking: #HIGH }
  key cast(t682i.kotabnr as kotabnr_char)  as ConditionTable,
      @ObjectModel.foreignKey.association: '_Language'
      @Semantics.language: true
  key tmc1t.spras                          as Language,
      @Search:      { defaultSearchElement: true, fuzzinessThreshold: 0.8, ranking: #HIGH }
      @Semantics:   { text: true }
      @Consumption.filter.hidden: true
      tmc1t.gstxt                          as PrcgKeyCombinationDescription,
      

      _SlsPrcgKeyCombination,
      _Language
}
where
      t682i.kvewe = 'A'
  and t682i.kappl = 'V'
  and t685.kozgf != ''
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"T681",
"T682I",
"T685",
"TMC1T"
],
"ASSOCIATED":
[
"I_LANGUAGE",
"I_SLSPRCGKEYCOMBINATION"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/

Learn More