I_ShiftNoteAttachment

@AccessControl.authorizationCheck: #MANDATORY
@AccessControl.personalData.blocking: #NOT_REQUIRED
@EndUserText.label: 'Shift Note Attachment'
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.modelingPattern: #NONE
@ObjectModel.supportedCapabilities: [#CDS_MODELING_DATA_SOURCE, #SQL_DATA_SOURCE]
@ObjectModel.usageType: {serviceQuality: #C,sizeCategory: #L, dataClass: #TRANSACTIONAL}
@VDM.lifecycle.contract.type: #PUBLIC_LOCAL_API
@VDM.viewType: #COMPOSITE

define view entity I_ShiftNoteAttachment
  as select from   I_ShiftNoteDocumentLink        as doclink
    inner join     I_DocumentInfoRecordAttachment as attachm on  attachm.DocumentInfoRecordDocType    = doclink.DocumentInfoRecordDocType
                                                             and attachm.DocumentInfoRecordDocVersion = doclink.DocumentInfoRecordDocVersion
                                                             and attachm.DocumentInfoRecordDocNumber  = doclink.DocumentInfoRecordDocNumber
                                                             and attachm.DocumentInfoRecordDocPart    = doclink.DocumentInfoRecordDocPart
{
  key attachm.DocumentInfoRecordDocType,
  key attachm.DocumentInfoRecordDocVersion,
  key attachm.DocumentInfoRecordDocNumber,
  key attachm.DocumentInfoRecordDocPart,
  key attachm.DocumentIndex,
  key cast(attachm.FileUUID as edoc_file_guid preserving type)        as FileUUID,
  key attachm.PhysicalDocument,

      // Attachment admin data

      @Semantics.systemDateTime.createdAt: true
      cast(attachm.CreationDateTime as hp_created_at preserving type) as CreationDateTime,
      @Semantics.user.createdBy: true
      attachm.CreatedByUser,
      @Semantics.systemDateTime.lastChangedAt: true
      cast(attachm.ChangedDateTime as hp_changed_at preserving type)  as ChangedDateTime,
      @Semantics.user.lastChangedBy: true
      attachm.LastChangedByUser,
      attachm.OriginalCheckedOutTime                                  as OriginalCheckedOutDateTime,
      attachm.OriginalCheckedOutUser,

      // Attachment details

      cast(attachm.FileName as filen_type preserving type)            as FileName,
      attachm.FileSize,
      attachm.WorkstationApplication,
      attachm.MimeType,
      attachm.StorageCategory,
      cast(attachm.OriginalIsProtected as pp_cvflag preserving type)  as OriginalIsProtected,
      attachm.DocumentTitle,
      attachm.DocumentFormat,

      // LOIO and PHIO Details

      attachm.LogicalDocument,
      attachm.LogicalDocumentClass,
      attachm.PhysicalDocumentClass,
      @Semantics.booleanIndicator: true
      attachm.LogicalDocumentIsReference,
      attachm.OriginalType,
      attachm.PhysicalDocTechnicalStatus,
      @Semantics.text: true
      attachm.InternalComment

};
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_DOCUMENTINFORECORDATTACHMENT",
"I_SHIFTNOTEDOCUMENTLINK"
],
"ASSOCIATED":
[],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/