I_RetailPromotionItemStore

@Analytics.technicalName: 'IRTLPROMNITMSTRE'
@EndUserText: {label: 'Retail Promotion Item Store'}
@AccessControl: {
    authorizationCheck: #CHECK,
    personalData.blocking: #REQUIRED
}

@VDM: {viewType: #BASIC}

@ObjectModel: {
    representativeKey: 'StoreCustomer',
    usageType: {
        serviceQuality: #A,
        sizeCategory: #XL,
        dataClass: #TRANSACTIONAL
   }
}

define view entity I_RetailPromotionItemStore
  as select from wale

  association [1..1] to I_RetailPromotion            as _RetailPromotion          on  $projection.RetailPromotion = _RetailPromotion.RetailPromotion
  association [1..1] to I_RetailPromotionItem        as _RetailPromotionItem      on  $projection.RetailPromotion   = _RetailPromotionItem.RetailPromotion
                                                                                  and $projection.Product           = _RetailPromotionItem.Product
                                                                                  and $projection.SalesQuantityUnit = _RetailPromotionItem.SalesQuantityUnit
  association [1..1] to I_RtlPromnStoreGroup         as _RtlPromnStoreGroup       on  $projection.RetailPromotion      = _RtlPromnStoreGroup.RetailPromotion
                                                                                  and $projection.StoreGroupInternalID = _RtlPromnStoreGroup.StoreGroupInternalID

  association [1..1] to I_RtlPromnItmStoreAnncmntSts as _ItmStoreAnncmntSts       on  $projection.RtlPromnItmStoreAnncmntSts = _ItmStoreAnncmntSts.RtlPromnItmStoreAnncmntSts

  association [1..1] to I_Product                    as _Product                  on  $projection.Product = _Product.Product
  association [1..1] to I_UnitOfMeasure              as _UnitOfMeasure            on  $projection.SalesQuantityUnit = _UnitOfMeasure.UnitOfMeasure
  association [1..1] to I_Customer                   as _Customer                 on  $projection.StoreCustomer = _Customer.Customer
  /*+[hideWarning] { "IDS" : [ "CARDINALITY_CHECK" ]  } */
  association [1..1] to I_Site                       as _Site                     on  $projection.StoreCustomer = _Site.SiteCustomer
  association [1..1] to I_ClassHeader                as _StoreGroupClassHeader    on  $projection.StoreGroupInternalID = _StoreGroupClassHeader.ClassInternalID
  association [0..1] to I_Supplier                   as _Supplier                 on  $projection.Supplier = _Supplier.Supplier
  association [1..1] to I_Site                       as _SupplyingSite            on  $projection.PromotionSupplyingSite = _SupplyingSite.Site
  association [0..1] to I_Currency                   as _PromnPlnItmStoreCurrency on  $projection.PromnPlnItmStoreCurrency = _PromnPlnItmStoreCurrency.Currency

  association [1..1] to I_SalesOrganization          as _SalesOrganization        on  $projection.SalesOrganization = _SalesOrganization.SalesOrganization
  association [1..1] to I_DistributionChannel        as _DistributionChannel      on  $projection.DistributionChannel = _DistributionChannel.DistributionChannel
{

      @ObjectModel.foreignKey.association: '_RetailPromotion'
  key aktnr                                              as RetailPromotion,

      @ObjectModel: {foreignKey: {association: '_Product'}}
  key cast(artnr as productnumber preserving type)       as Product,
      _Product,

      @ObjectModel: {foreignKey: {association: '_UnitOfMeasure'}}
  key mebme                                              as SalesQuantityUnit,
      _UnitOfMeasure,

      @ObjectModel: {foreignKey: {association: '_Customer'}}
  key kunnr                                              as StoreCustomer,
      _Customer,
      _Site,

      @ObjectModel: {foreignKey: {association: '_StoreGroupClassHeader'}}
  key clint                                              as StoreGroupInternalID,
      _StoreGroupClassHeader,

      @ObjectModel.foreignKey.association: '_Supplier'
      lifnr                                              as Supplier,
      _Supplier,

      @Semantics.booleanIndicator: true
      rustb                                              as LocHasRepliedToAnnouncement,

      @Semantics.amount.currencyCode: 'PromnPlnItmStoreCurrency'
      plvkp                                              as PromnPlnItmStoreSalesPrice,

      @Semantics.quantity.unitOfMeasure: 'SalesQuantityUnit'
      _RetailPromotionItem.RtlPromotionItemSalesPriceQty as RtlPromotionItemSalesPriceQty,

      waela                                              as PromnPlnItmStoreCurrency,
      _PromnPlnItmStoreCurrency,


      @ObjectModel.foreignKey.association: '_ItmStoreAnncmntSts'
      bedeb                                              as RtlPromnItmStoreAnncmntSts,
      _ItmStoreAnncmntSts,

      @Semantics.booleanIndicator: true
      relif                                              as IsRegularSupplier,


      @Semantics.quantity.unitOfMeasure: 'SalesQuantityUnit'
      wmnge                                              as PromnPlnItmStoreRequestedQty,


      @Semantics.quantity.unitOfMeasure: 'SalesQuantityUnit'
      aufme                                              as PromnPlnItmStoreConfdQty,


      @Semantics.quantity.unitOfMeasure: 'SalesQuantityUnit'
      pabbm                                              as PromnPlnItmSalesQuantity,

      @ObjectModel.foreignKey.association: '_SupplyingSite'
      vzwrk                                              as PromotionSupplyingSite,

      @ObjectModel.foreignKey.association: '_SalesOrganization'
      vkorg                                              as SalesOrganization,

      @ObjectModel.foreignKey.association: '_DistributionChannel'
      vtweg                                              as DistributionChannel,

      _RtlPromnStoreGroup.RtlPromnLatestPossibleGRDate   as RtlPromnLatestPossibleGRDate,
      _RtlPromnStoreGroup,

      _RetailPromotionItem.ProductGroup                  as ProductGroup,
      _RetailPromotionItem._ClassHeader,

      _RetailPromotionItem.AllocationTable               as AllocationTable,
      _RetailPromotionItem._AllocationTable,

      _RetailPromotionItem.AllocationTableItem           as AllocationTableItem,
      _RetailPromotionItem._AllocationTableItem,

      @ObjectModel.association.type: [#TO_COMPOSITION_PARENT]
      _RetailPromotionItem,

      @ObjectModel.association.type: [#TO_COMPOSITION_ROOT]
      _RetailPromotion,

      _SupplyingSite,

      _SalesOrganization,
      _DistributionChannel
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_RETAILPROMOTIONITEM",
"I_RTLPROMNSTOREGROUP",
"WALE"
],
"ASSOCIATED":
[
"I_ALLOCATIONTABLE",
"I_ALLOCATIONTABLEITEM",
"I_CLASSHEADER",
"I_CURRENCY",
"I_CUSTOMER",
"I_DISTRIBUTIONCHANNEL",
"I_PRODUCT",
"I_RETAILPROMOTION",
"I_RETAILPROMOTIONITEM",
"I_RTLPROMNITMSTOREANNCMNTSTS",
"I_RTLPROMNSTOREGROUP",
"I_SALESORGANIZATION",
"I_SITE",
"I_SUPPLIER",
"I_UNITOFMEASURE"
],
"BASE":
[
"I_RETAILPROMOTIONITEM"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/