I_SaraDailyChemicalProductQty

@AbapCatalog: { sqlViewName: 'ISARAPRODQTY',
                compiler.compareFilter: true,
                preserveKey: true }
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'SARA: Daily Chemical Product Quantity'
@ClientHandling.algorithm: #SESSION_VARIABLE
@AccessControl.personalData.blocking: #NOT_REQUIRED  
@VDM.viewType: #COMPOSITE
@VDM.lifecycle.status: #DEPRECATED
@VDM.lifecycle.successor: 'I_DailyChmlProductStkQty'
@ObjectModel:
{
  usageType:
  {
    dataClass: #MIXED,
    sizeCategory: #XL,
    serviceQuality: #D
  }
}            
@DataAging.noAgingRestriction:true
define view I_SaraDailyChemicalProductQty 
   with parameters
    P_StartDate  : vdm_v_start_date,
    P_EndDate    : vdm_v_end_date,
    P_PeriodType : nsdm_period_type
  as select from I_MaterialStockTimeSeries(P_StartDate:  :P_StartDate,
                                           P_EndDate:    :P_EndDate,
                                           P_PeriodType: :P_PeriodType)    as _MaterialStock
  inner join    I_ChemicalMaterial             as _ChemicalMaterial        on _ChemicalMaterial.Material              = _MaterialStock.Material  
 
  inner join    I_ChemicalRevision             as _ChemicalRevision        on _ChemicalMaterial.ChemicalRevisionUUID  = _ChemicalRevision.ChemicalRevisionUUID 
                                                                          and _ChemicalMaterial.ChemicalUUID          = _ChemicalRevision.ChemicalUUID     
                                        
  inner join    I_UnitOfMeasure                as _BaseUnit                on _MaterialStock.MaterialBaseUnit = _BaseUnit.UnitOfMeasure

  inner join    P_PLANTCURRENCY                as _CompanyCode             on _MaterialStock.Plant = _CompanyCode.Plant
  {
      @Semantics.businessDate.at: true
      @Semantics.businessDate.to: false  -- switch of semantic inherited from one of the lower view in the stack  
  key _MaterialStock.EndDate            as EndDate,
      // Stock Identifier

      @ObjectModel.foreignKey.association: '_Material'
  key _MaterialStock.Material           as Material,
      @ObjectModel.foreignKey.association: '_Plant'
  key _MaterialStock.Plant              as Plant,
      @ObjectModel.foreignKey.association: '_StorageLocation'
  key _MaterialStock.StorageLocation    as StorageLocation,
  
      @Semantics.unitOfMeasure
      _MaterialStock.MaterialBaseUnit   as ProductBaseUnit,
      
      // Quantity

      @Semantics.quantity.unitOfMeasure: 'ProductBaseUnit'
      @DefaultAggregation : #SUM
      sum(MatlWrhsStkQtyInMatlBaseUnit) as Quantity,
      
       _ChemicalMaterial.ChemicalUUID   as ChemicalUUID,
       _CompanyCode.CompanyCode         as CompanyCode,
       _MaterialStock._Material,
       _MaterialStock._StorageLocation,
       _MaterialStock._Plant
}
where PeriodType = :P_PeriodType  
and   InventoryStockType = '01'   
and   MatlWrhsStkQtyInMatlBaseUnit is not initial
and   _ChemicalRevision.RevisionStartDate <= $session.system_date
and   _ChemicalRevision.RevisionEndDate   >= $session.system_date
  
group by
_MaterialStock.EndDate,
_MaterialStock.Material,
_MaterialStock.Plant,
_MaterialStock.StorageLocation,
_MaterialStock.MaterialBaseUnit,                               
_ChemicalMaterial.ChemicalUUID,
_CompanyCode.CompanyCode 
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_CHEMICALMATERIAL",
"I_CHEMICALREVISION",
"I_MATERIALSTOCKTIMESERIES",
"I_UNITOFMEASURE",
"P_PLANTCURRENCY"
],
"ASSOCIATED":
[
"I_MATERIAL",
"I_PLANT",
"I_STORAGELOCATION"
],
"BASE":
[
"I_MATERIALSTOCKTIMESERIES"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/