I_REObjectAssgmtAddl

@AbapCatalog.sqlViewName: 'IREOBJLASSGMTADD'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #NOT_REQUIRED //#CHECK


@ClientHandling.algorithm: #SESSION_VARIABLE
@VDM.viewType : #COMPOSITE // BASIC

@Metadata.ignorePropagatedAnnotations: true

@AccessControl.personalData.blocking: #NOT_REQUIRED

@ObjectModel: {
//  representativeKey: 'RETermNumber',

  semanticKey: ['REStatusObjectSource', 'REObjectAssignmentType', 'REStatusObjectTarget', 'InternalRealEstateNumber' ],
  usageType.serviceQuality: #D,
  usageType.sizeCategory: #L,
  usageType.dataClass: #MIXED
}
@VDM.lifecycle.contract.type: #SAP_INTERNAL_API
@EndUserText.label: 'RE Object Assignment additional'
define view I_REObjectAssgmtAddl as select from I_REObjectAssgmtHier
 {

  key   REStatusObjectSource,
  key   REObjectAssignmentType,
 // @ObjectModel.text.element: ['REIdentification']

  key   REStatusObjectTarget,
  key   cast( concat( ValidityStartDate, ValidityEndDate ) as recadateperiod ) as ValidityStartEndDateValue,
      // new for TP composition purpose

  key   InternalRealEstateNumber,
        REStatusObjectSourceIsArchived,
        REGenerationType,
        REIsMainAsset,
        REAssignmentHasMultiple,  
         
        case REObjectTypeTarget
          when 'J4'
          then  cast(_REContractSubject.REContractSubjectDescription as recadescription ) 
          when 'J5'
          then  cast(_REObjectTypeDetails._REIntegrationObject.REIntegrationObjectName as recadescription ) 
          when 'J6'
          then  cast(_REObjectTypeDetails._REServiceGroup.REServiceGroupName as recadescription )             
          when 'IS'
          then  cast(_REObjectTypeDetails._REContract.REContractName as recadescription  )                    
          when 'KS'
          then  cast(_CostCenter[1: ValidityEndDate >= $session.system_date and ValidityStartDate <= $session.system_date]._Text[1: Language = $session.system_language ].CostCenterName as recadescription  )      
          when 'OR'
          then  cast(_InternalOrder.InternalOrderDescription as recadescription  )                
          when 'PR'
          then  cast(_WBSElement.WBSDescription as recadescription )  
          else cast( ' ' as recadescription ) 
//          else _REObjectTarget.REObjectText

        end as REObjectText, 
        
        _REGenerationType
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_COSTCENTER",
"I_COSTCENTERTEXT",
"I_INTERNALORDER",
"I_RECONTRACT",
"I_RECONTRACTSUBJECT",
"I_REINTEGRATIONOBJECT",
"I_REOBJECTASSGMTHIER",
"I_REOBJECTTYPEDETAILS",
"I_RESERVICEGROUP",
"I_WBSELEMENTBASICDATA"
],
"ASSOCIATED":
[
"I_REGENERATIONTYPE"
],
"BASE":
[
"I_REOBJECTASSGMTHIER"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/