I_PurgDeliveryAddressTypeText

@AccessControl.authorizationCheck: #NOT_REQUIRED
@Analytics.dataExtraction.enabled: true
@EndUserText.label: 'Purchasing Delivery Address Type - Text'
@Metadata.ignorePropagatedAnnotations: true
@Analytics.internalName: #LOCAL
@Analytics.technicalName: 'IPURDELADDRTYPET'
@ObjectModel.dataCategory: #TEXT
@ObjectModel.modelingPattern: #LANGUAGE_DEPENDENT_TEXT
@ObjectModel.representativeKey: 'PurchasingDeliveryAddressType'
@ObjectModel.supportedCapabilities: [#CDS_MODELING_ASSOCIATION_TARGET, 
                                     #CDS_MODELING_DATA_SOURCE,
                                     #EXTRACTION_DATA_SOURCE,
                                     #LANGUAGE_DEPENDENT_TEXT,
                                     #SEARCHABLE_ENTITY,
                                     #SQL_DATA_SOURCE]
@ObjectModel.usageType.serviceQuality: #A
@ObjectModel.usageType.dataClass: #META
@ObjectModel.usageType.sizeCategory: #S
@Search.searchable: true
@VDM.lifecycle.contract.type: #PUBLIC_LOCAL_API
@VDM.viewType: #BASIC
define view entity I_PurgDeliveryAddressTypeText
  as select from dd07t 
  association to parent I_PurgDeliveryAddressType as _PurgDeliveryAddressType
    on $projection.PurchasingDeliveryAddressType = _PurgDeliveryAddressType.PurchasingDeliveryAddressType
  association [0..1] to I_Language as _Language      
    on $projection.Language = _Language.Language
{
      @ObjectModel.foreignKey.association: '_Language'
      @Semantics.language: true
  key cast( dd07t.ddlanguage as spras preserving type ) as Language, 
      @ObjectModel.foreignKey.association: '_PurgDeliveryAddressType'
      @ObjectModel.text.element: ['PurgDeliveryAddressTypeName']
  key cast( dd07t.domvalue_l as purdeliveryaddrtype ) as PurchasingDeliveryAddressType,
      @Analytics.hidden: true
      @Consumption.hidden: true
      dd07t.domvalue_l as DomainValue,
      @Search.defaultSearchElement: true
      @Search.fuzzinessThreshold: 0.8
      @Search.ranking: #LOW
      @Semantics.text: true
      cast( dd07t.ddtext as purgdeliveryaddrtypet preserving type ) as PurgDeliveryAddressTypeName,
      _PurgDeliveryAddressType,
      _Language
} 
where dd07t.domname  = 'PURDELIVERYADDRTYPE_D'
  and dd07t.as4local = 'A'
  and dd07t.as4vers  = '0000'
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"DD07T"
],
"ASSOCIATED":
[
"I_LANGUAGE",
"I_PURGDELIVERYADDRESSTYPE"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/