I_SAFTLineItemCA

@AbapCatalog.sqlViewName: 'ISAFTLITMCA'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AbapCatalog.dataMaintenance: #RESTRICTED
@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #BLOCKED_DATA_INCLUDED
@ObjectModel.usageType.serviceQuality: #X
@ObjectModel.usageType.sizeCategory: #XL
@ObjectModel.usageType.dataClass: #MIXED
@VDM.viewType: #COMPOSITE
@ClientHandling.algorithm: #SESSION_VARIABLE
@EndUserText.label: 'SAF-T FI-CA GL Line Item'
define view I_SAFTLineItemCA
  as select distinct from I_CADocumentBPItemPhysical        as FicaEntryItem
  
    inner join I_CADocumentGLItem                           as FicaLineItem   on  FicaLineItem.CADocumentNumber  = FicaEntryItem.CADocumentNumber         
    
    inner join I_JournalEntryItem                           as JournalItem    on JournalItem.ReferenceDocument   = SUBSTRING(FicaLineItem.CAReconciliationKey,1,10)
                                                                             and JournalItem.CompanyCode         = FicaEntryItem.CompanyCode
                                                                            


{
      @ObjectModel.foreignKey.association: '_CompCode'
  key FicaEntryItem.CompanyCode                                        as CompanyCode,
      
  key FicaEntryItem.CADocumentNumber                                   as CADocumentNumber,
  key FicaLineItem.CAGLItemNumber                                      as CAGLItemNumber,
  
      
  key JournalItem.FiscalYear                                           as FiscalYear,
      
      FicaEntryItem.CAApplicationArea                                  as CAApplicationArea,
      @ObjectModel.foreignKey.association: '_BusinessPartner'
      FicaEntryItem.BusinessPartner                                    as BusinessPartner,
      @Semantics.currencyCode: true
      @ObjectModel.foreignKey.association: '_CompanyCodeCurrency'
      FicaEntryItem.CompanyCodeCurrency,
      @ObjectModel.foreignKey.association: '_GLAccount'
      FicaLineItem.GLAccount                                           as GLAccount,
      //''                                                               as AlternativeGLAccount,


      FicaLineItem.ChartOfAccounts                                     as ChartOfAccounts,
      //''                                                               as CountryChartOfAccounts,


      FicaEntryItem._DocHeader.CAReferenceDocument                     as CAReferenceDocument,
      FicaEntryItem.CAPostingDate                                      as PostingDate,
      FicaEntryItem.CABPItemText                                       as DocumentItemText,

      @DefaultAggregation: #SUM
      @Semantics: { amount : {currencyCode: 'CompanyCodeCurrency'} }
      FicaLineItem.CAAmountInLocalCurrency                             as AmountInCompanyCodeCurrency,

      @DefaultAggregation: #SUM
      @Semantics: { amount : {currencyCode: 'CompanyCodeCurrency'} }
      case
        when FicaLineItem.CAAmountInLocalCurrency <= 0
         then abs(FicaLineItem.CAAmountInLocalCurrency)
          else cast(0 as betrh_kk)
       end                                                             as DebitAmountInCoCodeCrcy,

      @DefaultAggregation: #SUM
      @Semantics: { amount : {currencyCode: 'CompanyCodeCurrency'} }
      case
        when FicaLineItem.CAAmountInLocalCurrency > 0
         then abs(FicaLineItem.CAAmountInLocalCurrency)
          else cast(0 as betrh_kk)
       end                                                             as CreditAmountInCoCodeCrcy,

      case
      when FicaLineItem.CAAmountInLocalCurrency > 0
       then 'C' //credit - H

      else 'D' //Debit - S

      end                                                              as DebitCreditCode,

      FicaEntryItem.TaxCode                                            as TaxCode,
      FicaEntryItem.CATaxAmountInLocalCurrency                         as TaxAmount,
      
      
      FicaEntryItem._DocHeader.CAReversalDocumentNumber                as CAReversalDocumentNumber,
      case
        when FicaEntryItem._DocHeader.CAReversalDocumentNumber <> ''
          then 'X' //Reversed

        else ' ' //Not

        end                                                            as IsReversed,

      FicaLineItem.CostCenter                                          as CostCenter,
      
      0                                                                as Quantity, // To Clarify


      
      FicaEntryItem._DocHeader.LogicalSystem                           as LogicalSystem,

      FicaLineItem.CATransactionKeyAccountDetn                         as TransactionTypeDetermination,

      //''                                                               as ReferenceSDDocument,


      'S'                                                              as FinancialAccountType,
      FicaEntryItem.Country                                            as Country,
      FicaEntryItem.TaxCalculationProcedure,

      //''                                                               as OrderID, // To Clarify

      FicaEntryItem.PersonnelNumber,
      FicaLineItem.CAAmountInTransactionCurrency,
      FicaEntryItem.TransactionCurrency,
      FicaLineItem.ValueDate,
      case
        when FicaEntryItem._DocHeader.CAReversedDocumentNumber <> ''
          then 'X' //Reversed

        else ' ' //Not

        end                                                            as IsReversal,
      FicaLineItem.SalesOrder                                          as SalesDocument,
      FicaLineItem.SalesOrderItem                                      as SalesDocumentItem,
      //' '                                                              as PaymentReference,

      //' '                                                              as BillingDocument,


      
   
       //Associations

      _CompCode,
      _BusinessPartner,      
      _DocHeader,
      _CompanyCodeCurrency,
      _GLAccount
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_CADOCUMENTBPITEMPHYSICAL",
"I_CADOCUMENTGLITEM",
"I_CADOCUMENTHEADER",
"I_JOURNALENTRYITEM"
],
"ASSOCIATED":
[
"I_BUSINESSPARTNER",
"I_CADOCUMENTHEADER",
"I_COMPANYCODE",
"I_CURRENCY",
"I_GLACCOUNTINCHARTOFACCOUNTS"
],
"BASE":
[
"I_CADOCUMENTBPITEMPHYSICAL",
"I_CADOCUMENTGLITEM"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/