I_REIntegObjectLevel3VH

@AbapCatalog.sqlViewName: 'IREINTOBJLVL3VH'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey:true

@VDM.viewType: #COMPOSITE

@ObjectModel.dataCategory: #VALUE_HELP

@ObjectModel.usageType.dataClass: #MASTER
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #L

@AccessControl.authorizationCheck: #CHECK

@ClientHandling.algorithm: #SESSION_VARIABLE

@Search.searchable: true

@Metadata.ignorePropagatedAnnotations: true
@EndUserText.label: 'Real Estate Space/Land Area Help'

define view I_REIntegObjectLevel3VH
  as select from I_REIntegrationObjectSubObj

  association [1..1] to I_REIntegrationObject as _REIntegrationObjLvl0         on  _REIntegrationObjLvl0.InternalRealEstateNumber = $projection.InternalRealEstateNumberLvl0
  association [1..1] to I_REIntegrationObject as _REIntegrationObjLvl1Building on  _REIntegrationObjLvl1Building.InternalRealEstateNumber = $projection.InternalRealEstateNumberLvl1
                                                                               and _REIntegrationObjLvl1Building.REIntegrationObjectType  = 'C4BU'
  association [1..1] to I_REIntegrationObject as _REIntegrationObjLvl1Land     on  _REIntegrationObjLvl1Land.InternalRealEstateNumber = $projection.InternalRealEstateNumberLvl1
                                                                               and _REIntegrationObjLvl1Land.REIntegrationObjectType  = 'C4PR'
  association [1..1] to I_REIntegrationObject as _REIntegrationObjLvl2         on  _REIntegrationObjLvl2.InternalRealEstateNumber = $projection.InternalRealEstateNumberLvl2
  association [1..1] to I_REIntegrationObject as _REIntegrationObjLvl3         on  _REIntegrationObjLvl3.InternalRealEstateNumber = $projection.InternalRealEstateNumberLvl3

{
           @UI.hidden: true
  key      InternalRealEstateNumberLvl3,

           //Level 3

           @ObjectModel.foreignKey.association: '_REIntegObjectType'
           @Consumption.hidden: true
           _REIntegrationObjLvl3.REIntegrationObjectType,
           @Consumption.hidden: true
           @ObjectModel.foreignKey.association: '_RESpaceGroupUsageType'
           _REIntegrationObjLvl3.RESpaceGroupUsageType,
           @Consumption.hidden: true
           @Consumption.valueHelpDefinition: [{   entity: {name: 'I_RESpaceGrpEnableUseType', element: 'RESpaceGrpEnableUseType' } }]
           _REIntegrationObjLvl3.RESpaceGrpEnableUseType,
           @Consumption.hidden: true
            @Consumption.valueHelpDefinition: [{   entity: {name: 'C_REUseEnableObjSpaceGrpTypeVH', element: 'REIntegObjSpaceGroupType' } }]
           _REIntegrationObjLvl3.REIntegObjSpaceGroupType,
           @Search.defaultSearchElement: true
           @EndUserText.label: 'Space/Land Area Number'
           @ObjectModel.text.element: 'REIntegrationObjectName'
           _REIntegrationObjLvl3.REIntegrationObjectNumber,
           @Search.defaultSearchElement: true
           @Search.fuzzinessThreshold: 0.8
           @Search.ranking: #HIGH
           @EndUserText.label: 'Space/Land Area'
           _REIntegrationObjLvl3.REIntegrationObjectName,
           @Search.defaultSearchElement: true
           @Search.fuzzinessThreshold: 0.8
           @Search.ranking: #HIGH
           @EndUserText.label: 'Space/Land Area Long Name'
           _REIntegrationObjLvl3.REIntegObjectLongName,
           @Consumption.hidden: true
           _REIntegrationObjLvl3.REParentIntegObjectType,
           @Consumption.hidden: true
           _REIntegrationObjLvl3.REParentIntegObjectExternalID,
           @Consumption.hidden: true
           _REIntegrationObjLvl3.Responsible,
           @Consumption.hidden: true
           _REIntegrationObjLvl3.REAuthorizationGroup,

           @Consumption.hidden: true
           _REIntegrationObjLvl3._REIntegObjectType,
           @Consumption.hidden: true
           _REIntegrationObjLvl3._REParentIntegObjectType,
           @Consumption.hidden: true
           _REIntegrationObjLvl3._REIntegObjSpaceGroupType,
           @Consumption.hidden: true
           _REIntegrationObjLvl3._RESpaceGroupUsageType,
           @Consumption.hidden: true
           _REIntegrationObjLvl3._RESpaceGrpEnableUseType,
           _REIntegrationObjLvl3.ValidityStartDate               as ValidityStartDateLvl3,
           _REIntegrationObjLvl3.ValidityEndDate                 as ValidityEndDateLvl3,

           //Level 0

           @Consumption.hidden: true
           InternalRealEstateNumberLvl0,
           @Search.defaultSearchElement: true
           @Search.fuzzinessThreshold: 0.8
           @Search.ranking: #HIGH
           @EndUserText.label: 'Site'
           REIntegObjectSiteName,

           //Level 1

           RealEstateExternalIDLvl1,
           @Consumption.hidden: true
           InternalRealEstateNumberLvl1,
           @Search.defaultSearchElement: true
           @Search.fuzzinessThreshold: 0.8
           @Search.ranking: #HIGH
           @EndUserText.label: 'Building'
           _REIntegrationObjLvl1Building.REIntegrationObjectName as REIntegObjectBuildingName,
           @Search.defaultSearchElement: true
           @Search.fuzzinessThreshold: 0.8
           @Search.ranking: #HIGH
           @EndUserText.label: 'Land'
           _REIntegrationObjLvl1Land.REIntegrationObjectName     as REIntegObjectLandName,  
                      
           //Level 2

           @Consumption.hidden: true
           RealEstateExternalIDLvl2,
           @Consumption.hidden: true
           InternalRealEstateNumberLvl2,
           @Search.defaultSearchElement: true
           @Search.fuzzinessThreshold: 0.8
           @Search.ranking: #HIGH
           @Consumption.hidden: true
           @EndUserText.label: 'Floor'
           _REIntegrationObjLvl2.REIntegrationObjectName         as REIntegObjectFloorName,
         
           _REIntegrationObjLvl0,
           _REIntegrationObjLvl1Building,
           _REIntegrationObjLvl1Land,
           _REIntegrationObjLvl2,
           _REIntegrationObjLvl3
}
where
     REIntegrationObjectType = 'C4SP'
  or REIntegrationObjectType = 'C4LA'
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_REINTEGRATIONOBJECT",
"I_REINTEGRATIONOBJECTSUBOBJ"
],
"ASSOCIATED":
[
"I_REINTEGOBJECTTYPE",
"I_REINTEGOBJSPACEGROUPTYPE",
"I_REINTEGRATIONOBJECT",
"I_RESPACEGROUPUSAGETYPE",
"I_RESPACEGRPENABLEUSETYPE"
],
"BASE":
[
"I_REINTEGRATIONOBJECT"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/