I_RangeOfCoverageProfileText

@AbapCatalog.sqlViewName: 'IRANGEOFCOVERTXT'
@AbapCatalog.buffering: {status: #ACTIVE, type: #GENERIC, numberOfKeyFields: 001}
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #NOT_REQUIRED
@ClientHandling.algorithm: #SESSION_VARIABLE
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.dataCategory: #TEXT
@ObjectModel.modelingPattern: #LANGUAGE_DEPENDENT_TEXT
@ObjectModel.supportedCapabilities: [#LANGUAGE_DEPENDENT_TEXT, #SQL_DATA_SOURCE, #CDS_MODELING_DATA_SOURCE, #SEARCHABLE_ENTITY]
@ObjectModel.representativeKey: 'RangeOfCoverageProfile'
@ObjectModel.usageType: {serviceQuality: #A, sizeCategory: #S, dataClass: #CUSTOMIZING}
@Search.searchable: true
@VDM.lifecycle.contract.type: #PUBLIC_LOCAL_API
@VDM.viewType: #BASIC
@EndUserText.label: 'Range of Coverage Profile - Text'

define view I_RangeOfCoverageProfileText
  as select from t438s as txt
  
  association [1..1] to I_Plant                  as _Plant    on  $projection.Plant    = _Plant.Plant
  association [0..1] to I_Language               as _Language on  $projection.Language = _Language.Language
  association [1..1] to I_RangeOfCoverageProfile as _Profile  on  $projection.Plant                  = _Profile.Plant
                                                              and $projection.RangeOfCoverageProfile = _Profile.RangeOfCoverageProfile
{
      @ObjectModel.foreignKey.association: '_Plant'
  key werks                                            as Plant,
      @ObjectModel.foreignKey.association: '_Profile'  
      @ObjectModel.text.element: ['RangeOfCoverageProfileName']
  key cast(rwpro as pph_rwpro preserving type)         as RangeOfCoverageProfile,
      @ObjectModel.foreignKey.association: '_Language'
      @Semantics.language: true
  key txt.spras                                        as Language,
      @Search: {defaultSearchElement: true, ranking: #LOW, fuzzinessThreshold: 0.8}
      @Semantics.text: true
      cast(txt.text40 as pph_rwprotxt preserving type) as RangeOfCoverageProfileName,

      //Associations

      @ObjectModel.association.type: [#TO_COMPOSITION_PARENT, #TO_COMPOSITION_ROOT]
      _Profile,
      _Plant,
      _Language
};
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"T438S"
],
"ASSOCIATED":
[
"I_LANGUAGE",
"I_PLANT",
"I_RANGEOFCOVERAGEPROFILE"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/