I_RELocalTaxMap

@AbapCatalog.sqlViewName: 'IRETAXMAP'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #NOT_REQUIRED
@Analytics.dataCategory: #DIMENSION
@Analytics.internalName:#LOCAL
@ClientHandling.algorithm: #SESSION_VARIABLE
@EndUserText.label: 'Local Tax Group'
@ObjectModel.usageType.dataClass: #CUSTOMIZING
@ObjectModel.usageType.serviceQuality: #B
@ObjectModel.usageType.sizeCategory: #S
@ObjectModel.representativeKey: 'RETaxGroup'
@ObjectModel.semanticKey: ['RETaxGroup']
@VDM.viewType:#BASIC
@Search.searchable: true

define view I_RELocalTaxMap
  as select from tivexfitaxmap
    inner join   t007a         as tax_code     on tivexfitaxmap.taxcode = tax_code.mwskz
    inner join   t005          as country_data on  tax_code.kalsm     = country_data.kalsm
                                               and country_data.land1 = tivexfitaxmap.country
    inner join   tivrataxtype  as RETaxType    on  RETaxType.taxtype = tivexfitaxmap.taxtype
                                               and RETaxType.country = tivexfitaxmap.country
  association [0..1] to I_RETaxGroup as _RETaxGroup on tivexfitaxmap.taxgroup = _RETaxGroup.TaxGroup
  association [0..1] to I_Country    as _Country    on $projection.Country = _Country.Country
{
      @ObjectModel.foreignKey.association: '_Country'
      @Search.defaultSearchElement: true
      @Search.fuzzinessThreshold: 0.8
      @Search.ranking: #HIGH
  key tivexfitaxmap.country               as Country,
      @Search.defaultSearchElement: true
      @Search.fuzzinessThreshold: 0.8
      @Search.ranking: #HIGH
  key tivexfitaxmap.taxtype               as RETaxType,
  key tivexfitaxmap.taxgroup              as RETaxGroup,
  key cast(validfrom as rebdvdmvalidfrom) as ValidityStartDate,
      cast(validto as rebdvdmvalidto)     as ValidityEndDate,
      tivexfitaxmap.taxcode               as TaxCode,
      tax_code.xinact                     as REIsExclForNewAssgmt,

      _RETaxGroup,
      _Country

}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"T005",
"T007A",
"TIVEXFITAXMAP",
"TIVRATAXTYPE"
],
"ASSOCIATED":
[
"I_COUNTRY",
"I_RETAXGROUP"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/