I_ReturnsInspectionStatusText

@Analytics.dataExtraction.enabled: true 
@AccessControl.authorizationCheck: #NOT_REQUIRED
@Analytics.technicalName              : 'IRETINSPCODETEXT'
@EndUserText.label: 'Returns Inspection Status - Text'
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.dataCategory: #TEXT
@ObjectModel.modelingPattern: #LANGUAGE_DEPENDENT_TEXT
@ObjectModel.representativeKey: 'ReturnsInspectionStatus'
@ObjectModel.supportedCapabilities: [#CDS_MODELING_ASSOCIATION_TARGET,
                                     #CDS_MODELING_DATA_SOURCE,
                                     #EXTRACTION_DATA_SOURCE,
                                     #LANGUAGE_DEPENDENT_TEXT,
                                     #SQL_DATA_SOURCE]
@ObjectModel.usageType.serviceQuality: #A
@ObjectModel.usageType.dataClass: #META
@ObjectModel.usageType.sizeCategory: #S
@Search.searchable: true
@VDM.lifecycle.contract.type: #PUBLIC_LOCAL_API
@VDM.viewType: #BASIC
define view entity I_ReturnsInspectionStatusText 
  as select from dd07t
 association to parent I_ReturnsInspectionStatus  as _ReturnsInspectionStatus
 on $projection.ReturnsInspectionStatus = _ReturnsInspectionStatus.ReturnsInspectionStatus
  association [0..1] to I_Language as _Language
    on $projection.Language = _Language.Language
{
      @ObjectModel.foreignKey.association: '_Language'
      @Semantics.language: true
  key cast( dd07t.ddlanguage as spras preserving type ) as Language,
      @ObjectModel.foreignKey.association: '_ReturnsInspectionStatus'
      @ObjectModel.text.element: ['ReturnsInspectionStatusText']
  key cast(  dd07t.domvalue_l  as msr_insp_insp_status ) as ReturnsInspectionStatus,//ReturnsInspectionItemStatus,

      @Search.defaultSearchElement: true
      @Search.fuzzinessThreshold: 0.8
      @Search.ranking: #HIGH
      @Semantics.text: true
      cast( dd07t.ddtext  as char60 preserving type ) as ReturnsInspectionStatusText,
     _ReturnsInspectionStatus,
      _Language
}
where
      dd07t.domname  = 'MSR_INSP_INSP_STATUS'
  and dd07t.as4local = 'A' and ddlanguage = $session.system_language


/*+[internal] {
"BASEINFO":
{
"FROM":
[
"DD07T"
],
"ASSOCIATED":
[
"I_LANGUAGE",
"I_RETURNSINSPECTIONSTATUS"
],
"BASE":
[],
"ANNO_REF":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/