I_ServiceDocumentItemSuccessor

@EndUserText.label: 'Service Document Item Successor'
@ClientHandling.algorithm: #SESSION_VARIABLE

@VDM: {
  viewType: #BASIC,
  lifecycle.contract.type: #PUBLIC_LOCAL_API,
  lifecycle.status: #DEPRECATED,
  lifecycle.successor: 'I_ServiceDocumentItemSuccssr_2'
}
@AccessControl: {
  authorizationCheck: #CHECK,
  personalData.blocking: #('TRANSACTIONAL_DATA')
}
@AbapCatalog: {
  sqlViewName: 'ISERVDOCITMSUCC',
  compiler.compareFilter: true ,
  preserveKey: true
}
@ObjectModel: {
//   representativeKey: 'ServiceDocumentItmRelationUUID',

   usageType: {
     dataClass:      #TRANSACTIONAL,
     serviceQuality: #A,
     sizeCategory:   #XL
   }
}

//@Analytics.dataCategory: #DIMENSION

//@Metadata.allowExtensions:true

@Metadata.ignorePropagatedAnnotations: true

/*
  1902 CE: Data preview might give you an error because hextobin conversion may not work on properly on junk data. Hence dump occurs.
  To view the data, you have to apply the condition "CharcLength = 32" to get the results for Service scenario only.

  1911 CE: DO not use hextobin converted attribute.

*/

/*
If there is any new Business object addition in service document view (e.g. BUS2000116 )
then the same business object has to be added in DCL "I_ServiceDocumentItemSuccessor" as well.
*/

/* !!!DONOT USE THIS VIEW. SOON IT IS GOING TO BE DEPRECATED!!! */

define view I_ServiceDocumentItemSuccessor
  as select from crmd_brelvonai
  association [1]    to I_ServiceDocumentItemEnhcd as _ServiceDocItm       on  $projection.ServiceDocItmSuccessorUUID     = _ServiceDocItm.ServiceDocumentItemUUID
                                                                           and $projection.ServiceDocItmSuccssrBusObjType = _ServiceDocItm.ServiceDocumentItemObjectType

  association [0..1] to I_UnitOfMeasure            as _BaseUnit            on  $projection.SrvcDocItmDocFlowQuantityUnit = _BaseUnit.UnitOfMeasure

  association [0..1] to I_Currency                 as _TransactionCurrency on  $projection.SrvcDocItmDocFlowCurrency = _TransactionCurrency.Currency



{
  key relationid         as ServiceDocumentItmRelationUUID,
  key posno              as ServiceDocItmRltnSqncNumber,

      objkey_a           as ServiceDocumentItemCharUUID,
      objkey_b           as ServiceDocItmSuccssrCharUUID,

      breltyp            as ServiceDocumentItmRelationType,

      /* CRMT_BRELVONAI */
      length(objkey_a)   as CharcLength,
      hextobin(objkey_a) as ServiceDocumentItemUUID,
      objtype_a          as ServiceDocumentItemObjectType,
      vona_kind          as ServiceDocumentItmRelationKind,
      hextobin(objkey_b) as ServiceDocItmSuccessorUUID,
      objtype_b          as ServiceDocItmSuccssrBusObjType,


      @ObjectModel.foreignKey.association: '_BaseUnit'
      @Semantics.unitOfMeasure:true
      quantity_unit      as SrvcDocItmDocFlowQuantityUnit,
      //@DefaultAggregation: #SUM

      @Semantics: { quantity : {unitOfMeasure: 'SrvcDocItmDocFlowQuantityUnit'} }
      quantity           as SrvcDocItmDocFlowQuantity,

      //      @ObjectModel.foreignKey.association: '_TransactionCurrency'

      @API.element.releaseState: #DEPRECATED
      @Semantics.currencyCode:true
      currency           as SrvcDocItmDocFlowCurrency,
      @API.element.releaseState: #DEPRECATED
      @Semantics: { amount : {currencyCode: 'SrvcDocItmDocFlowCurrency'} }
      value              as SrvcDocumentItmDocFlowAmount,
      doc_info           as SrvcDocItmDocFlowBillingInfo,
      qty_difference     as SrvcDocItmDocFlowQtyIsDiffnt,

      //Associations

      _ServiceDocItm,
      _TransactionCurrency,
      _BaseUnit


}
where
     objtype_b like 'BUS2000%'
  or objtype_b =    'VBAP'
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"CRMD_BRELVONAI"
],
"ASSOCIATED":
[
"I_CURRENCY",
"I_SERVICEDOCUMENTITEMENHCD",
"I_UNITOFMEASURE"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/