I_SalesOrganizationUnit

DDL: I_SALESORGANIZATIONUNIT Type: view BASIC

Sales Organizational Unit

I_SalesOrganizationUnit is a Basic CDS View (Dimension) that provides data about "Sales Organizational Unit" in SAP S/4HANA. It reads from 1 data source (t77s0) and exposes 5 fields with key field OrganizationalUnit. It has 2 associations to related views.

1 data source(s) 5 fields

Data Sources (1)

SourceAliasJoin Type
t77s0 systemtable inner

Associations (2)

CardinalityTargetAliasCondition
[0..*] I_SalesOrganizationUnitText _Text $projection.OrganizationalUnit = _Text.OrganizationalUnit
[0..*] I_SalesOrganizationUnitText _TextCurrent $projection.OrganizationalUnit = _TextCurrent.OrganizationalUnit and $projection.StartDate = _TextCurrent.StartDate and $projection.EndDate = _TextCurrent.EndDate

Annotations (16)

NameValueLevelField
EndUserText.label Sales Organizational Unit view
ClientHandling.algorithm #SESSION_VARIABLE view
AbapCatalog.sqlViewName ISALESORGUNIT view
AbapCatalog.compiler.compareFilter true view
AbapCatalog.preserveKey true view
VDM.viewType #BASIC view
VDM.lifecycle.contract.type #PUBLIC_LOCAL_API view
AccessControl.authorizationCheck #NOT_REQUIRED view
ObjectModel.representativeKey OrganizationalUnit view
ObjectModel.usageType.dataClass #CUSTOMIZING view
ObjectModel.usageType.serviceQuality #A view
ObjectModel.usageType.sizeCategory #L view
Search.searchable true view
Metadata.allowExtensions true view
Metadata.ignorePropagatedAnnotations true view
Analytics.dataCategory #DIMENSION view

Fields (5)

KeyFieldSource TableSource FieldDescription
KEY OrganizationalUnit objid
StartDate begda
EndDate endda
_Text _Text
_TextCurrent _TextCurrent 
@EndUserText.label: 'Sales Organizational Unit'
@ClientHandling.algorithm: #SESSION_VARIABLE
@AbapCatalog: {
  sqlViewName: 'ISALESORGUNIT',
  compiler.compareFilter: true,
  preserveKey: true
}
@VDM: {
  viewType: #BASIC,
  lifecycle.contract.type: #PUBLIC_LOCAL_API
}
@AccessControl.authorizationCheck: #NOT_REQUIRED

@ObjectModel: {
   representativeKey: 'OrganizationalUnit',
   usageType: {
     dataClass:      #CUSTOMIZING,
     serviceQuality: #A,
     sizeCategory:   #L
   },
   supportedCapabilities: [ #ANALYTICAL_DIMENSION, #CDS_MODELING_ASSOCIATION_TARGET, #SQL_DATA_SOURCE, #CDS_MODELING_DATA_SOURCE ]
}
@Search.searchable: true
@Metadata.allowExtensions: true
@Metadata.ignorePropagatedAnnotations: true
@Analytics.dataCategory: #DIMENSION

define view I_SalesOrganizationUnit
  as select distinct from hrp1000
    inner join            t77s0   as systemtable on  grpid = 'PLOGI'
                                                 and semid = 'PLOGI'
                                                 and gsval = hrp1000.plvar
  association [0..*] to I_SalesOrganizationUnitText as _Text on $projection.OrganizationalUnit = _Text.OrganizationalUnit
  association [0..*] to I_SalesOrganizationUnitText as _TextCurrent on $projection.OrganizationalUnit = _TextCurrent.OrganizationalUnit
                                                                   and $projection.StartDate          = _TextCurrent.StartDate
                                                                   and $projection.EndDate            = _TextCurrent.EndDate

{
      @Search.defaultSearchElement: true
      @ObjectModel.text.association: '_Text'
      @Search.fuzzinessThreshold: 0.8
      @Search.ranking: #HIGH
  key objid         as OrganizationalUnit,
      otjid         as OrgUnitTypeIDConcatenated,
      begda         as StartDate,
      endda         as EndDate,

      _Text,
      _TextCurrent
}

where
      hrp1000.otype = 'O'
  and hrp1000.istat = '1'
  and begda         <= $session.system_date
  and endda         >= $session.system_date
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"HRP1000",
"T77S0"
],
"ASSOCIATED":
[
"I_SALESORGANIZATIONUNITTEXT"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/

Learn More