I_SettlementUnitHeaderDetail

/*---------------------------------------------------------------------*
* Copyright  2012 SAP AG. All rights reserved                          *
*----------------------------------------------------------------------*
* CDS Name                : I_SettlementUnitHeaderDetail               *
* CDS Description         : Interface View For Settlement Unit Detail  *
*                           And Header Tab Triggered From Settlement   *
*                           Unit Tab                                   *
*---------------------------------------------------------------------*/
@AbapCatalog.sqlViewName: 'ISTLUNITHDRDET'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #CHECK
@ClientHandling.type: #INHERITED
@ClientHandling.algorithm: #SESSION_VARIABLE
@VDM.viewType: #COMPOSITE
@ObjectModel.usageType.dataClass: #MIXED
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.supportedCapabilities: #CDS_MODELING_DATA_SOURCE
@ObjectModel.usageType.sizeCategory: #XL
@AccessControl.personalData.blocking: #NOT_REQUIRED
@Metadata.ignorePropagatedAnnotations: true
@EndUserText.label: 'Interface for Settlement Unit Header Details'
define view I_SettlementUnitHeaderDetail
  as select from    I_SettlementDocumentHeader                                       as _SettlmtDocHead
    left outer join P_GenericDomainVH( p_domain_name: 'WLF_PR_SIDE')                 as _Side                   on _Side.DomainValue = _SettlmtDocHead.Side
    left outer join P_GenericDomainVH( p_domain_name: '/ACCGO/D_SETTL_CAT')          as _SettlementCategory     on _SettlementCategory.DomainValue = _SettlmtDocHead.ACMReferenceSettlementCategory
    left outer join P_GenericDomainVH( p_domain_name: 'LAND1')                       as _CountryName            on _CountryName.DomainValue = _SettlmtDocHead.CustomerCountryKey
    left outer join P_GenericDomainVH( p_domain_name: '/ACCGO/D_SETTL_SCENARIO')     as _SettlementScenarioName on _SettlementScenarioName.DomainValue = SettlementScenario
    left outer join P_GenericDomainVH( p_domain_name: '/ACCGO/D_DPQS_IN_SETTLEMENT') as _DPQSInSettlement       on _DPQSInSettlement.DomainValue = DPQSinSettlementIndicator
  association [0..1] to I_ACMSettlementDocumentTypeTxt as _DocType              on  _DocType.ACMSettlementDocumentType = _SettlmtDocHead.ACMSettlementDocumentType
                                                                                and _DocType.Language                  = $session.system_language
  association [0..1] to P_TradingContractCounterparty  as _CounterpartyPurchase on  _CounterpartyPurchase.Counterparty = _SettlmtDocHead.ReferenceVendor
  association [0..1] to P_TradingContractCounterparty  as _CounterpartySales    on  _CounterpartySales.Counterparty = _SettlmtDocHead.SoldToParty
  association [0..1] to I_RegionText                   as _RegionText           on  _RegionText.Country  = _SettlmtDocHead.CustomerCountryKey
                                                                                and _RegionText.Region   = _SettlmtDocHead.Region
                                                                                and _RegionText.Language = $session.system_language
{
  key SettlementDocHeaderUUID,
      SettlmtDoc,
      SettlmtDocYear,
      ContractApplicationDocument,
      SoldToParty,
      PayerParty,
      BillToParty,
      ReferenceVendor,
      ReferencePayer,

      case
        when ReferenceVendor is not initial
          then ReferenceVendor
        when SoldToParty is not initial
          then SoldToParty
        else ''
      end                                    as ACMSettlementDocReferenceParty,

      case
        when _CounterpartyPurchase.CounterpartyFullName is not initial
          then _CounterpartyPurchase.CounterpartyFullName
        when _CounterpartySales.CounterpartyFullName is not initial
          then _CounterpartySales.CounterpartyFullName
        else ''
      end                                    as CounterpartyFullName,

      ACMSettlementDocumentType,
      _DocType.ApplicationDocTypeDescription as ApplicationDocTypeDescription,
      ACMReferenceSettlementCategory,
      _SettlementCategory.DomainText         as DocumentCategoryText,
      CustomerCountryKey,
      _CountryName.DomainText                as CompanyCountryName,
      _SettlmtDocHead.Region                 as Region,
      _RegionText.RegionName                 as RegionName,
      ABDNumber,
      Side,
      _Side.DomainText                       as DocumentSide,
      SettlementScenario,
      _SettlementScenarioName.DomainText     as SettlementScenarioName,
      SettlementPostingDate,
      @Semantics.currencyCode: true
      SettlementCurrency,
      @Semantics.amount.currencyCode: 'SettlementCurrency'
      ACMSettlementUnitNetAmount,
      @Semantics.amount.currencyCode: 'SettlementCurrency'
      ACMSettlementUnitNetAmount             as ACMSettlementNetOrderAmount,
      @Semantics.amount.currencyCode: 'SettlementCurrency'
      ACMSettlementUnitGrossAmount,
      ThresholdPercentage,
      _DPQSInSettlement.DomainText           as ACMSettlementDPQSIndicatorText,
      DPQSinSettlementIndicator,
      ACMSettlementUnitIsIgnoreDPQS,
      ACMSettlmtIsFnlSeparateInvcFee,
      ContractApplicationUUID,
      ContractApplicationVersion,
      ApplItemCreatedOnDateTime,
      PrepaymentStopIntrstDate,
      PrepaymentSuspendIntrstFromDte,
      PrepaymentSuspendIntrstToDte

}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_ACMSETTLEMENTDOCUMENTTYPETXT",
"I_REGIONTEXT",
"I_SETTLEMENTDOCUMENTHEADER",
"P_GENERICDOMAINVH",
"P_TRADINGCONTRACTCOUNTERPARTY"
],
"ASSOCIATED":
[
"I_ACMSETTLEMENTDOCUMENTTYPETXT",
"I_REGIONTEXT",
"P_TRADINGCONTRACTCOUNTERPARTY"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/