I_QualityTaskLongText

@AbapCatalog.sqlViewName: 'IQTSKLT'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@ClientHandling.algorithm: #SESSION_VARIABLE
@AccessControl.authorizationCheck: #MANDATORY
@VDM: { 
  viewType: #BASIC,
  lifecycle.contract.type: #PUBLIC_LOCAL_API
}
@ObjectModel.supportedCapabilities: 
    [ #SQL_DATA_SOURCE, #CDS_MODELING_DATA_SOURCE, #CDS_MODELING_ASSOCIATION_TARGET ]
@ObjectModel.modelingPattern: #NONE
@ObjectModel: {
    dataCategory: #TEXT,
    usageType: {
        dataClass: #TRANSACTIONAL,
        sizeCategory: #L,
        serviceQuality: #C
    },
    representativeKey: 'LongTextInternalNumber'
}
@EndUserText.label: 'Quality Task Long Text'
@Metadata.ignorePropagatedAnnotations: true

define view I_QualityTaskLongText as select from qtaskltext 

    association [1..1] to I_QualityTask         as _QualityTask         on $projection.QualityTaskInternalId = _QualityTask.QualityTaskInternalId    
    association [1..1] to I_Language            as _Language            on $projection.Language = _Language.Language
{
    @ObjectModel.foreignKey.association: '_QualityTask'
    key qmnum                                                       as QualityTaskInternalId,   
    
    @ObjectModel.foreignKey.association: '_Language'
    @Semantics.language: true
    key langu                                                       as Language,
    
    key counter                                                     as LongTextInternalNumber,
    
    textid                                                          as LongTextID,
    
    @Semantics.text
    content                                                         as QualityTaskLongText,
    
    created_by                                                      as LongTextCreatedByUser,
    cast( created_at as qlt_longtext_created_at preserving type )   as LongTextCreatedAt,
    changed_by                                                      as LongTextLastChangedByUser,
    cast( changed_at as qlt_longtext_changed_at preserving type )   as LongTextLastChangedAt,
    cast( mimetype as w3conttype )                                  as MimeType,
    
    /* Association */
    _QualityTask,
    _Language
        
} where qtaskltext.qmnum like '$%'
    and qtaskltext.manum = '0000'
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"QTASKLTEXT"
],
"ASSOCIATED":
[
"I_LANGUAGE",
"I_QUALITYTASK"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/