I_RetsMgmtProcessItem

@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.representativeKey: 'RetsMgmtProcessItem'
@ObjectModel.usageType.dataClass: #TRANSACTIONAL
@ObjectModel.usageType.serviceQuality: #B
@ObjectModel.usageType.sizeCategory: #L
@Analytics.dataExtraction.enabled: false
@VDM.viewType: #BASIC
@EndUserText.label: 'Returns Management Process Item'
@AccessControl.authorizationCheck: #NOT_REQUIRED
@AbapCatalog.sqlViewName: 'IRMRTSPROCESSITM'

define view I_RetsMgmtProcessItem
  as select from msr_d_item

  association [1..1] to I_RetsMgmtProcess            as _RetsMgmtProcess              on  $projection.RetsMgmtProcess = _RetsMgmtProcess.RetsMgmtProcess
  association [0..1] to I_ReturnsDocumentType        as _ReturnsReferenceDocumentType on  $projection.ReturnsReferenceDocumentType = _ReturnsReferenceDocumentType.ReturnsDocumentType
  association [1..1] to I_RetsMgmtProcItmWthProcgSts as _RetsMgmtProcItmWthProcgSts   on  $projection.RetsMgmtProcess     = _RetsMgmtProcItmWthProcgSts.RetsMgmtProcess
                                                                                      and $projection.RetsMgmtProcessItem = _RetsMgmtProcItmWthProcgSts.RetsMgmtProcessItem
  association [1..1] to I_RetsMgmtProcessItemExec    as _RetsMgmtProcessItemExec      on  $projection.RetsMgmtProcess     = _RetsMgmtProcessItemExec.RetsMgmtProcess
                                                                                      and $projection.RetsMgmtProcessItem = _RetsMgmtProcessItemExec.RetsMgmtProcessItem
  association [1..1] to I_RetsMgmtProcItmRetOrdExec  as _RetsMgmtProcItmRetOrdExec    on  $projection.RetsMgmtProcess     = _RetsMgmtProcItmRetOrdExec.RetsMgmtProcess
                                                                                      and $projection.RetsMgmtProcessItem = _RetsMgmtProcItmRetOrdExec.RetsMgmtProcessItem
  association [0..*] to I_RetsMgmtProcItmInspExec    as _RetsMgmtProcItmInspExec      on  $projection.RetsMgmtProcess     = _RetsMgmtProcItmInspExec.RetsMgmtProcess
                                                                                      and $projection.RetsMgmtProcessItem = _RetsMgmtProcItmInspExec.RetsMgmtProcessItem
  association [0..1] to I_SalesDocumentRjcnReason    as _ReturnsRefundRjcnReason      on  $projection.ReturnsRefundRjcnReason = _ReturnsRefundRjcnReason.SalesDocumentRjcnReason
{
      //Key

      @ObjectModel.foreignKey.association: '_RetsMgmtProcess'
  key msr_id       as RetsMgmtProcess,
  key item         as RetsMgmtProcessItem,

      //Product

      matnr        as Material,

      //Reference

      @ObjectModel.foreignKey.association: '_ReturnsReferenceDocumentType'
      ref_doc_type as ReturnsReferenceDocumentType,
      ref_doc_nr   as ReturnsReferenceDocument,
      ref_doc_item as ReturnsReferenceDocumentItem,

      //Return

      rma_customer as CustRetMatlAuthzn,
      @ObjectModel.foreignKey.association: '_ReturnsRefundRjcnReason'
      cmr_abgru    as ReturnsRefundRjcnReason,

      //Associations

      @ObjectModel.association.type: [#TO_COMPOSITION_PARENT,
                                     #TO_COMPOSITION_ROOT]
      _RetsMgmtProcess,
      _ReturnsReferenceDocumentType,
      _RetsMgmtProcItmWthProcgSts,
      _RetsMgmtProcessItemExec,
      _RetsMgmtProcItmRetOrdExec,
      _RetsMgmtProcItmInspExec,
      _ReturnsRefundRjcnReason
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"MSR_D_ITEM"
],
"ASSOCIATED":
[
"I_RETSMGMTPROCESS",
"I_RETSMGMTPROCESSITEMEXEC",
"I_RETSMGMTPROCITMINSPEXEC",
"I_RETSMGMTPROCITMRETORDEXEC",
"I_RETSMGMTPROCITMWTHPROCGSTS",
"I_RETURNSDOCUMENTTYPE",
"I_SALESDOCUMENTRJCNREASON"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/