I_RO_SAFTPurInvoiceLineItem

@AbapCatalog.sqlViewName: 'IROSAFTPURLITM'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@VDM.viewType: #COMPOSITE
@AccessControl.authorizationCheck: #CHECK
@ObjectModel.usageType.sizeCategory: #XXL
@ObjectModel.usageType.dataClass:  #MIXED
@ObjectModel.usageType.serviceQuality: #X
@Analytics: { dataCategory: #DIMENSION }
@Analytics.internalName:#LOCAL
@ClientHandling.algorithm: #SESSION_VARIABLE
@AbapCatalog.buffering.status: #NOT_ALLOWED
//@Metadata.ignorePropagatedAnnotations: true

@Metadata.allowExtensions:true
//@ObjectModel.representativeKey: 'AccountingDocument'

@AccessControl.personalData.blocking: #REQUIRED
@ObjectModel.supportedCapabilities: [#CDS_MODELING_ASSOCIATION_TARGET,
                                     #CDS_MODELING_DATA_SOURCE,
                                     #SQL_DATA_SOURCE]
@EndUserText.label: 'RO SAFT Purchase Invoice Line Item'
define view I_RO_SAFTPurInvoiceLineItem
  as select distinct from I_RO_SAFTAccountingItem      as _InvoiceLineItem
    join         I_RO_SAFTPurInvoiceTaxAmount as AnalysisAmount on  AnalysisAmount.AccountingDocument = _InvoiceLineItem.AccountingDocument
                                                                and AnalysisAmount.CompanyCode        = _InvoiceLineItem.CompanyCode
                                                                and AnalysisAmount.FiscalYear         = _InvoiceLineItem.FiscalYear
  association [0..1] to I_ProductText                  as _description    on  $projection.Product   = _description.Product
                                                                          and _description.Language = '4'
  association [0..1] to I_RO_SAFTUnitOfMeasureMap      as _Uom            on  $projection.BaseUnit = _Uom.SourceUnitOfMeasure
  association [0..1] to I_Product                      as _Product        on  $projection.Product = _Product.Product
  association [0..1] to I_ProductUnitsOfMeasure        as _ProductUom     on  $projection.Product = _ProductUom.Product
  association [0..1] to I_RO_SAFTSalesInvcAnalysisType as _Analysis       on  _InvoiceLineItem.CompanyCode = _Analysis.CompanyCode
                                                                          and _InvoiceLineItem.CostCenter  = _Analysis.CostCenter
  association [0..1] to I_SalesDocumentBasic           as _OrderReference on  _InvoiceLineItem.SalesOrder = _OrderReference.SalesDocument
  association [0..1] to I_RO_SAFTPurInvoiceItemAmount  as _InvoiceLineAmt on  _InvoiceLineItem.CompanyCode        = _InvoiceLineAmt.CompanyCode
                                                                          and _InvoiceLineItem.AccountingDocument = _InvoiceLineAmt.AccountingDocument
                                                                          and _InvoiceLineItem.FiscalYear         = _InvoiceLineAmt.FiscalYear
                                                                          and _InvoiceLineItem.AccountingDocumentItem = _InvoiceLineAmt.AccountingDocumentItem
  association [0..1] to I_RO_SAFTPurInvoiceTaxInfo     as _TaxInfo        on  _InvoiceLineItem.CompanyCode        = _TaxInfo.CompanyCode
                                                                          and _InvoiceLineItem.AccountingDocument = _TaxInfo.AccountingDocument
                                                                          and _InvoiceLineItem.FiscalYear         = _TaxInfo.FiscalYear
                                                                          and _InvoiceLineItem.AccountingDocumentItem = _TaxInfo.AccountingDocumentItem
{
      _InvoiceLineItem.AccountingDocument                                                 as AccountingDocument,
      _InvoiceLineItem.AccountingDocumentItem                                             as AccountingDocumentItem,
      _InvoiceLineItem.AccountingDocumentItemRef                                          as AccountingDocumentItemRef,
      _InvoiceLineItem.TargetGLAccount                                                    as TargetGLAccount,
      _InvoiceLineItem.CompanyCode                                                        as CompanyCode,
      _InvoiceLineItem.FiscalYear                                                         as FiscalYear,
      _InvoiceLineItem.SalesOrder                                                         as SalesOrder,
      //Analysis

      _Analysis.RO_SAFTAnalysisType                                                       as RO_SAFTAnalysisType,
      _Analysis.CostCenter                                                                as CostCenter,
      ///ceecv/rocvalanl.anals_type as AnalysisType,


      //OrderReferences,

      _OrderReference.SalesDocumentDate                                                       as SalesOrderDate,
      _OrderReference.SalesDocument                                                         as OriginSDDocument,

//      _OrderReference.SalesOrderDate                                                      as SalesOrderDate,

//      _OrderReference.OriginSDDocument                                                    as OriginSDDocument,

      _InvoiceLineItem.Product                                                            as Product,
      _description.ProductName                                                            as ProductDescription,
      @Semantics.quantity.unitOfMeasure : 'BaseUnit'
      _InvoiceLineItem.Quantity                                                           as Quantity,
      _InvoiceLineItem.ProductPriceUnitQuantity,

      //GoodsServicesID


      _InvoiceLineItem.BaseUnit                                                           as BaseUnit,
      _Uom.SourceUnitOfMeasureFactor                                                      as SourceUnitOfMeasureFactor,
      _ProductUom.AlternativeUnit                                                         as AlternativeUnit,
      _InvoiceLineItem.DocumentItemText                                                   as DocumentItemText,
      @Semantics.quantity.unitOfMeasure : 'AlternativeUnit'
      _ProductUom.QuantityNumerator                                                       as QuantityNumerator,
      @Semantics.quantity.unitOfMeasure : 'AlternativeUnit'
      _ProductUom.QuantityDenominator                                                     as QuantityDenominator,

      case when ( _Uom.SourceUnitOfMeasureFactor = _ProductUom.AlternativeUnit )
        then 1
        else 0
      end                                                                                 as ConversionFactor,

      cast( case when _Product.ProductType = 'DIEN'
                 then 02
                 else 01
        end  as mtart )                                                                   as MaterialType, //GoodsServicesID,


      //InvoiceLineAmount

      //AnalysisAmount.bukrs,

      //AnalysisAmount.belnr,

      @Semantics.amount.currencyCode : 'TransactionCurrency'
      AnalysisAmount.TotalVATAmtInCoCodeCrcy,
      @Semantics.amount.currencyCode : 'TransactionCurrency'
      _InvoiceLineAmt.TransactionAmountInLocalCrcy                                        as TotalAmountInLocalCurrency,
      _InvoiceLineAmt.TransactionCurrency                                                 as TransactionCurrency,
      @Semantics.amount.currencyCode : 'TransactionCurrency'
      _InvoiceLineAmt.InvoiceAmountInInvoiceDocCrcy                                       as TotalAmountInSourceCurrency,
      @Semantics.amount.currencyCode : 'TransactionCurrency'
      AnalysisAmount.TaxAmountInDocCry,
      cast(round(AnalysisAmount.ExchangeRate, 4) as saft_ro_exchange_rate)                as ExchangeRate,
      _InvoiceLineItem.DebitCreditCode                                                    as DebitCreditCode,

      //  TaxInformation

      _TaxInfo.RO_SAFTTaxType                                                             as RO_SAFTTaxType,
      _TaxInfo.RO_SAFTTaxCode                                                             as RO_SAFTTaxCode,
      _TaxInfo.TaxRateInPercent                                                           as TaxRateInPercent,
      _TaxInfo.TaxRate                                                                    as TaxRate,
      _TaxInfo.RO_SAFTTaxBaseDescription                                                  as RO_SAFTTaxBaseDescription,
      @Semantics.amount.currencyCode : 'SDTransactionCurrency'
      _TaxInfo.TotalVATAmtInCoCodeCrcy                                                    as TotalTaxAmount,
      _TaxInfo.TransactionCurrency                                                        as SDTransactionCurrency,
      @Semantics.amount.currencyCode : 'SDTransactionCurrency'
      _TaxInfo.TaxAmountInDocCry                                                          as TaxAmountInTransCrcy,
      cast(round(_TaxInfo.ExchangeRate, 4) as saft_ro_exchange_rate)                      as TaxExchangeRate,
      _TaxInfo.TaxExemptCode                                                              as TaxExemptCode,
      _TaxInfo.GenerationYear                                                             as GenerationYear
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_PRODUCT",
"I_PRODUCTTEXT",
"I_PRODUCTUNITSOFMEASURE",
"I_RO_SAFTACCOUNTINGITEM",
"I_RO_SAFTPURINVOICEITEMAMOUNT",
"I_RO_SAFTPURINVOICETAXAMOUNT",
"I_RO_SAFTPURINVOICETAXINFO",
"I_RO_SAFTSALESINVCANALYSISTYPE",
"I_RO_SAFTUNITOFMEASUREMAP",
"I_SALESDOCUMENTBASIC"
],
"ASSOCIATED":
[
"I_PRODUCT",
"I_PRODUCTTEXT",
"I_PRODUCTUNITSOFMEASURE",
"I_RO_SAFTPURINVOICEITEMAMOUNT",
"I_RO_SAFTPURINVOICETAXINFO",
"I_RO_SAFTSALESINVCANALYSISTYPE",
"I_RO_SAFTUNITOFMEASUREMAP",
"I_SALESDOCUMENTBASIC"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/