I_ReldSftyInstrnFctryAreaVH

@EndUserText.label: 'Factory Areas for Safety Instruction'

@AccessControl.authorizationCheck: #MANDATORY

@VDM: {
  viewType: #COMPOSITE,
  lifecycle.contract.type: #SAP_INTERNAL_API
  }

@ObjectModel: {
                dataCategory:#VALUE_HELP,
                representativeKey: 'EHSLocationUUID',
                semanticKey: ['EHSLocationUUID'],
                usageType:{ serviceQuality: #C,
                            sizeCategory:  #M,
                            dataClass: #MIXED }
               }

@Search.searchable: true

@Metadata: { ignorePropagatedAnnotations: true,
             allowExtensions:true }


define view entity I_ReldSftyInstrnFctryAreaVH

  as select from I_EHSLocationHierarchyNode

    inner join   I_EHSLocationHierarchyRevision on  I_EHSLocationHierarchyRevision.RevisionStartDate           <= $session.system_date
                                                and I_EHSLocationHierarchyRevision.RevisionEndDate             >= $session.system_date
                                                and I_EHSLocationHierarchyRevision.EHSLocHierarchyRevisionUUID = I_EHSLocationHierarchyNode.EHSLocHierarchyRevisionUUID

    inner join   I_EHSLocationRevision          on  I_EHSLocationRevision.RevisionStartDate <= $session.system_date
                                                and I_EHSLocationRevision.RevisionEndDate   >= $session.system_date
                                                and I_EHSLocationRevision.EHSLocationUUID   = I_EHSLocationHierarchyNode.EHSParentLocationUUID

    inner join   I_SafetyInstructionDefinition  on  I_EHSLocationRevision.Plant           = I_SafetyInstructionDefinition.Plant
                                                and I_EHSLocationRevision.EHSLocationType = I_SafetyInstructionDefinition.SafetyInstructionLocType

/*+[hideWarning] { "IDS" : [  "CARDINALITY_CHECK" ] } */
  association [0..1] to I_EHSLocationRevision        as _EHSLocationRevision   on  $projection.EHSLocationUUID            = _EHSLocationRevision.EHSLocationUUID
                                                                               and _EHSLocationRevision.RevisionStartDate <= $session.system_date
                                                                               and _EHSLocationRevision.RevisionEndDate   >= $session.system_date

// end correction 3113514 28.10.2021  


  association [0..1] to I_CurrentEHSLocationNameText as _EHSLocationName       on  $projection.EHSLocationUUID = _EHSLocationName.EHSLocationUUID
                                                                               and _EHSLocationName.Language   = $session.system_language

  association [0..1] to I_CurrentEHSLocationNameText as _EHSParentLocationName on  $projection.EHSParentLocationUUID = _EHSParentLocationName.EHSLocationUUID
                                                                               and _EHSParentLocationName.Language   = $session.system_language

  association [0..1] to C_EHSLocationTypeVH   as _EHSLocationTypeVH     on  $projection.ehslocationtype = _EHSLocationTypeVH.EHSLocationType

{
         //I_EHSLocHierarchyPath

         @EndUserText.label: 'Factory Area Location UUID'
         @ObjectModel: { text: { element: ['EHSLocationName'] } }
  key    I_EHSLocationHierarchyNode.EHSLocationUUID,  //correction 3113514 28.10.2021


         @Consumption.filter.hidden: true
         @EndUserText.label: 'Parent Factory UUID'
  key    I_EHSLocationHierarchyNode.EHSParentLocationUUID,  //correction 3113514 28.10.2021


         @ObjectModel: { filter.enabled: true,
                       sort.enabled: true }
  key    I_SafetyInstructionDefinition.SafetyInstructionType,

         @ObjectModel: { filter.enabled: true,
                         sort.enabled: true }
         @Consumption.filter.hidden: true
  key    I_SafetyInstructionDefinition.SafetyInstructionSubType,

         @EndUserText.label: 'Factory Area Name'
         @Semantics.text: true
         @Search: { defaultSearchElement: true,
                    fuzzinessThreshold: 1,
                    ranking: #HIGH }
         _EHSLocationName.EHSLocationName,

         @EndUserText.label: 'Parent Location Name'
         _EHSParentLocationName.EHSLocationName                                                               as EHSParentLocationName,

         @Search: { defaultSearchElement: true,
                    fuzzinessThreshold: 1,
                    ranking: #MEDIUM }
         _EHSLocationRevision.Plant,

         @EndUserText.label: 'Location Type'
         @Consumption.valueHelp: '_EHSLocationTypeVH'
         _EHSLocationRevision.EHSLocationType,

         @EndUserText.label: 'Location Type'
         @Consumption: { valueHelpDefinition: [{ entity: { name: 'C_EHSLocationTypeVH',
                                                        element: 'EHSLocationTypeText'
                                            }, label: 'Location Type' }]     }
         @Search: { defaultSearchElement: true,
                    fuzzinessThreshold: 1,
                    ranking: #MEDIUM }
         _EHSLocationRevision._EHSLocationType._Text[1: Language = $session.system_language].EHSLocationTypeText,

         @Search: { defaultSearchElement: true,
                    fuzzinessThreshold: 1,
                    ranking: #MEDIUM }
         _EHSLocationRevision.CostCenter,

         // DCL related fields

         @Consumption.hidden: true
         _EHSLocationRevision.EHSLocationStatus,
         @Consumption.hidden: true
         cast(_EHSLocationRevision.EHSLocationAuthorizationGroup as ehfnd_loc_auth_group_nc preserving type ) as EHSLocationAuthorizationGroup,
         @Consumption.hidden: true
         _EHSLocationRevision.ControllingArea,
         @Consumption.hidden: true
         _EHSLocationRevision.CompanyCode,
         @Consumption.hidden: true
         _EHSLocationRevision.BusinessArea,

         I_EHSLocationHierarchyNode._EHSParentLocation,
         I_EHSLocationHierarchyNode._EHSLocation,
         @Consumption.hidden: true
         _EHSLocationTypeVH,
         _EHSLocationRevision
}


where
  I_EHSLocationHierarchyNode.EHSParentLocationUUID <> hextobin('00000000000000000000000000000000')
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_CURRENTEHSLOCATIONNAMETEXT",
"I_EHSLOCATIONHIERARCHYNODE",
"I_EHSLOCATIONHIERARCHYREVISION",
"I_EHSLOCATIONREVISION",
"I_EHSLOCATIONTYPE",
"I_EHSLOCATIONTYPETEXT",
"I_SAFETYINSTRUCTIONDEFINITION"
],
"ASSOCIATED":
[
"C_EHSLOCATIONTYPEVH",
"I_EHSLOCATIONREVISION",
"I_EHSLOCATIONROOT"
],
"BASE":
[
"I_EHSLOCATIONHIERARCHYNODE"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/