I_QualityInProcurement

@AbapCatalog.sqlViewName: 'IQLTYINPROCMT'
@ClientHandling.algorithm: #SESSION_VARIABLE
@EndUserText.label: 'Quality Info Record in Procurement'
@AccessControl.authorizationCheck: #CHECK
@VDM: {
    viewType: #BASIC,
    lifecycle.contract.type: #PUBLIC_LOCAL_API
}
@AccessControl.personalData.blocking: #REQUIRED
@ObjectModel.representativeKey: 'QltyInProcmtIntID'
@ObjectModel.usageType: { serviceQuality: #C, sizeCategory: #S, dataClass: #MASTER }

@Analytics: { dataCategory: #DIMENSION }
@Metadata.allowExtensions:true

// P_DocObjKeyForQltyInProcmt: used for building DocumentObjectKey


define view I_QualityInProcurement as select from qinf
    left outer to one join P_DocObjKeyForQltyInProcmt as _DocObjKeyForQltyInProcmt 
        on  qinf.zaehl = _DocObjKeyForQltyInProcmt.QltyInProcmtIntID
        and qinf.matnr = _DocObjKeyForQltyInProcmt.Material
        and qinf.werk  = _DocObjKeyForQltyInProcmt.Plant                
        and qinf.revlv = _DocObjKeyForQltyInProcmt.MaterialRevisionLevel   

  association [1..1] to I_Plant                         as _Plant                         on  $projection.Plant                       = _Plant.Plant
  association [1..1] to I_Material                      as _Material                      on  $projection.Material                    = _Material.Material
  association [1..1] to I_Productplantqtmanagement      as _ProductPlantQtManagement      on  $projection.Material                    = _ProductPlantQtManagement.Product
                                                                                          and $projection.Plant                       = _ProductPlantQtManagement.Plant
  association [0..1] to I_Supplier                      as _Supplier                      on  $projection.Supplier                    = _Supplier.Supplier
  association [0..1] to I_UnitOfMeasure                 as _UnitOfMeasure                 on  $projection.BaseUnit                    = _UnitOfMeasure.UnitOfMeasure
  association [0..1] to I_StatusProfile                 as _StatusProfile                 on  $projection.StatusProfile               = _StatusProfile.StatusProfile
  association [0..1] to I_User                          as _CreatedByUser                 on  $projection.CreatedByUser               = _CreatedByUser.UserID
  association [0..1] to I_User                          as _LastChangedByUser             on  $projection.LastChangedByUser           = _LastChangedByUser.UserID
  association [0..1] to I_Language                      as _Language                      on  $projection.Language                    = _Language.Language
  association [0..1] to I_ProcurementBlock              as _ProcurementBlock              on  $projection.ProcurementBlock            = _ProcurementBlock.ProcurementBlock
  association [0..1] to I_ProcurementBlock              as _SupplierProcurementBlock      on  $projection.supplierprocurementblock    = _SupplierProcurementBlock.ProcurementBlock
  association [0..1] to I_QualityManagementSystem       as _QualityManagementSystem       on  $projection.QualityManagementSystem     = _QualityManagementSystem.QualityManagementSystem
  association [0..1] to I_QualityManagementSystem       as _SuplrQltyMgmtSystem           on  $projection.suplrqualitymanagementsystem = _SuplrQltyMgmtSystem.QualityManagementSystem
  association [0..1] to I_InspectionLotType             as _InspectionLotType             on  $projection.InspectionLotType           = _InspectionLotType.InspectionLotType
  association [0..1] to I_InspectionLot                 as _QltyInProcmtCurInspLot        on  $projection.QltyInProcmtCurInspLot      = _QltyInProcmtCurInspLot.InspectionLot
  association [0..1] to I_InspectionLot                 as _QltyInProcmtNextInspLot       on  $projection.QltyInProcmtNextInspLot     = _QltyInProcmtNextInspLot.InspectionLot
  association [0..1] to I_ControllingObject             as _ControllingObject             on  $projection.ControllingObject           = _ControllingObject.ControllingObject
  association [0..1] to I_QltyInProcmtInspControl       as _QltyInProcmtInspControl       on  $projection.QltyInProcmtInspControl     = _QltyInProcmtInspControl.QltyInProcmtInspControl
  association [0..1] to I_QltyInProcmtCertificateCtrl   as _QltyInProcmtCertificateCtrl   on  $projection.QltyInProcmtCertificateCtrl = _QltyInProcmtCertificateCtrl.QltyInProcmtCertificateCtrl
  association [0..*] to I_QltyFirstArticleInsp          as _QltyFirstArticleInsp          on  $projection.Material                    = _QltyFirstArticleInsp.Material
                                                                                         and  $projection.QltyInProcmtIntID           = _QltyFirstArticleInsp.QltyInProcmtIntID
  //Extension

  association [1..1] to E_QualityInProcurement          as _Extension                     on  $projection.Material = _Extension.Material
                                                                                          and $projection.QltyInProcmtIntID = _Extension.QltyInProcmtIntID
{
  @ObjectModel.foreignKey.association: '_Material'
  key qinf.matnr            as Material,
  key cast(qinf.zaehl as vdm_qm_qltyinprocmtintid preserving type ) as QltyInProcmtIntID,
  
  @ObjectModel.foreignKey.association: '_Supplier'
  qinf.lieferant        as Supplier,
  @ObjectModel.foreignKey.association: '_Plant'
  qinf.werk             as Plant,
  cast( qinf.revlv as qrevlv preserving type ) as MaterialRevisionLevel,

  //@Semantics.businessDate.to: true

  qinf.frei_dat         as QltyInProcmtReleaseValidTo,
  cast( qinf.frei_mgkz as vdm_qfreimgkz preserving type )        as QltyInProcmtRelQtyIsActive,
  @Semantics.unitOfMeasure:true
  qinf.me               as BaseUnit,
  @Semantics.quantity.unitOfMeasure: 'BaseUnit'
  @DefaultAggregation:#NONE
  qinf.frei_mng         as ReleasedQuantity,
  @Semantics.quantity.unitOfMeasure: 'BaseUnit'
  @DefaultAggregation:#NONE
  qinf.best_mg          as OrderedQuantity,
  @Semantics.businessDate.at: true
  qinf.dat_rueck        as QltyInProcmtResetOnDate,
  @Semantics.text: true
  qinf.sperrgrund       as BlockReason,
  @ObjectModel.foreignKey.association: '_ProcurementBlock'
  qinf.sperrfkt         as ProcurementBlock,
  @ObjectModel.foreignKey.association: '_QualityManagementSystem'
  qinf.qssysfam         as QualityManagementSystem,
  qinf.qssysdat         as QltyInProcmtCertfnValidTo,
  @ObjectModel.foreignKey.association: '_SupplierProcurementBlock'
  _Supplier.SupplierProcurementBlock,
  @ObjectModel.foreignKey.association: '_SuplrQltyMgmtSystem'
  _Supplier.SuplrQualityManagementSystem,
  _Supplier.SuplrQltyInProcmtCertfnValidTo,
  @ObjectModel.foreignKey.association: '_QltyInProcmtInspControl'
  qinf.noinsp           as QltyInProcmtInspControl,
  @ObjectModel.foreignKey.association: '_InspectionLotType'
  qinf.variabnahm       as InspectionLotType,
  qinf.ltextkz          as QltyInProcmtHasLongText,
  cast( qinf.noinspabn as vdm_qnoweabn preserving type )        as QltyInProcmtNoFurtherInsp,
  qinf.vorlabn          as QltyInProcmtLotCrtnLeadTime,
  qinf.loekz            as IsDeleted,
  @ObjectModel.foreignKey.association: '_QltyInProcmtCertificateCtrl'
  qinf.certcontrol      as QltyInProcmtCertificateCtrl,
  cast( qinf.qvvorh as vdm_qqsvvorh preserving type )           as QltyInProcmtHasAssuranceAgrmt,
  qinf.plos             as QltyInProcmtCurInspLot,
  qinf.plos2            as QltyInProcmtNextInspLot,
  qinf.ppap_is_required as ProdnPieceApprovalIsRequired,
  qinf.ppap_id          as ProductionPieceApproval,
  qinf.ppap_level       as ProductionPieceApprovalLevel,
  qinf.ppap_status      as ProductionPieceApprovalStatus,
  qinf.stsma            as StatusProfile,
  qinf.objnr            as ControllingObject,

  @Semantics.user.createdBy: true
  qinf.ersteller        as CreatedByUser,
  @Semantics.systemDate.createdAt: true
  qinf.erstelldat       as CreationDate,
  @Semantics.user.lastChangedBy: true
  qinf.aenderer         as LastChangedByUser,
  @Semantics.systemDate.lastChangedAt: true
  qinf.aenderdat        as LastChangeDate,
  case qinf.changeddatetime
    when 0 then cast( '19000101010101' as tzntstmps )
    else qinf.changeddatetime end  as ChangedDateTime,
  //@Semantics.language: true

  qinf.spras            as Language, // or QINF.sprache


  _DocObjKeyForQltyInProcmt.LinkedSAPObjectKey as LinkedSAPObjectKey,
  cast( 'Q01' as qdokart preserving type ) as DocumentInfoRecordDocType,

  /*Assosiations*/
  _Material,
  _ProductPlantQtManagement,
  _Plant,
  _Supplier,
  _UnitOfMeasure,
  _ProcurementBlock,
  _SupplierProcurementBlock,
  _QualityManagementSystem,
  _SuplrQltyMgmtSystem,
  _ControllingObject,
  _QltyInProcmtInspControl,
  _QltyInProcmtCertificateCtrl,
  _QltyFirstArticleInsp,
  _InspectionLotType,
  _QltyInProcmtCurInspLot,
  _QltyInProcmtNextInspLot,
  _StatusProfile,
  _CreatedByUser,
  _LastChangedByUser,
  _Language
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_SUPPLIER",
"P_DOCOBJKEYFORQLTYINPROCMT",
"QINF"
],
"ASSOCIATED":
[
"E_QUALITYINPROCUREMENT",
"I_CONTROLLINGOBJECT",
"I_INSPECTIONLOT",
"I_INSPECTIONLOTTYPE",
"I_LANGUAGE",
"I_MATERIAL",
"I_PLANT",
"I_PROCUREMENTBLOCK",
"I_PRODUCTPLANTQTMANAGEMENT",
"I_QLTYFIRSTARTICLEINSP",
"I_QLTYINPROCMTCERTIFICATECTRL",
"I_QLTYINPROCMTINSPCONTROL",
"I_QUALITYMANAGEMENTSYSTEM",
"I_STATUSPROFILE",
"I_SUPPLIER",
"I_UNITOFMEASURE",
"I_USER"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/