I_SalesOrderPricingElement

DDL: I_SALESORDERPRICINGELEMENT Type: view BASIC

Sales Order Pricing Element

I_SalesOrderPricingElement is a Basic CDS View that provides data about "Sales Order Pricing Element" in SAP S/4HANA. It reads from 1 data source (I_SalesDocumentPricingElement) and exposes 65 fields with key fields SalesOrder, PricingProcedureStep, PricingProcedureCounter.

1 data source(s) 65 fields

Data Sources (1)

SourceAliasJoin Type
I_SalesDocumentPricingElement PricingElement from

Annotations (11)

NameValueLevelField
ClientHandling.algorithm #SESSION_VARIABLE view
EndUserText.label Sales Order Pricing Element view
VDM.viewType #BASIC view
VDM.lifecycle.contract.type #PUBLIC_LOCAL_API view
AccessControl.authorizationCheck #CHECK view
AbapCatalog.sqlViewName ISDSLSORDPREL view
AbapCatalog.compiler.compareFilter true view
ObjectModel.usageType.dataClass #TRANSACTIONAL view
ObjectModel.usageType.serviceQuality #B view
ObjectModel.usageType.sizeCategory #XL view
Metadata.ignorePropagatedAnnotations true view

Fields (65)

KeyFieldSource TableSource FieldDescription
KEY SalesOrder
KEY PricingProcedureStep PricingProcedureStep
KEY PricingProcedureCounter PricingProcedureCounter
ConditionApplication ConditionApplication
ConditionType ConditionType
PricingDateTime PricingDateTime
PriceConditionDeterminationDte PriceConditionDeterminationDte
ConditionCalculationType ConditionCalculationType
ConditionBaseValue ConditionBaseValue
ConditionRateValue ConditionRateValue
ConditionCurrency ConditionCurrency
ConditionQuantity ConditionQuantity
ConditionQuantityUnit ConditionQuantityUnit
ConditionCategory ConditionCategory
ConditionIsForStatistics ConditionIsForStatistics
PricingScaleType PricingScaleType
IsRelevantForAccrual IsRelevantForAccrual
CndnIsRelevantForInvoiceList CndnIsRelevantForInvoiceList
ConditionOrigin ConditionOrigin
IsGroupCondition IsGroupCondition
ConditionRecord ConditionRecord
ConditionSequentialNumber ConditionSequentialNumber
TaxCode TaxCode
WithholdingTaxCode WithholdingTaxCode
CndnRoundingOffDiffAmount CndnRoundingOffDiffAmount
ConditionAmount ConditionAmount
TransactionCurrency TransactionCurrency
ConditionControl ConditionControl
ConditionInactiveReason ConditionInactiveReason
ConditionClass ConditionClass
PrcgProcedureCounterForHeader PrcgProcedureCounterForHeader
FactorForConditionBasisValue FactorForConditionBasisValue
StructureCondition StructureCondition
PeriodFactorForCndnBasisValue PeriodFactorForCndnBasisValue
PricingScaleBasis PricingScaleBasis
ConditionScaleBasisValue ConditionScaleBasisValue
ConditionScaleBasisUnit ConditionScaleBasisUnit
ConditionScaleBasisCurrency ConditionScaleBasisCurrency
CndnIsRelevantForIntcoBilling CndnIsRelevantForIntcoBilling
ConditionIsManuallyChanged ConditionIsManuallyChanged
ConditionIsForConfiguration ConditionIsForConfiguration
VariantCondition VariantCondition
ConditionRateAmount ConditionRateAmount
ConditionRateRatio ConditionRateRatio
ConditionRateRatioUnit ConditionRateRatioUnit
ConditionBaseAmount ConditionBaseAmount
ConditionBaseQuantity ConditionBaseQuantity
_SalesOrder _SalesOrder
_ConditionApplication _ConditionApplication
_PricingConditionType _PricingConditionType
_ConditionCalculationType _ConditionCalculationType
_ConditionCurrency _ConditionCurrency
_Currency _Currency
_ConditionQuantityUnit _ConditionQuantityUnit
_ConditionCategory _ConditionCategory
_ConditionOrigin _ConditionOrigin
_ConditionControl _ConditionControl
_ConditionInactiveReason _ConditionInactiveReason
_ConditionClass _ConditionClass
_PricingScaleBasis _PricingScaleBasis
_ScaleUnitOfMeasure _ScaleUnitOfMeasure
_ScaleCurrency _ScaleCurrency
_VariantCondition _VariantCondition
_StructureCondition _StructureCondition
_ConditionRateRatioUnit _ConditionRateRatioUnit 
@ClientHandling.algorithm: #SESSION_VARIABLE 
@EndUserText.label: 'Sales Order Pricing Element'
@VDM: {
  viewType: #BASIC,
  lifecycle.contract.type: #PUBLIC_LOCAL_API
}
@AccessControl: { 
  authorizationCheck: #CHECK,
  personalData.blocking: #('TRANSACTIONAL_DATA')
}
@AbapCatalog: {
  sqlViewName: 'ISDSLSORDPREL',
  compiler.compareFilter: true
}
@ObjectModel: {
   usageType: {
     dataClass:      #TRANSACTIONAL,
     serviceQuality: #B,
     sizeCategory:   #XL
   },
   supportedCapabilities: [ #SQL_DATA_SOURCE, #CDS_MODELING_DATA_SOURCE, #CDS_MODELING_ASSOCIATION_TARGET ]
}
@Metadata.ignorePropagatedAnnotations: true

define view I_SalesOrderPricingElement as select from I_SalesDocumentPricingElement       as PricingElement
      
    association[1..1] to I_SalesOrder   as _SalesOrder   on $projection.SalesOrder  = _SalesOrder.SalesOrder
 
{
      @ObjectModel.foreignKey.association: '_SalesOrder'                                                                                                   
  key cast(SalesDocument as vdm_sales_order preserving type) as SalesOrder,  
  key PricingProcedureStep,
  key PricingProcedureCounter, 
      @ObjectModel.foreignKey.association: '_ConditionApplication'
      ConditionApplication, 
      @ObjectModel.foreignKey.association: '_PricingConditionType'
      ConditionType,
      @VDM.lifecycle.status: #DEPRECATED
      @VDM.lifecycle.successor: 'PriceConditionDeterminationDte'
      PricingDateTime,
      PriceConditionDeterminationDte,
      @ObjectModel.foreignKey.association: '_ConditionCalculationType'
      ConditionCalculationType,
      ConditionBaseValue,
      ConditionRateValue,
      @ObjectModel.foreignKey.association: '_ConditionCurrency'
      ConditionCurrency,
      @DefaultAggregation:#NONE
      @Semantics.quantity.unitOfMeasure: 'ConditionQuantityUnit'
      ConditionQuantity,
      @Semantics.unitOfMeasure: true
      @ObjectModel.foreignKey.association: '_ConditionQuantityUnit'
      ConditionQuantityUnit,
      @ObjectModel.foreignKey.association: '_ConditionCategory'
      ConditionCategory,
      ConditionIsForStatistics,
      PricingScaleType,
      IsRelevantForAccrual,
      CndnIsRelevantForInvoiceList,
      @ObjectModel.foreignKey.association: '_ConditionOrigin'
      ConditionOrigin,
      IsGroupCondition,
      ConditionRecord,
      ConditionSequentialNumber,
      TaxCode,
      WithholdingTaxCode,
      @DefaultAggregation:#NONE
      @Semantics.amount.currencyCode: 'TransactionCurrency'
      CndnRoundingOffDiffAmount,
      @DefaultAggregation:#NONE
      @Semantics.amount.currencyCode: 'TransactionCurrency'
      ConditionAmount,
      @Semantics.currencyCode: true
      @ObjectModel.foreignKey.association: '_Currency'
      TransactionCurrency,
      @ObjectModel.foreignKey.association: '_ConditionControl'
      ConditionControl,
      @ObjectModel.foreignKey.association: '_ConditionInactiveReason'
      ConditionInactiveReason,
      @ObjectModel.foreignKey.association: '_ConditionClass'
      ConditionClass,
      PrcgProcedureCounterForHeader,
      FactorForConditionBasisValue,
      @ObjectModel.foreignKey.association: '_StructureCondition'
      StructureCondition,
      PeriodFactorForCndnBasisValue,
      @ObjectModel.foreignKey.association: '_PricingScaleBasis'
      PricingScaleBasis,
      ConditionScaleBasisValue,
      @Semantics.unitOfMeasure: true
      @ObjectModel.foreignKey.association: '_ScaleUnitOfMeasure'
      ConditionScaleBasisUnit,
      @Semantics.currencyCode: true
      @ObjectModel.foreignKey.association: '_ScaleCurrency'
      ConditionScaleBasisCurrency,
      CndnIsRelevantForIntcoBilling,
      ConditionIsManuallyChanged,
      ConditionIsForConfiguration,
      VariantCondition,
      @Semantics.amount.currencyCode: 'ConditionCurrency'
      @OData.v2.amount.noDecimalShift: true
      ConditionRateAmount,
      @Semantics.quantity.unitOfMeasure: 'ConditionRateRatioUnit'
      ConditionRateRatio,
      @Semantics.unitOfMeasure: true
      @ObjectModel.foreignKey.association: '_ConditionRateRatioUnit'
      ConditionRateRatioUnit,
      @Semantics.amount.currencyCode: 'TransactionCurrency'
      @OData.v2.amount.noDecimalShift: true
      ConditionBaseAmount,
      @Semantics.quantity.unitOfMeasure: 'ConditionQuantityUnit'
      ConditionBaseQuantity,  
      
      //Association

      @ObjectModel.association.type: [#TO_COMPOSITION_PARENT, #TO_COMPOSITION_ROOT]
      _SalesOrder,
      _ConditionApplication,
      _PricingConditionType,
      _ConditionCalculationType,
      _ConditionCurrency,
      _Currency, 
      _ConditionQuantityUnit,
      _ConditionCategory,
      _ConditionOrigin,
      _ConditionControl,
      _ConditionInactiveReason,
      _ConditionClass,
      _PricingScaleBasis,
      _ScaleUnitOfMeasure, 
      _ScaleCurrency, 
      _VariantCondition,
      _StructureCondition,
      _ConditionRateRatioUnit

}
where SDDocumentCategory = 'C';   
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_SALESDOCUMENTPRICINGELEMENT"
],
"ASSOCIATED":
[
"I_CONDITIONAPPLICATION",
"I_CONDITIONCALCULATIONTYPE",
"I_CONDITIONCATEGORY",
"I_CONDITIONCLASS",
"I_CONDITIONCONTROL",
"I_CONDITIONINACTIVEREASON",
"I_CONDITIONORIGIN",
"I_CONDITIONRATERATIOUNIT",
"I_CURRENCY",
"I_PRICINGCONDITIONTYPE",
"I_PRICINGSCALEBASIS",
"I_SALESORDER",
"I_STRUCTURECONDITION",
"I_UNITOFMEASURE",
"I_VARIANTCONDITION"
],
"BASE":
[
"I_SALESDOCUMENTPRICINGELEMENT"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/

Learn More