I_SAFTBankStatement

@AbapCatalog.sqlViewName: 'ISAFTBNKST'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #BLOCKED_DATA_INCLUDED
@ObjectModel.usageType.serviceQuality: #D
@ObjectModel.usageType.sizeCategory: #XL
@ObjectModel.usageType.dataClass: #MIXED
@VDM.viewType: #BASIC
@ClientHandling.algorithm: #SESSION_VARIABLE
@EndUserText.label: 'SAF-T Bank Statement'
define view I_SAFTBankStatement
  as select from febko       as f
    inner join   I_Housebank as hb on  hb.CompanyCode = f.bukrs
                                   and hb.HouseBank   = f.hbkid

    inner join I_Iban as iban on       iban.BankCountry     =  hb.BankCountry
                              and      iban.Bank            =  hb.BankInternalID
                              and      iban.BankAccount     =  f.ktonr
                              
//  association [0..*] to I_Iban        as _IBAN        on  $projection.BankCountry    = _IBAN.BankCountry

//                                                      and $projection.BankInternalID = _IBAN.Bank

//                                                      and $projection.BankAccount    = _IBAN.BankAccount

//                                                      and $projection.BankControlKey = _IBAN.BankControlKey


  association [1..1] to I_CompanyCode as _CompanyCode on  $projection.CompanyCode = _CompanyCode.CompanyCode
  
  association [1..1] to I_Currency as _Currency on $projection.Currency = _Currency.Currency

{
  key f.bukrs      as CompanyCode,
  key f.kukey      as BankStatementShortID,
      
      iban.IBAN    as IBAN,
      
      f.azidt      as BankStatementInternalID,
      f.azdat      as BankStatementDate,
      @Semantics.currencyCode:true
      f.waers      as Currency,

      @Semantics.amount.currencyCode: 'Currency'  
      case when f.ssvoz = 'S'
       then - abs(f.ssbtr)
       else ssbtr
      end          as StartingBalanceAmtInTransCrcy,
      f.ssvoz      as StartingBalSurplusDeficitCode,

      @Semantics.amount.currencyCode: 'Currency'  
      case when f.esvoz = 'S'
       then - abs(f.esbtr)
       else esbtr
      end          as ClosingBalanceAmtInTransCrcy,
      f.esvoz      as ClosingBalSurplusDeficitCode,

      f.hbkid      as HouseBank,
      f.ktonr      as BankAccount,
      hb.BankCountry,
      hb.BankInternalID,
      hb.BankControlKey,

      _CompanyCode,
//      _IBAN,

      _Currency
}
where
  anwnd = '0001' //Electronic and manual bank statement

/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_HOUSEBANK",
"I_IBAN",
"FEBKO"
],
"ASSOCIATED":
[
"I_COMPANYCODE",
"I_CURRENCY"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/