I_SiteMasterCustomizingData

@AbapCatalog.sqlViewName: 'ISMCD'
@EndUserText.label: 'Site Master Data Customizing'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #CHECK
@ClientHandling.algorithm: #SESSION_VARIABLE
@VDM.viewType: #BASIC
@AccessControl.personalData.blocking: #REQUIRED
@ObjectModel: {
   usageType: {
     dataClass:      #MIXED,
     sizeCategory:   #M,
     serviceQuality: #C
   }
}
define view I_SiteMasterCustomizingData
  as select from           t001w as Site
    left outer to one join wrf1  as _SiteMaster     on _SiteMaster.locnr = Site.kunnr
    left outer to one join ckmlv as _MaterialLedger on _MaterialLedger.bwkey = Site.bwkey
    left outer to one join t001k as _ValuationArea  on _ValuationArea.bwkey = Site.bwkey
  association [0..1] to I_SiteProfile                  as _SiteProfile                  on  $projection.SiteProfile = _SiteProfile.SiteProfile
  association [0..1] to I_SiteMasterCustomizing        as _SiteMasterCustomizing        on  $projection.Site = _SiteMasterCustomizing.Site
  association [0..1] to I_PointOfSaleInboundProfileT   as _PointOfSaleInboundProfileT   on  $projection.PointOfSaleInboundProfile = _PointOfSaleInboundProfileT.PointOfSaleInboundProfile
                                                                                        and _PointOfSaleInboundProfileT.Language  = $session.system_language
  association[0..1] to I_PointOfSaleOutboundProfileT as _PointOfSaleOutboundProfileT on $projection.PointOfSaleOutboundProfile = _PointOfSaleOutboundProfileT.PointOfSaleOutboundProfile 
                                                                                        and  _PointOfSaleOutboundProfileT.Language = $session.system_language                                                                                    
  association [0..1] to I_CurrencyText                 as _CurrencyText                 on  $projection.PointOfSaleCurrency = _CurrencyText.Currency
                                                                                        and _CurrencyText.Language          = $session.system_language
  association [0..1] to I_TransportationZoneText       as _TransportationZoneText       on  $projection.SupplyRegion         = _TransportationZoneText.TransportZone
                                                                                        and $projection.CountryCode          = _TransportationZoneText.CountryCode
                                                                                        and _TransportationZoneText.Language = $session.system_language
  association [0..1] to I_SiteTaxClassificationText    as _SiteTaxClassificationText    on  $projection.SiteTaxClassification   = _SiteTaxClassificationText.SiteTaxClassification
                                                                                        and $projection.CountryCode             = _SiteTaxClassificationText.CountryCode
                                                                                        and _SiteTaxClassificationText.Language = $session.system_language
  association [0..1] to I_SiteDistributionProfileText  as _SiteDistributionProfileText  on  $projection.SiteDistributionProfile   = _SiteDistributionProfileText.SiteDistributionProfile
                                                                                        and _SiteDistributionProfileText.Language = $session.system_language
  association [0..1] to I_SiteLevelConditionText       as _SiteLevelConditionText       on  $projection.SiteLevelCondition   = _SiteLevelConditionText.SiteLevelCondition
                                                                                        and _SiteLevelConditionText.Language = $session.system_language
  association [0..1] to I_SalesAreaDeterminationText   as _SalesAreaDeterminationText   on  $projection.SalesAreaDetermination   = _SalesAreaDeterminationText.SalesAreaDetermination
                                                                                        and _SalesAreaDeterminationText.Language = $session.system_language
  association [0..1] to I_ControlCrdtOfCostCentersText as _ControlCrdtOfCostCentersText on  $projection.ControlCreditOfCostCenters = _ControlCrdtOfCostCentersText.ControlCreditOfCostCenters
                                                                                        and _ControlCrdtOfCostCentersText.Language = $session.system_language
  association [0..1] to I_SiteRevaluationProfileText   as _RevaluationProfileText       on  $projection.RevaluationProfile   = _RevaluationProfileText.RevaluationProfile
                                                                                        and _RevaluationProfileText.Language = $session.system_language
  association [0..1] to I_SiteInventoryMgmtProfileText as _InventoryProfileText         on  $projection.InventoryManagementProfile = _InventoryProfileText.InventoryManagementProfile
                                                                                        and _InventoryProfileText.Language = $session.system_language
  association [0..1] to I_ProductPriceDetnCtrlTxt      as _PriceControlText             on  $projection.PriceDeterminationControl = _PriceControlText.PriceDeterminationControl
                                                                                        and _PriceControlText.Language            = $session.system_language
  association [0..1] to I_SiteConsumptionActyUpdtTxt   as _ConsumptionActivityText      on  $projection.ActualActivitiesUpdated = _ConsumptionActivityText.ActualActivitiesUpdated
                                                                                        and _ConsumptionActivityText.Language   = $session.system_language
  association [0..1] to I_SalesOrganizationText        as _SalesOrgPriceText            on  $projection.SalesOrgForRtlPriceDetn = _SalesOrgPriceText.SalesOrganization
                                                                                        and _SalesOrgPriceText.Language         = $session.system_language
  association [0..1] to I_DistributionChannelText      as _DistributionChannelPriceText on  $projection.DistrChnlForRetailPriceDetn = _DistributionChannelPriceText.DistributionChannel
                                                                                        and _DistributionChannelPriceText.Language  = $session.system_language
  association [0..1] to I_SubsequentListingText        as _SubsequentListingText        on  $projection.SubsequentListingIsActive = _SubsequentListingText.SubsequentListingIsActive
                                                                                        and _SubsequentListingText.Language       = $session.system_language

{
  key Site.werks                                                  as Site,
      _SiteMaster.locnr                                           as SiteCustomer,
      _SiteMaster.bwvko                                           as SalesOrgForRtlPriceDetn,
      _SiteMaster.bwvtw                                           as DistrChnlForRetailPriceDetn,
      Site.bzqhl                                                  as RegularSupplierIsTknIntoAcct,
      Site.kordb                                                  as IsSourceListRequired,
      Site.kkowk                                                  as SiteLevelCondition,
      Site.zone1                                                  as SupplyRegion,
      Site.taxiw                                                  as SiteTaxClassification,
      Site.fprfw                                                  as SiteDistributionProfile,
      Site.land1                                                  as CountryCode,
      Site.vtbfi                                                  as SalesAreaDetermination,
      Site.mgvupd                                                 as ActualCostingIsActive,
      Site.mgvlaupd                                               as ActualActivitiesUpdated,
      Site.mgvlareval                                             as ControlCreditOfCostCenters,
      _ValuationArea.bwmod                                        as ValuationGroupingCode,
      _ValuationArea.wbpro                                        as InventoryManagementProfile,
      _ValuationArea.xvkbw                                        as SalesPriceValuationIsActive,
      _ValuationArea.uprof                                        as RevaluationProfile,
      _ValuationArea.xbkng                                        as IsNegativeStockAllowed,
      _ValuationArea.mlasv                                        as PriceDeterminationIsBinding,
      _ValuationArea.mlccs                                        as CostCompSplitIsExisting,
      _ValuationArea.mlast                                        as PriceDeterminationControl,
      _MaterialLedger.mlbwi                                       as MaterialLedgerIsLive,
      _MaterialLedger.act_live                                    as ActualCostingIsLive,

      case when _SiteMaster.betrp is not null
           then  _SiteMaster.betrp
      else
           _SiteMasterCustomizing.SiteProfile
      end                                                         as SiteProfile,

      case when _SiteMaster.inpro is not null
           then _SiteMaster.inpro
      else
            _SiteMasterCustomizing.PointOfSaleInboundProfile end  as PointOfSaleInboundProfile,
            
      case
           when _SiteMaster.kopro is not null then _SiteMaster.kopro
           else  _SiteMasterCustomizing.PointOfSaleOutboundProfile
      end as PointOfSaleOutboundProfile,      

      case when _SiteMaster.posws is not null
            then _SiteMaster.posws
      else
            _SiteMasterCustomizing.PointOfSaleCurrency end        as PointOfSaleCurrency,

      case when _SiteMaster.autob is not null
            then _SiteMaster.autob
      else
            _SiteMasterCustomizing.OrderConversionIsAutomatic end as OrderConversionIsAutomatic,

      _SiteMaster.nlmatfb                                         as SubsequentListingIsActive,
      _PointOfSaleInboundProfileT,
      _PointOfSaleOutboundProfileT,
      _CurrencyText,
      _SiteProfile,
      _SiteMasterCustomizing,
      _TransportationZoneText,
      _SiteTaxClassificationText,

      _SiteDistributionProfileText,
      _SiteLevelConditionText,
      _SalesAreaDeterminationText,
      _ControlCrdtOfCostCentersText,
      _RevaluationProfileText,
      _InventoryProfileText,
      _PriceControlText,
      _ConsumptionActivityText,
      _SalesOrgPriceText,
      _DistributionChannelPriceText,
      _SubsequentListingText
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_SITEMASTERCUSTOMIZING",
"CKMLV",
"T001K",
"T001W",
"WRF1"
],
"ASSOCIATED":
[
"I_CONTROLCRDTOFCOSTCENTERSTEXT",
"I_CURRENCYTEXT",
"I_DISTRIBUTIONCHANNELTEXT",
"I_POINTOFSALEINBOUNDPROFILET",
"I_POINTOFSALEOUTBOUNDPROFILET",
"I_PRODUCTPRICEDETNCTRLTXT",
"I_SALESAREADETERMINATIONTEXT",
"I_SALESORGANIZATIONTEXT",
"I_SITECONSUMPTIONACTYUPDTTXT",
"I_SITEDISTRIBUTIONPROFILETEXT",
"I_SITEINVENTORYMGMTPROFILETEXT",
"I_SITELEVELCONDITIONTEXT",
"I_SITEMASTERCUSTOMIZING",
"I_SITEPROFILE",
"I_SITEREVALUATIONPROFILETEXT",
"I_SITETAXCLASSIFICATIONTEXT",
"I_SUBSEQUENTLISTINGTEXT",
"I_TRANSPORTATIONZONETEXT"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/