I_SlsOrdFlfmtPurchaseOrder

@ClientHandling.algorithm: #SESSION_VARIABLE 
@ObjectModel.usageType.dataClass: #MIXED
@ObjectModel.usageType.serviceQuality: #D
@ObjectModel.usageType.sizeCategory: #S

@EndUserText.label: 'SOFM Purchase Order'
@VDM.viewType: #COMPOSITE
@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #BLOCKED_DATA_EXCLUDED
@AbapCatalog.preserveKey: true
@AbapCatalog.sqlViewName: 'ISOFPURORD'

define view I_SlsOrdFlfmtPurchaseOrder

as
select from I_PurchasingDocument

association [1..1] to I_PurchaseOrderStatus    as _PurchaseOrderStatus    on $projection.PurchasingDocument = _PurchaseOrderStatus.PurchaseOrder
association [0..1] to I_PurchasingDocumentStatus  as _Status               on $projection.purchasingdocumentstatus = _Status.PurchasingDocumentStatus

{
    // Key

    key PurchasingDocument,
    
    //Category    

    @ObjectModel.foreignKey.association: '_PurchasingDocumentType' 
    PurchasingDocumentType,
     _PurchasingDocumentType,
    @ObjectModel.foreignKey.association: '_PurchasingDocumentCategory' 
    PurchasingDocumentCategory,
    _PurchasingDocumentCategory,          

    // Purchasing

    PurchasingDocumentOrderDate as PurchaseOrderDate,
     
    // Organization

    @ObjectModel.text.element:  [ 'PurchasingGroupName' ]   
    _PurchasingGroup.PurchasingGroup,    
    @Semantics.text: true  
    _PurchasingGroup.PurchasingGroupName,
    
    @ObjectModel.text.element:  [ 'PurchasingOrganizationName' ]   
    _PurchasingOrganization.PurchasingOrganization,  
    @Semantics.text: true  
    _PurchasingOrganization.PurchasingOrganizationName,
    
    // Partner

    @ObjectModel.text.element:  [ 'SupplierName' ]   
    _Supplier.Supplier,
    @Semantics.text: true  
    _Supplier.SupplierName,
    
    //Status

    @ObjectModel.foreignKey.association: '_Status'
    _PurchaseOrderStatus.PurchasingDocumentStatus,
    _Status
      
}

where  PurchasingDocumentDeletionCode <> 'X'
and    PurchasingDocumentCategory = 'F'
and    IsEndOfPurposeBlocked = ''  -- AT20.11.2017 Mitigation Removal DPP filter in PurchasingDocument Views

                                                 
  
  
  
  
  
  
  
  
  
  
  
  
  
  
 /*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_PURCHASEORDERSTATUS",
"I_PURCHASINGDOCUMENT",
"I_PURCHASINGGROUP",
"I_PURCHASINGORGANIZATION",
"I_SUPPLIER"
],
"ASSOCIATED":
[
"I_PURCHASEORDERSTATUS",
"I_PURCHASINGDOCUMENTCATEGORY",
"I_PURCHASINGDOCUMENTSTATUS",
"I_PURCHASINGDOCUMENTTYPE"
],
"BASE":
[
"I_PURCHASINGDOCUMENT"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/