I_SalesQuotationItemPartner

DDL: I_SALESQUOTATIONITEMPARTNER Type: view COMPOSITE

Sales Quotation Item Partner

I_SalesQuotationItemPartner is a Composite CDS View that provides data about "Sales Quotation Item Partner" in SAP S/4HANA. It reads from 1 data source (I_SalesDocumentItemPartner) and exposes 18 fields with key fields SalesQuotation, SalesQuotationItem, PartnerFunction.

1 data source(s) 18 fields

Data Sources (1)

SourceAliasJoin Type
I_SalesDocumentItemPartner Partner from

Annotations (12)

NameValueLevelField
ClientHandling.algorithm #SESSION_VARIABLE view
EndUserText.label Sales Quotation Item Partner view
VDM.viewType #COMPOSITE view
VDM.lifecycle.contract.type #PUBLIC_LOCAL_API view
AccessControl.authorizationCheck #CHECK view
AbapCatalog.sqlViewName ISDSLSQTANITMPT view
AbapCatalog.compiler.compareFilter true view
ObjectModel.representativeKey PartnerFunction view
ObjectModel.usageType.dataClass #TRANSACTIONAL view
ObjectModel.usageType.serviceQuality #B view
ObjectModel.usageType.sizeCategory #XL view
Metadata.ignorePropagatedAnnotations true view

Fields (18)

KeyFieldSource TableSource FieldDescription
KEY SalesQuotation
KEY SalesQuotationItem
KEY PartnerFunction PartnerFunction
Customer Customer
Supplier Supplier
Personnel Personnel
AddressID AddressID
AddressPersonID AddressPersonID
AddressObjectType AddressObjectType
SDDocPartnerAddressRefType SDDocPartnerAddressRefType
ContactPerson ContactPerson
ReferenceBusinessPartner ReferenceBusinessPartner
_SalesQuotation _SalesQuotation
_SalesQuotationItem _SalesQuotationItem
_PartnerFunction _PartnerFunction
_Address _Address
_DfltAddrRprstn _DfltAddrRprstn
_BusinessPartnerAddress _BusinessPartnerAddress 
@ClientHandling.algorithm: #SESSION_VARIABLE 
@EndUserText.label: 'Sales Quotation Item Partner'
@VDM: {
  viewType: #COMPOSITE,
  lifecycle.contract.type: #PUBLIC_LOCAL_API
}
@AccessControl: { 
  authorizationCheck: #CHECK,
  personalData.blocking: #('TRANSACTIONAL_DATA'),
  privilegedAssociations: [ '_Address','_DfltAddrRprstn' ]
}
@AbapCatalog: {
  sqlViewName: 'ISDSLSQTANITMPT',
  compiler.compareFilter: true
}
@ObjectModel: {
  representativeKey: 'PartnerFunction',
  usageType: {
    dataClass:      #TRANSACTIONAL,
    serviceQuality: #B,
    sizeCategory:   #XL
   },
   supportedCapabilities: [ #SQL_DATA_SOURCE, #CDS_MODELING_DATA_SOURCE, #CDS_MODELING_ASSOCIATION_TARGET]
}
@Metadata.ignorePropagatedAnnotations: true

define view I_SalesQuotationItemPartner as select from I_SalesDocumentItemPartner  as Partner
      
    association[1..1] to I_SalesQuotation      as _SalesQuotation      on  $projection.SalesQuotation     = _SalesQuotation.SalesQuotation 
    association[1..1] to I_SalesQuotationItem  as _SalesQuotationItem  on  $projection.SalesQuotation     = _SalesQuotationItem.SalesQuotation  
                                                                       and $projection.SalesQuotationItem = _SalesQuotationItem.SalesQuotationItem  
    
{
        @ObjectModel.foreignKey.association: '_SalesQuotation'                                                                                                   
    key cast(SalesDocument as sales_quotation preserving type) as SalesQuotation,             
        @ObjectModel.foreignKey.association: '_SalesQuotationItem'                                                                                                   
    key cast(SalesDocumentItem as sales_quotation_item preserving type) as SalesQuotationItem,   
        @ObjectModel.foreignKey.association: '_PartnerFunction'     
    key PartnerFunction,       
        Customer,          
        Supplier,           
        Personnel,    
        @ObjectModel.foreignKey.association: '_Address' 
        AddressID,
        AddressPersonID,
        AddressObjectType,
        SDDocPartnerAddressRefType,
        ContactPerson,
        ReferenceBusinessPartner,
        
        //Association

        @ObjectModel.association.type: [#TO_COMPOSITION_ROOT]    
        _SalesQuotation,
        @ObjectModel.association.type: [#TO_COMPOSITION_PARENT]    
        _SalesQuotationItem, 
        _PartnerFunction,
        _Address,
        _DfltAddrRprstn,
        _BusinessPartnerAddress

}
where SDDocumentCategory = 'B';         
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_SALESDOCUMENTITEMPARTNER"
],
"ASSOCIATED":
[
"I_ADDRESS",
"I_ADDRESS_2",
"I_BUSPARTADDRESS",
"I_PARTNERFUNCTION",
"I_SALESQUOTATION",
"I_SALESQUOTATIONITEM"
],
"BASE":
[
"I_SALESDOCUMENTITEMPARTNER"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/

Learn More