I_REObjectAssgmtHierAddl

@AbapCatalog.sqlViewName: 'IREOBJASGMTHADDL'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #NOT_REQUIRED //#CHECK


@ClientHandling.algorithm: #SESSION_VARIABLE
@VDM.viewType : #COMPOSITE // BASIC

@Metadata.ignorePropagatedAnnotations: true

@AccessControl.personalData.blocking: #NOT_REQUIRED

@ObjectModel: {
  semanticKey: ['InternalRealEstateNumber','REStatusObjectSource', 'REObjectAssignmentType', 'REStatusObjectTarget', 'ValidityStartDate'],
  usageType.serviceQuality: #D,
  usageType.sizeCategory: #L,
  usageType.dataClass: #MIXED
}
@VDM.lifecycle.contract.type: #SAP_INTERNAL_API
@EndUserText.label: 'IO Object Assgmt Hierarchy Additional'
define view I_REObjectAssgmtHierAddl
  as select from I_REObjectAssgmtHier
  association [0..1] to I_REAccountingObject as _REAccountingObject on $projection.REStatusObjectTarget = _REAccountingObject.REAccountingObject
  association [1..1] to I_REEntryValidity    as _REEntryValidity    on $projection.REEntryValidity = _REEntryValidity.REEntryValidity
{
  key  REStatusObjectSource,
  key  REObjectAssignmentType,
  key  REStatusObjectTarget,
  key  cast(concat(ValidityStartDate, ValidityEndDate ) as recadateperiod) as ValidityStartEndDateValue,
  key  InternalRealEstateNumber,
       ValidityStartDate,
       ValidityEndDate,

        case REObjectTypeTarget
          when 'J4'
          then  cast(_REContractSubject.REContractSubjectDescription as recadescription ) 
          when 'J5'
          then  cast(_REObjectTypeDetails._REIntegrationObject.REIntegrationObjectName as recadescription ) 
          when 'IW'
          then  cast(_REObjectTypeDetails._REBusinessEntity.REBusinessEntityName as recadescription  ) 
          when 'IB'
          then  cast(_REObjectTypeDetails._REBuilding.REBuildingName as recadescription  ) 
          when 'IG'
          then  cast(_REObjectTypeDetails._REProperty.REPropertyName as recadescription ) 
          when 'IM'
          then  cast(_REObjectTypeDetails._RERentalObject.RERentalObjectName as recadescription  )     
          when 'IS'
          then  cast(_REObjectTypeDetails._REContract.REContractName as recadescription  )                    
          when 'KS'
          then  cast(_CostCenter[1: ValidityEndDate >= $session.system_date and ValidityStartDate <= $session.system_date]._Text[1: Language = $session.system_language ].CostCenterName as recadescription  )      
          when 'OR'
          then  cast(_InternalOrder.InternalOrderDescription as recadescription  )                
          when 'PR'
          then  cast(_WBSElement.WBSDescription as recadescription )  
        end as REObjectText, 
        
        case REObjectTypeTarget
          when 'KS'
          then  _CostCenter[1: ValidityEndDate >= $session.system_date and ValidityStartDate <= $session.system_date].ControllingArea 
          when 'OR'
          then  _InternalOrder.ControllingArea 
          when 'PR'
          then _WBSElement.ControllingArea 
          else _REObjectTypeDetails._REKeyAssgmt._CompanyCode.ControllingArea
        end as ControllingArea, 
        
        case REObjectTypeTarget
          when 'KS'
          then _CostCenter[1: ValidityEndDate >= $session.system_date and ValidityStartDate <= $session.system_date].CompanyCode
          when 'OR'
          then _InternalOrder.CompanyCode
          when 'PR'
          then _WBSElement.CompanyCode
          else _REObjectTypeDetails._REKeyAssgmt.CompanyCode
        end as CompanyCode,

       @ObjectModel.foreignKey.association: '_REEntryValidity'
       case
       //           when ValidityStartDate is initial then cast ('0' as recavdmentryvalidity)

           when ValidityStartDate is initial and ValidityEndDate is initial then cast ('3' as recavdmentryvalidity)
           when ValidityStartDate > $session.system_date then cast ('2' as recavdmentryvalidity)
           when ValidityStartDate <= $session.system_date and ValidityEndDate >= $session.system_date then cast('3' as recavdmentryvalidity)
           else cast ('1' as recavdmentryvalidity)
       end                                                                 as REEntryValidity,

       case
       //           when ValidityStartDate is initial then 0

           when ValidityStartDate is initial and ValidityEndDate is initial then 3
           when ValidityStartDate > $session.system_date then 2
           when ValidityStartDate <= $session.system_date and ValidityEndDate >= $session.system_date then 3
       else 1
       end                                                                 as REEntryValidityCriticality,

       _REAccountingObject,
       _REEntryValidity
}
//where _CostCenter.ValidityStartDate            <= $session.system_date

//  and _CostCenter.ValidityEndDate              >= $session.system_date

/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_COMPANYCODE",
"I_COSTCENTER",
"I_COSTCENTERTEXT",
"I_INTERNALORDER",
"I_REBUILDING",
"I_REBUSINESSENTITY",
"I_RECONTRACT",
"I_RECONTRACTSUBJECT",
"I_REINTEGRATIONOBJECT",
"I_REKEYASSGMT",
"I_REOBJECTASSGMTHIER",
"I_REOBJECTTYPEDETAILS",
"I_REPROPERTY",
"I_RERENTALOBJECT",
"I_WBSELEMENTBASICDATA"
],
"ASSOCIATED":
[
"I_REACCOUNTINGOBJECT",
"I_REENTRYVALIDITY"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/