I_RSHMaintSchedWrkCtrCap

@AbapCatalog.sqlViewName: 'IRSHMNTSCHWCCAP'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #CHECK

@Metadata.ignorePropagatedAnnotations:true
@VDM.lifecycle.contract.type:#SAP_INTERNAL_API

@ObjectModel.usageType.dataClass: #TRANSACTIONAL
@ObjectModel.usageType.serviceQuality: #X
@ObjectModel.usageType.sizeCategory: #XL
@VDM.viewType: #BASIC
@ClientHandling.algorithm: #SESSION_VARIABLE

@EndUserText.label: 'Work Center Capacity of Frozen Schedules'

/*
CONTRACT**********************************************************************************************************************

Name:                       Work Center capacity of frozen schedules
Specification:              This view retrieves the snapshot of the work center capacity at the time of schedule freeze
Requires:                   Only the schedules that are frozen have an entry in the table
Owners:                     PSP
Contributors:
Unit Test required Y/N:     No
Additional comments         NA

END OF CONTRACT***************************************************************************************************************
*/

define view I_RSHMaintSchedWrkCtrCap
  as select from rsh_d_mntschdwc
    inner join   I_WorkCenter on  I_WorkCenter.WorkCenterInternalID = rsh_d_mntschdwc.workcenterinternalid
                              and I_WorkCenter.WorkCenterTypeCode   = rsh_d_mntschdwc.workcentertypecode
  association [1..1] to I_RSHMaintSchedSimulation as _MaintSchedSimulation on _MaintSchedSimulation.MaintSchedSimlnUUID = $projection.MaintSchedSimlnUUID
{

      //rsh_d_mntschdwc

  key maintschedsimlnuuid                  as MaintSchedSimlnUUID,
  key rsh_d_mntschdwc.workcenterinternalid as WorkCenterInternalID,
      rsh_d_mntschdwc.workcentertypecode   as WorkCenterTypeCode,
      I_WorkCenter.WorkCenter              as WorkCenter,
      @Semantics.quantity.unitOfMeasure: 'TotalPlannedCapacityUnit'
      totalplannedcapacity                 as TotalPlannedCapacity,
      //Mandatory since planned capacity is a declared as a field of type 'quantity' in GFC

      cast('s' as unit)                    as TotalPlannedCapacityUnit, 
      @Semantics.quantity.unitOfMeasure: 'TotalAvailableCapacityUnit'
      totalavailablecapacity               as TotalAvailableCapacity,
      //Mandatory since available capacity is a declared as a field of type 'quantity' in GFC

      cast('s' as unit)                    as TotalAvailableCapacityUnit,  
      Plant,
      WorkCenterCategoryCode,

      @ObjectModel.association.type: [ #TO_COMPOSITION_ROOT, #TO_COMPOSITION_PARENT ]
      _MaintSchedSimulation

}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_WORKCENTER",
"RSH_D_MNTSCHDWC"
],
"ASSOCIATED":
[
"I_RSHMAINTSCHEDSIMULATION"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/