I_QltyTaskArchivingStatusText

@AbapCatalog.sqlViewName: 'IQLTYTSKASTATTXT'
@AbapCatalog.compiler.compareFilter: true

@AccessControl.authorizationCheck: #NOT_REQUIRED
@AccessControl.personalData.blocking: #NOT_REQUIRED

@VDM.viewType: #BASIC

@EndUserText.label: 'Quality Task Archiving Status Text'
@ClientHandling.algorithm: #SESSION_VARIABLE

@ObjectModel: {
    dataCategory: #TEXT,
    usageType: {
        dataClass: #ORGANIZATIONAL,
        sizeCategory: #S,
        serviceQuality: #A
    },
    representativeKey: 'QualityTaskArchivingStatus'
}

define view I_QltyTaskArchivingStatusText as select from dd07t
//=== Assocation to common views

    association [0..1] to I_Language                as _Language                on $projection.Language = _Language.Language

//=== Assocation to QM specific views    

    association [0..1] to I_QltyTaskArchivingStatus as _QltyTaskArchivingStatus on $projection.QualityTaskArchivingStatus = _QltyTaskArchivingStatus.QualityTaskArchivingStatus

{
//=== Key Fields

    key cast(substring(domvalue_l, 1, 2) as qtskacyclestat preserving type) as QualityTaskArchivingStatus,
        @ObjectModel.foreignKey.association: '_Language'
        @Semantics.language: true
    key ddlanguage as Language,
   
//=== Common Fields 

        @Semantics.text: true
        cast(substring(dd07t.ddtext, 1, 40) as qtskacyclestattxt preserving type) as QualityTaskArchivingStatusText,
    
//=== Expose Associations

        _QltyTaskArchivingStatus,
        _Language
      
} where dd07t.domname = 'QTSKACYCLESTAT' and dd07t.as4local = 'A'
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"DD07T"
],
"ASSOCIATED":
[
"I_LANGUAGE",
"I_QLTYTASKARCHIVINGSTATUS"
],
"BASE":
[],
"ANNO_REF":
[],
"VERSION":0
}
}*/