I_SlsOrdFlfmtScheduleLine

@ClientHandling.algorithm: #SESSION_VARIABLE 
@ObjectModel.usageType.dataClass: #MIXED
@ObjectModel.usageType.serviceQuality: #D
@ObjectModel.usageType.sizeCategory: #S
@EndUserText.label: 'SOFM Sales Order Scheduleline'
@VDM.viewType: #COMPOSITE
@AccessControl.authorizationCheck: #CHECK
@AbapCatalog.preserveKey: true
@AbapCatalog.sqlViewName: 'ISOFSCHEDLINE' 


define view I_SlsOrdFlfmtScheduleLine 
as 
select from I_SalesDocumentScheduleLine as SO_SL

{
  //Key

  key SalesDocument as SalesOrder,
  key SalesDocumentItem as SalesOrderItem,
  key ScheduleLine,
  
  _SalesDocumentItem, 
     
  //Category 

  _SalesDocumentItem._SalesDocument.SalesDocumentType as SalesOrderType,
  
  //Organization

  _SalesDocumentItem._SalesDocument.SalesOrganization,
  _SalesDocumentItem._SalesDocument.DistributionChannel,
  _SalesDocumentItem._SalesDocument.OrganizationDivision,   
  
  //Requested

  cast( IsRequestedDelivSchedLine as reqd_deliv) as IsRequestedDelivSchedLine ,
  cast(RequestedDeliveryDate as reqd_deliv_date) as RequestedDeliveryDate,
  ScheduleLineOrderQuantity,
  
  //Confirmed

  cast(IsConfirmedDelivSchedLine as confd_deliv) as IsConfirmedDelivSchedLine,
  cast(ConfirmedDeliveryDate as confd_deliv_date) as ConfirmedDeliveryDate,
  @DefaultAggregation: #SUM
  @Semantics.quantity.unitOfMeasure: 'OrderQuantityUnit'
  ConfdOrderQtyByMatlAvailCheck, 
    
  //Availibility

  ProductAvailabilityDate,
  
  //Shipping

  @ObjectModel.foreignKey.association: '_DelivBlockReasonForSchedLine'
  DelivBlockReasonForSchedLine,
  _DelivBlockReasonForSchedLine, 
  @DefaultAggregation: #SUM
  @Semantics.quantity.unitOfMeasure: 'OrderQuantityUnit'
  OpenConfdDelivQtyInOrdQtyUnit,
  @DefaultAggregation: #SUM
  @Semantics.quantity.unitOfMeasure: 'OrderQuantityUnit'
  DeliveredQtyInOrderQtyUnit, 
   
  cast ( case when IsRequestedDelivSchedLine = 'X'
          then RequestedDeliveryDate  
          else ConfirmedDeliveryDate
  end as lfdat_v ) as DeliveryDate,

  //Sales

  @Semantics.unitOfMeasure:true
  @ObjectModel.foreignKey.association: '_OrderQuantityUnit' 
  OrderQuantityUnit,
  _OrderQuantityUnit
} 

where ( _SalesDocumentItem._SalesDocument.SDDocumentCategory = 'C' or   --> Order
        _SalesDocumentItem._SalesDocument.SDDocumentCategory = 'I' or   --> Order w/o charge
        _SalesDocumentItem._SalesDocument.SDDocumentCategory = 'L' )    --> Debit Memo Request
 ;
                                                       
  
  
  
  
  
  
  
  
  
  
  
  
  
  
  
  
  
  
  
  
 /*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_SALESDOCUMENT",
"I_SALESDOCUMENTITEM",
"I_SALESDOCUMENTSCHEDULELINE"
],
"ASSOCIATED":
[
"I_DELIVERYBLOCKREASON",
"I_SALESDOCUMENTITEM",
"I_UNITOFMEASURE"
],
"BASE":
[
"I_SALESDOCUMENTSCHEDULELINE"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/