I_RSHProjectAssignmentHrs

@AbapCatalog.sqlViewName: 'IRSHPRJASGPHR'
@AccessControl.privilegedAssociations:  [ '_ProjectAssignmentPerDay' ]
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #CHECK
@ObjectModel.usageType.dataClass: #TRANSACTIONAL
@ObjectModel.usageType.serviceQuality: #D
@ObjectModel.usageType.sizeCategory: #XL
@ObjectModel.supportedCapabilities: [#CDS_MODELING_DATA_SOURCE,#CDS_MODELING_ASSOCIATION_TARGET,#EXTRACTION_DATA_SOURCE]
@Analytics.dataExtraction.enabled: true
@VDM.viewType: #COMPOSITE
@ClientHandling.algorithm: #SESSION_VARIABLE
@Metadata.ignorePropagatedAnnotations: true  
@VDM.lifecycle.contract.type: #PUBLIC_LOCAL_API 
@AccessControl.personalData.blocking: #REQUIRED
@AccessControl.personalData.blockingIndicator: ['IsBusinessPurposeCompleted','IsBusPrpsCmpltdProjectManager','IsBusPrpsCmpltdCustomer']
@EndUserText.label: 'Resource Assignments'

/*
CONTRACT**********************************************************************************************************************

Name:                       RELEASED CDS VIEW for Project Assignment
Specification:              Read Only CDS View for Customer use in View Builder to read Assginment Data
Requires:                   NA
Ensures:                    NA
Owners:                     TR
Contributors:               NA
Unit Test required Y/N:     N
Additional comments         None

END OF CONTRACT***************************************************************************************************************
*/


define view I_RSHProjectAssignmentHrs   

  as select from I_RSHProjectAssignment as ProjectAssignment
 
  association [0..*] to P_RSHResourceTimeSlice       as _Resource                on  _Resource.EmploymentInternalID = $projection.EmploymentInternalID
                                                                                 and _Resource.StartDate            <= $projection.ProjAssignmentStartDate
                                                                                 and _Resource.EndDate              >= $projection.ProjAssignmentStartDate 


  association [0..1] to P_RSHStaffingRequestDetails     as _Request                      on  _Request.ResourceDemandUUID = $projection.ResourceDemandUUID
 
   
  association [0..*] to I_RSHProjectAssignmentDailyHrs as _ProjectAssignmentPerDay on  _ProjectAssignmentPerDay.ProjAssignmentUUID = $projection.ProjAssignmentUUID
  
  association [0..1] to I_EngmntProjPlanConfig as _EngmtProjPlanConfig on _EngmtProjPlanConfig.ProjectProfileCode = 'P001'
  
 
{
  key ProjectAssignment.ProjAssignmentUUID       as ProjAssignmentUUID,
      ProjectAssignment.ResourceDemandUUID       as ResourceDemandUUID,
      ProjectAssignment.EmploymentInternalID     as EmploymentInternalID,
      ProjectAssignment.ProjAssignmentStartDate  as ProjAssignmentStartDate,
      ProjectAssignment.ProjAssignmentEndDate    as ProjAssignmentEndDate,
      ProjectAssignment.ProjAssignmentTotalHours as ProjAssignmentTotalHours,
      ProjectAssignment.SourceOfSupply           as SourceOfSupply,
      
      // Resource Specific Data for DCL

      _Resource.CompanyCode,
      _Resource.CostCenter,
      
       @Consumption.hidden: true
      _Resource.AuthorizationGroup,
      
       @Consumption.hidden: true
      _Resource.IsBusinessPurposeCompleted,
      
      // Request Specific Data for DCL

      _Request.ServiceOrganization,
      _Request.EmployeeRequestHdrSrvOrg,
      _Request.EmployeeRequestDelivOrg,
      _Request.ProjectVisibility,
      
       @Consumption.hidden: true
      _Request._Customer.IsBusinessPurposeCompleted as IsBusPrpsCmpltdCustomer,
       @Consumption.hidden: true
      _Request._Customer.AuthorizationGroup as CustomerAuthznGrp,
      @Consumption.hidden: true
      _Request._ProjectManager._WorkforcePerson.IsBusinessPurposeCompleted   as IsBusPrpsCmpltdProjectManager,  
       @Consumption.hidden: true                                                                     
      _Request._ProjectManager._WorkforcePerson.AuthorizationGroup           as ProjectManagerAuthznGrp,
             
      // Association to Per Day Assignments

      _ProjectAssignmentPerDay,
      
      @Semantics.booleanIndicator 
      _EngmtProjPlanConfig.ExternalStaffingIsActive                          as ExternalStaffingIsActive
}
where _EngmtProjPlanConfig.ExternalStaffingIsActive = '' 
   or _EngmtProjPlanConfig.ExternalStaffingIsActive = ' '
   or _EngmtProjPlanConfig.ExternalStaffingIsActive is null
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_CUSTOMER",
"I_ENGMNTPROJPLANCONFIG",
"I_PERSONWORKAGREEMENT_1",
"I_RSHPROJECTASSIGNMENT",
"I_WORKFORCEPERSON",
"P_RSHRESOURCETIMESLICE",
"P_RSHSTAFFINGREQUESTDETAILS"
],
"ASSOCIATED":
[
"I_ENGMNTPROJPLANCONFIG",
"I_RSHPROJECTASSIGNMENTDAILYHRS",
"P_RSHRESOURCETIMESLICE",
"P_RSHSTAFFINGREQUESTDETAILS"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/