I_ServiceDocumentSuccessor

@ClientHandling.algorithm: #SESSION_VARIABLE
@EndUserText.label: 'Follow-Up Service Transaction'
@VDM: {
  viewType: #BASIC,
  lifecycle.contract.type: #PUBLIC_LOCAL_API
}

@Analytics: {
    dataCategory: #FACT,
    dataExtraction: {
        enabled: true,
        delta.changeDataCapture: {
            mapping:[
                {
//                   filter: [{operator: #EQ, tableElement: 'objtype_a', value: 'BUS2000%'}],

                    table: 'crmd_brelvonae', role: #MAIN,
                    viewElement: ['ServiceDocumentRelationUUID', 'ServiceDocRltnSequenceNumber'],
                    tableElement: ['relationid', 'posno']
                }
            ]
        }
    }
 }

@AccessControl: {
  authorizationCheck: #CHECK,
  personalData.blocking: #('TRANSACTIONAL_DATA')
}

@AbapCatalog: {
  sqlViewName: 'ISERVDOCSUCC',
  compiler.compareFilter: true,
  preserveKey: true
}

@ObjectModel: {
//   representativeKey: 'ServiceDocumentRelationUUID',

   usageType: {
     dataClass:      #TRANSACTIONAL,
     serviceQuality: #B,
     sizeCategory:   #XL
   },
   supportedCapabilities: [#CDS_MODELING_DATA_SOURCE, #SQL_DATA_SOURCE, #CDS_MODELING_ASSOCIATION_TARGET, #EXTRACTION_DATA_SOURCE]
}
//@Metadata.allowExtensions:true

@Metadata.ignorePropagatedAnnotations: true
/*
If there is any new Business object addition in service document view (e.g. BUS200016 )
then the same business object has to be added in DCL "I_ServiceDocumentSuccessor" as well.
*/
define view I_ServiceDocumentSuccessor
  as select from crmd_brelvonae

  association [1] to I_ServiceDocumentEnhcd as _ServiceDoc on  $projection.ServiceDocumentSuccessorUUID  = _ServiceDoc.ServiceDocumentUUID
                                                           and $projection.ServiceDocSuccessorBusObjType = _ServiceDoc.ServiceObjectType

{

  key relationid    as ServiceDocumentRelationUUID,
  key posno         as ServiceDocRltnSequenceNumber,
      breltyp       as ServiceDocumentRelationType,

      /* CRMT_BRELVONAE */
      objguid_a_sel as ServiceDocumentUUID,
      objtype_a_sel as ServiceObjectType,

      vona_kind     as ServiceDocumentRelationKind,

      objguid_b_sel as ServiceDocumentSuccessorUUID,
      objkey_b_sel  as ServiceDocSuccessor,
      objtype_b_sel as ServiceDocSuccessorBusObjType,

      //Associations

      _ServiceDoc

}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"CRMD_BRELVONAE"
],
"ASSOCIATED":
[
"I_SERVICEDOCUMENTENHCD"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/