I_ResvnCreationCodeText

@EndUserText.label: 'Reservation Creation Code - Text'
@AccessControl.authorizationCheck: #NOT_REQUIRED
@ObjectModel: {
                usageType: {
                             sizeCategory: #S,
                             serviceQuality: #A,
                             dataClass:#CUSTOMIZING
                           },
                dataCategory: #TEXT,
                representativeKey: 'ReservationCreationCode'
              }

@VDM: {
        viewType: #BASIC
      }
@Metadata: {
             ignorePropagatedAnnotations: true
           }
@Consumption.ranked: true
@Search.searchable: true
define view entity I_ResvnCreationCodeText
  as select from dd07t
  association [0..1] to I_ReservationCreationCode as _ReservationCreationCode on $projection.ReservationCreationCode = _ReservationCreationCode.ReservationCreationCode
  association [0..1] to I_Language                as _Language                on $projection.Language = _Language.Language
{
       @ObjectModel.foreignKey.association: '_ReservationCreationCode'
       @ObjectModel.text.element: ['ReservationCreationCodeName']
  key  cast(SUBSTRING(dd07t.domvalue_l, 1, 4) as imrs_creation_code preserving type) as ReservationCreationCode,
       @ObjectModel.foreignKey.association: '_Language'
       @Semantics.language:true
  key  cast( ddlanguage as spras )                                                   as Language,

      @Semantics.text: true
      @Search.defaultSearchElement: true
      @Search.fuzzinessThreshold: 0.8
      @Search.ranking: #LOW
       cast ( substring ( ddtext, 1, 60 ) as val_text )                              as ReservationCreationCodeName,

       _ReservationCreationCode,
       _Language

}
where
  (
    dd07t.domname  = 'IMRS_CREATION_CODE'
  )
  and(
    dd07t.as4local = 'A'
  );
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"DD07T"
],
"ASSOCIATED":
[
"I_LANGUAGE",
"I_RESERVATIONCREATIONCODE"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/