I_SerialNumberStockSegment

@AbapCatalog.sqlViewName: 'ISERNUMSTOCKSEG' 
@AbapCatalog.preserveKey: true
@AbapCatalog.compiler.compareFilter: true
@EndUserText.label: 'Serial Number Stock Segment'
 
@VDM.viewType: #BASIC
@AccessControl.authorizationCheck: #CHECK 
@AccessControl.personalData.blocking: #REQUIRED 
@ObjectModel.representativeKey: 'SerialNumber'
@ObjectModel.semanticKey:  [ 'Material', 'SerialNumber' ] 
@ObjectModel.supportedCapabilities: [
  #SQL_DATA_SOURCE,
  #CDS_MODELING_DATA_SOURCE,
  #CDS_MODELING_ASSOCIATION_TARGET,
  #ANALYTICAL_DIMENSION
]

@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.usageType.dataClass: #MASTER
@ObjectModel.usageType.serviceQuality: #A
@ObjectModel.usageType.sizeCategory: #L

@Analytics: {dataCategory: #DIMENSION }

@Metadata.allowExtensions: true
@Metadata.ignorePropagatedAnnotations: true

define view I_SerialNumberStockSegment 
as select from I_EquipmentStockSegment as ess
  inner join I_Equipment as e
    on ess.Equipment = e.Equipment
{
  @ObjectModel.foreignKey.association: '_Material'
  key e.Material,
  
  key e.SerialNumber,
  
  @ObjectModel.foreignKey.association: '_Equipment'
  ess.Equipment,
         
  @ObjectModel.foreignKey.association: '_Plant'
  ess.Plant,   
  
  @ObjectModel.foreignKey.association: '_StorageLocation'
  ess.StorageLocation, 
     
  @ObjectModel.foreignKey.association: '_Customer'
  @Consumption.valueHelpDefinition: [
    { entity:  { name:    'I_Customer_VH',
                 element: 'Customer' }
    }]
  ess.Customer, 
  
  @ObjectModel.foreignKey.association: '_Supplier'
  @Consumption.valueHelpDefinition: [
    { entity:  { name:    'I_Supplier_VH',
                 element: 'Supplier' }
    }]
  ess.Supplier,  
  
  @ObjectModel.foreignKey.association: '_SalesOrder'
  @Consumption.valueHelpDefinition: [
    { entity:  { name:    'I_SalesOrderStdVH',
                 element: 'SalesOrder' }
    }]
  ess.SalesOrder, 
  
  @ObjectModel.foreignKey.association: '_SalesOrderItem'
  @Consumption.valueHelpDefinition: [
    { entity:  { name:    'I_SalesOrderItemStdVH',
                 element: 'SalesOrderItem' },
      additionalBinding: [{ localElement: 'SalesOrder',
                            element: 'SalesOrder' }]
    }]
  ess.SalesOrderItem,  
  
  @ObjectModel.foreignKey.association: '_InventorySpecialStockType'
  ess.InventorySpecialStockType,
    
  @ObjectModel.foreignKey.association: '_WBSElementByInternalKey'
  @Consumption.valueHelpDefinition: [
    { entity:  { name:    'I_WBSElmntByIntKeyStdVH',
                 element: 'WBSElementInternalID' }
    }]
  ess.WBSElementInternalID, 
  
  ess.Batch,     
  ess.InventoryStockType,    
  ess.StockOwner,
    
  // associations

  e._Material,
  ess._Equipment,
  ess._Plant,
  ess._StorageLocation,
  ess._SalesOrder,
  ess._SalesOrderItem,
  ess._Customer,
  ess._CustomerCompanyByPlant,
  ess._Supplier,
  ess._SupplierCompanyByPlant,
  ess._InventoryStockType,
  ess._InventorySpecialStockType,
  ess._WBSElementByInternalKey
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_EQUIPMENT",
"I_EQUIPMENTSTOCKSEGMENT"
],
"ASSOCIATED":
[
"I_CUSTOMER",
"I_CUSTOMERCOMPANYBYPLANT",
"I_EQUIPMENT",
"I_INVENTORYSPECIALSTOCKTYPE",
"I_INVENTORYSTOCKTYPE",
"I_MATERIAL",
"I_PLANT",
"I_SALESORDER",
"I_SALESORDERITEM",
"I_STORAGELOCATION",
"I_SUPPLIER",
"I_SUPPLIERCOMPANYBYPLANT",
"I_WBSELEMENTBYINTERNALKEY"
],
"BASE":
[
"I_EQUIPMENT",
"I_EQUIPMENTSTOCKSEGMENT"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/