@ClientHandling.algorithm: #SESSION_VARIABLE //Inserted by VDM CDS Suite Plugin
@ObjectModel.usageType.dataClass: #MIXED
@ObjectModel.usageType.serviceQuality: #D
@ObjectModel.usageType.sizeCategory: #S
@EndUserText.label: 'SOFM Purchase Order Item Purchasing Issue'
@VDM.viewType: #COMPOSITE
@AccessControl.authorizationCheck: #CHECK
@AbapCatalog.preserveKey: true
@AbapCatalog.sqlViewName: 'IPURORDITMSU01'
define view I_PurchaseOrderItemPurgIssue
with parameters
@Consumption.hidden: true
@Environment.systemField: #SYSTEM_DATE
P_ReferenceDate : sydate
as select from I_SalesOrderInSupplyPurgIssue as ISSUE_SU01 --(P_ReferenceDate: $parameters.P_ReferenceDate) as ISSUE_SU01
inner join I_PurchasingDocumentItem as POI
on ISSUE_SU01.PurchasingDocument = POI.PurchasingDocument
and ISSUE_SU01.PurchasingDocumentItem = POI.PurchasingDocumentItem
and POI.IsEndOfPurposeBlocked = '' -- AT20.11.2017 Mitigation Removal DPP filter in PurchasingDocument Views
inner join I_SalesDocumentItem as SOI
on ISSUE_SU01.SalesOrder = SOI.SalesDocument
and ISSUE_SU01.SalesOrderItem = SOI.SalesDocumentItem
left outer to one join I_PurgDocSupplierConfirmation as PO_CO
on POI.PurchasingDocument = PO_CO.PurchasingDocument
and POI.PurchasingDocumentItem = PO_CO.PurchasingDocumentItem
--and PO_CO._PurchasingDocument.IsEndOfPurposeBlocked = '' -- AT20.11.2017 Mitigation: not possible here, but also not needed ! Filter above should be sufficient !
{
// Key
key POI.PurchasingDocument,
key POI.PurchasingDocumentItem,
//DueDays
@DefaultAggregation: #MIN
ISSUE_SU01.DueDays,
@DefaultAggregation: #MIN
ISSUE_SU01.DueDate,
// Sales Order
ISSUE_SU01.SalesOrder,
ISSUE_SU01.SalesOrderItem,
// Category Sales Order
SOI._SalesDocument.SalesDocumentType as SalesOrderType,
@ObjectModel.foreignKey.association: '_ItemCategory'
SOI.SalesDocumentItemCategory as SalesOrderItemCategory,
_ItemCategory,
// Organization Sales Order
SOI._SalesDocument.SalesOrganization,
SOI._SalesDocument.DistributionChannel,
SOI._SalesDocument.OrganizationDivision,
// Quantity Sales Order Item
@DefaultAggregation: #SUM
@Semantics.quantity.unitOfMeasure: 'OrderQuantityUnit'
SOI.OrderQuantity,
@Semantics.unitOfMeasure: true
@ObjectModel.foreignKey.association: '_OrderQuantityUnit'
SOI.OrderQuantityUnit,
// Pricing Sales Order Item
@DefaultAggregation: #SUM
@Semantics.amount.currencyCode: 'TransactionCurrency'
SOI.NetAmount,
@Semantics.currencyCode: true
@ObjectModel.foreignKey.association: '_TransactionCurrency'
SOI.TransactionCurrency,
// Text Purchasing Order Item
POI.PurchasingDocumentItemText,
// Product Purchasing Order Item
POI.Material,
@ObjectModel.text.element: [ 'PlantName' ]
POI.Plant,
@Semantics.text: true
POI._Plant.PlantName,
// Quantity Purchasing Order Item
@DefaultAggregation:#SUM
@Semantics.quantity.unitOfMeasure: 'PurgDocOrderQuantityUnit'
POI.OrderQuantity as PurchasingDocumentOrderQty,
@Semantics.unitOfMeasure: true
POI.OrderQuantityUnit as PurgDocOrderQuantityUnit,
// Status Purchasing Order Item
POI.IsCompletelyDelivered,
POI.IsFinallyInvoiced,
case when (POI.SupplierConfirmationControlKey != '' and PO_CO.SequentialNmbrOfSuplrConf is null )
then 'X' else ''
end as SuplrConfIsPending,
// Date
ISSUE_SU01.DeliveryDate,
SOI._TransactionCurrency,
SOI._OrderQuantityUnit
}
where POI.PurchasingDocumentCategory = #BSTYP.'F'
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_PLANT",
"I_PURCHASINGDOCUMENTITEM",
"I_PURGDOCSUPPLIERCONFIRMATION",
"I_SALESDOCUMENT",
"I_SALESDOCUMENTITEM",
"I_SALESORDERINSUPPLYPURGISSUE"
],
"ASSOCIATED":
[
"I_CURRENCY",
"I_SALESDOCUMENTITEMCATEGORY",
"I_UNITOFMEASURE"
],
"BASE":
[
"I_SALESDOCUMENTITEM"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/