I_SettlmtRefDocCatText

DDL: I_SETTLMTREFDOCCATTEXT Type: view_entity BASIC

Reference Document Category - Text

I_SettlmtRefDocCatText is a Basic CDS View that provides data about "Reference Document Category - Text" in SAP S/4HANA. It reads from 1 data source (dd07t) and exposes 6 fields with key fields SettlmtRefDocCat, Language. It has 1 association to related views.

1 data source(s) 6 fields

Data Sources (1)

SourceAliasJoin Type
dd07t dd07t from

Associations (1)

CardinalityTargetAliasCondition
[0..1] I_Language _Language $projection.Language = _Language.Language

Annotations (14)

NameValueLevelField
EndUserText.label Reference Document Category - Text view
AccessControl.authorizationCheck #NOT_REQUIRED view
ObjectModel.dataCategory #TEXT view
ObjectModel.representativeKey SettlmtRefDocCat view
ObjectModel.modelingPattern #LANGUAGE_DEPENDENT_TEXT view
ObjectModel.usageType.dataClass #META view
ObjectModel.usageType.serviceQuality #A view
ObjectModel.usageType.sizeCategory #S view
VDM.viewType #BASIC view
VDM.lifecycle.contract.type #PUBLIC_LOCAL_API view
Search.searchable true view
Analytics.dataExtraction.enabled false view
Analytics.technicalName IWLFREFDOCCATT view
Metadata.ignorePropagatedAnnotations true view

Fields (6)

KeyFieldSource TableSource FieldDescription
KEY SettlmtRefDocCat
KEY Language
DomainValue dd07t domvalue_l
SettlmtRefDocCatName
_SettlmtRefDocCat _SettlmtRefDocCat
_Language _Language 
@EndUserText.label: 'Reference Document Category - Text'
@AccessControl: {
  authorizationCheck: #NOT_REQUIRED
}
@ObjectModel: {
  dataCategory: #TEXT,
  representativeKey: 'SettlmtRefDocCat',
  modelingPattern : #LANGUAGE_DEPENDENT_TEXT,
  supportedCapabilities :  [#LANGUAGE_DEPENDENT_TEXT,
                            #SQL_DATA_SOURCE,
                            #CDS_MODELING_DATA_SOURCE,
                            #CDS_MODELING_ASSOCIATION_TARGET,
                            #SEARCHABLE_ENTITY ],
  usageType: {
    dataClass:      #META,
    serviceQuality: #A,
    sizeCategory:   #S
  }
}
@VDM: {
  viewType: #BASIC,
  lifecycle.contract.type: #PUBLIC_LOCAL_API
}
@Search.searchable: true
@Analytics: {
  dataExtraction.enabled: false, 
  technicalName: 'IWLFREFDOCCATT'
} 
@Metadata: {
  ignorePropagatedAnnotations: true
}

/*+[hideWarning] { "IDS" : [ "KEY_CHECK", "CALCULATED_FIELD_CHECK" ]  } */
define view entity I_SettlmtRefDocCatText
  as select from dd07t

  association        to parent I_SettlmtRefDocCat as _SettlmtRefDocCat on $projection.SettlmtRefDocCat = _SettlmtRefDocCat.SettlmtRefDocCat
  association [0..1] to I_Language                as _Language         on $projection.Language = _Language.Language

{
      @ObjectModel.foreignKey.association: '_SettlmtRefDocCat'
      @ObjectModel.text.element: ['SettlmtRefDocCatName']
  key cast( substring(dd07t.domvalue_l, 1, 2) as wlf_ref_type preserving type ) as SettlmtRefDocCat,
      @ObjectModel.foreignKey.association: '_Language'
      @Semantics.language: true
  key cast( dd07t.ddlanguage as spras preserving type )                         as Language,
      @Analytics.hidden: true
      @Consumption.hidden: true
      dd07t.domvalue_l                                                          as DomainValue,
      @Search.defaultSearchElement: true
      @Search.fuzzinessThreshold: 0.8
      @Search.ranking: #LOW
      @Semantics.text: true
      cast( dd07t.ddtext as wlf_ref_type_text preserving type )                 as SettlmtRefDocCatName,

      /* Associations */
      _SettlmtRefDocCat,
      _Language
}

where
      dd07t.domname  = 'WLF_REF_TYPE'
  and dd07t.as4local = 'A'
  and dd07t.as4vers  = '0000'
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"DD07T"
],
"ASSOCIATED":
[
"I_LANGUAGE",
"I_SETTLMTREFDOCCAT"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/

Learn More