I_REContractType

@AbapCatalog.sqlViewName: 'IRECONTYPE'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #NOT_REQUIRED
@EndUserText.label: 'Real Estate Contract Type'
@ObjectModel.usageType.dataClass: #CUSTOMIZING
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #M
@ObjectModel.representativeKey: ['REContractType']
@ObjectModel.semanticKey: ['REContractType']
@ObjectModel.sapObjectNodeType.name: 'RealEstateContractType'
//@ClientDependent: true

@VDM.viewType: #BASIC
@ClientHandling.algorithm: #SESSION_VARIABLE
@AbapCatalog.preserveKey:true
//@Search.searchable: true

@ObjectModel.compositionRoot: true
@Metadata.ignorePropagatedAnnotations: true

@ObjectModel.modelingPattern:           #ANALYTICAL_DIMENSION
@ObjectModel.supportedCapabilities:  [  #ANALYTICAL_DIMENSION,
                                        #CDS_MODELING_ASSOCIATION_TARGET,
                                        #SQL_DATA_SOURCE,
                                        #EXTRACTION_DATA_SOURCE,
                                        #CDS_MODELING_DATA_SOURCE]

@Analytics:{
    dataCategory: #DIMENSION,
    internalName: #LOCAL,
    dataExtraction: {
        enabled: true
    }
}

// Double Maintenance with I_REContractType_2 required


define view  I_REContractType
  as select from tivcncctadd          as _ContractType
    join         I_REContractTypeFndn as _ContractTypeFndn on _ContractType.smvart = _ContractTypeFndn.REContractType
  association [0..*] to I_REContractTypeText as _Text on $projection.REContractType = _Text.REContractType
  association [1..*] to I_RETaxType          as _RETaxType             on $projection.RETaxType = _RETaxType.RETaxType
  association [0..1] to I_RETaxGroup         as _RETaxGroup            on $projection.TaxGroup = _RETaxGroup.TaxGroup
  association [0..1] to I_PlanningLevel      as _REFinanceDepositLevel on $projection.REFinanceDepositLevel = _REFinanceDepositLevel.PlanningLevel
{
      @ObjectModel.text.association: '_Text'
  key smvart           as REContractType,
      //gcvarnr as REScreenSequence,

      condgroup        as REConditionGroup,
//      nrnroff          as NumberRangeInterval,

      //home_url as REContractHomepage,

      adjustnumberbeg  as REAdjustNumberGroup,
      adjustnumberstep as REAdjustNumber,
      bproletype1      as REBusinessPartnerRole1,
      bproletype2      as REBusinessPartnerRole2,
      //bpappl as REApplicationCategory,

      usersupplier     as REContractUserSupplier,
      category         as REContractCategory,
      cfperiod         as RECashFlowPeriod,
      //optmeth as REOptionRateMethod,

//      @ObjectModel.foreignKey.association: '_RETaxType'

      taxtype          as RETaxType,
      @ObjectModel.foreignKey.association: '_RETaxGroup'
      taxgroup         as TaxGroup,
      cntypedeposit    as REContractDepositType,
      istaxfree        as REContractIsTaxFree,
      //nooptmeth as REIsOptionRateMethodRequired,

      //coseprof as RESettlementProfile,

      ntprocdefault    as RENoticeProcedure,
      cntypeusageind   as REInfluenceHoldings,
      @ObjectModel.foreignKey.association: '_REFinanceDepositLevel'
      cmcflevel        as REFinanceDepositLevel,
      //currencyassign as RECurrenyAssignment,

      ispossdenabled   as REIsPossessionDate,
      condgroupsum     as REConditionGroupTotal,
      @API.element.releaseState: #DEPRECATED
      @API.element.successor:    'REIsExclForNewAssgmt'
      @VDM.lifecycle.status:    #DEPRECATED
      @VDM.lifecycle.successor: 'REIsExclForNewAssgmt'
      cuexcludeassign  as REHasNewCreationAssignment,
      cuexcludeassign  as REIsExclForNewAssgmt,

      _ContractTypeFndn.NumberRangeInterval,
      _ContractTypeFndn.REUsageType,
      _ContractTypeFndn.REContractTypeCategory,
      _ContractTypeFndn.REIsAreaBasedRent,
      _ContractTypeFndn.REHasDistributionOnObject,

      _RETaxType,
      _RETaxGroup,
      _REFinanceDepositLevel,

      @ObjectModel.association.type: [#TO_COMPOSITION_CHILD]
      _Text


}
where
  _ContractTypeFndn.REIsNewContractType = 'X'
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_RECONTRACTTYPEFNDN",
"TIVCNCCTADD"
],
"ASSOCIATED":
[
"I_PLANNINGLEVEL",
"I_RECONTRACTTYPETEXT",
"I_RETAXGROUP",
"I_RETAXTYPE"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/