I_SalesOrderItemPartner

DDL: I_SALESORDERITEMPARTNER Type: view COMPOSITE

Sales Order Item Partner

I_SalesOrderItemPartner is a Composite CDS View that provides data about "Sales Order Item Partner" in SAP S/4HANA. It reads from 1 data source (I_SalesDocumentItemPartner) and exposes 26 fields with key fields SalesOrder, SalesOrderItem, PartnerFunction.

1 data source(s) 26 fields

Data Sources (1)

SourceAliasJoin Type
I_SalesDocumentItemPartner Partner from

Annotations (12)

NameValueLevelField
ClientHandling.algorithm #SESSION_VARIABLE view
EndUserText.label Sales Order Item Partner view
VDM.viewType #COMPOSITE view
VDM.lifecycle.contract.type #PUBLIC_LOCAL_API view
AccessControl.authorizationCheck #CHECK view
AbapCatalog.sqlViewName ISDSLSORDITMPT view
AbapCatalog.compiler.compareFilter true view
ObjectModel.representativeKey PartnerFunction view
ObjectModel.usageType.dataClass #TRANSACTIONAL view
ObjectModel.usageType.serviceQuality #C view
ObjectModel.usageType.sizeCategory #XL view
Metadata.ignorePropagatedAnnotations true view

Fields (26)

KeyFieldSource TableSource FieldDescription
KEY SalesOrder
KEY SalesOrderItem
KEY PartnerFunction I_SalesDocumentItemPartner PartnerFunction
Customer I_SalesDocumentItemPartner Customer
Supplier I_SalesDocumentItemPartner Supplier
Personnel I_SalesDocumentItemPartner Personnel
ContactPerson I_SalesDocumentItemPartner ContactPerson
Partner I_SalesDocumentItemPartner Partner
FullName I_SalesDocumentItemPartner FullName
ReferenceBusinessPartner I_SalesDocumentItemPartner ReferenceBusinessPartner
AddressID I_SalesDocumentItemPartner AddressID
AddressPersonID I_SalesDocumentItemPartner AddressPersonID
AddressObjectType I_SalesDocumentItemPartner AddressObjectType
SDDocPartnerAddressRefType I_SalesDocumentItemPartner SDDocPartnerAddressRefType
BPAddrDeterminationTransaction I_SalesDocumentItemPartner BPAddrDeterminationTransaction
BPRefAddressIDForDocSpcfcAddr I_SalesDocumentItemPartner BPRefAddressIDForDocSpcfcAddr
InternationalPhoneNumber I_SalesDocumentItemPartner InternationalPhoneNumber
InternationalMobilePhoneNumber I_SalesDocumentItemPartner InternationalMobilePhoneNumber
EmailAddress I_SalesDocumentItemPartner EmailAddress
_SalesOrder _SalesOrder
_SalesOrderItem _SalesOrderItem
_PartnerFunction I_SalesDocumentItemPartner _PartnerFunction
_Address I_SalesDocumentItemPartner _Address
_DfltAddrRprstn I_SalesDocumentItemPartner _DfltAddrRprstn
_BusinessPartnerAddress I_SalesDocumentItemPartner _BusinessPartnerAddress
_BPRefAddressForDocSpcfcAddr I_SalesDocumentItemPartner _BPRefAddressForDocSpcfcAddr 
@ClientHandling.algorithm: #SESSION_VARIABLE 
@EndUserText.label: 'Sales Order Item Partner'
@VDM: {
  viewType: #COMPOSITE,
  lifecycle.contract.type: #PUBLIC_LOCAL_API
}
@AccessControl: { 
  authorizationCheck: #CHECK,
  personalData.blocking: #('TRANSACTIONAL_DATA'),
  privilegedAssociations: [ '_Address', '_DfltAddrRprstn' ]
}
@AbapCatalog: {
  sqlViewName: 'ISDSLSORDITMPT',
  compiler.compareFilter: true
}
@ObjectModel: {
   representativeKey: 'PartnerFunction',
   usageType: {
     dataClass:      #TRANSACTIONAL,
     serviceQuality: #C,
     sizeCategory:   #XL
   },
   supportedCapabilities: [ #SQL_DATA_SOURCE, #CDS_MODELING_DATA_SOURCE, #CDS_MODELING_ASSOCIATION_TARGET]
}
@Metadata.ignorePropagatedAnnotations: true

define view I_SalesOrderItemPartner as select from I_SalesDocumentItemPartner  as Partner
      
    association[1..1] to I_SalesOrder      as _SalesOrder      on  $projection.SalesOrder     = _SalesOrder.SalesOrder 
    association[1..1] to I_SalesOrderItem  as _SalesOrderItem  on  $projection.SalesOrder     = _SalesOrderItem.SalesOrder  
                                                               and $projection.SalesOrderItem = _SalesOrderItem.SalesOrderItem  
    
{
        @ObjectModel.foreignKey.association: '_SalesOrder'                                                                                                   
    key cast(Partner.SalesDocument as vdm_sales_order preserving type)      as SalesOrder,             
        @ObjectModel.foreignKey.association: '_SalesOrderItem'                                                                                                   
    key cast(Partner.SalesDocumentItem as sales_order_item preserving type) as SalesOrderItem,             
        @ObjectModel.foreignKey.association: '_PartnerFunction'      
    key Partner.PartnerFunction, 
          
        Partner.Customer,          
        Partner.Supplier,           
        Partner.Personnel,
        Partner.ContactPerson,

        @ObjectModel.text.element: ['FullName']
        Partner.Partner,
        @Semantics: {
          text: true,
          name.fullName: true
        }
        Partner.FullName,
        
        Partner.ReferenceBusinessPartner,   
        
        @ObjectModel.foreignKey.association: '_Address'        
        Partner.AddressID,
        Partner.AddressPersonID,
        Partner.AddressObjectType,
        Partner.SDDocPartnerAddressRefType,
        Partner.BPAddrDeterminationTransaction,
        Partner.BPRefAddressIDForDocSpcfcAddr,    
      
        Partner.InternationalPhoneNumber,
        Partner.InternationalMobilePhoneNumber,
        Partner.EmailAddress,
        
        //Association

        @ObjectModel.association.type: [#TO_COMPOSITION_ROOT]    
        _SalesOrder,
        @ObjectModel.association.type: [#TO_COMPOSITION_PARENT]    
        _SalesOrderItem, 
        Partner._PartnerFunction,
        Partner._Address,
        Partner._DfltAddrRprstn,
        Partner._BusinessPartnerAddress,
        Partner._BPRefAddressForDocSpcfcAddr    

}
where Partner.SDDocumentCategory = 'C';         
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_SALESDOCUMENTITEMPARTNER"
],
"ASSOCIATED":
[
"I_ADDRESS",
"I_ADDRESS_2",
"I_BUSPARTADDRESS",
"I_PARTNERFUNCTION",
"I_SALESORDER",
"I_SALESORDERITEM"
],
"BASE":
[
"I_SALESDOCUMENTITEMPARTNER"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/

Learn More