I_ResvnCompletionStatusText

@EndUserText.label: 'Completion Status of Reservation - Text'
@AbapCatalog.sqlViewName: 'IRESCMPLSTSTXT'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #NOT_REQUIRED
@Analytics.dataExtraction.enabled: true
@ClientHandling.algorithm: #SESSION_VARIABLE
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel : {
  dataCategory: #TEXT,
  modelingPattern: #LANGUAGE_DEPENDENT_TEXT,
  representativeKey: 'ReservationCompletionStatus',
  usageType : {
    serviceQuality: #A,
    dataClass: #META,
    sizeCategory: #S
  }
}
@ObjectModel.supportedCapabilities: [#CDS_MODELING_ASSOCIATION_TARGET, 
                                     #CDS_MODELING_DATA_SOURCE,
                                     #EXTRACTION_DATA_SOURCE,
                                     #LANGUAGE_DEPENDENT_TEXT,
                                     #SEARCHABLE_ENTITY,
                                     #SQL_DATA_SOURCE]
@Search.searchable: true
@VDM: {
  lifecycle.contract.type: #PUBLIC_LOCAL_API,
  viewType: #BASIC
}

define view I_ResvnCompletionStatusText
  as select from dd07t

  /*+[hideWarning] { "IDS" :  [ "CALCULATED_FIELD_CHECK" ] } */
  association [1..1] to I_ResvnCompletionStatus as _ResvnCompletionStatus 
    on $projection.ReservationCompletionStatus = _ResvnCompletionStatus.ReservationCompletionStatus
  association [0..1] to I_Language as _Language              
    on $projection.Language = _Language.Language

{
      @Semantics.language: true
      @ObjectModel.foreignKey.association: '_Language'
  key cast( dd07t.ddlanguage as spras preserving type ) as Language, 
      @EndUserText.label: 'Status'
      @ObjectModel.foreignKey.association: '_ResvnCompletionStatus'
      @ObjectModel.text.element: ['ResvnCompletionStatusText']
  key cast ( dd07t.domvalue_l as imrs_resvn_compltn_status_code ) as ReservationCompletionStatus,
  
      @Analytics.hidden: true
      @Consumption.hidden: true
      dd07t.domvalue_l as DomainValue,
      
      @EndUserText.label: 'Status Text'
      @Search.defaultSearchElement: true
      @Search.fuzzinessThreshold: 0.8
      @Search.ranking: #HIGH
      @Semantics.text: true
      cast( dd07t.ddtext as imrs_resvn_compltn_status_text preserving type ) as ResvnCompletionStatusText,
      @ObjectModel.association.type: [#TO_COMPOSITION_PARENT, 
                                      #TO_COMPOSITION_ROOT] 
      _ResvnCompletionStatus,
      _Language

}
where
      dd07t.domname  = 'IMRS_RESVN_COMPLTN_STATUS_CODE'
  and dd07t.as4local = 'A'
  and dd07t.as4vers  = '0000'
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"DD07T"
],
"ASSOCIATED":
[
"I_LANGUAGE",
"I_RESVNCOMPLETIONSTATUS"
],
"BASE":
[],
"ANNO_REF":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/