I_PurchaseConfirmationStatusT

@ClientHandling.algorithm: #SESSION_VARIABLE 
@ObjectModel.dataCategory: #TEXT
@ObjectModel.representativeKey: 'PurchaseConfirmationStatus'
@ObjectModel.usageType.dataClass: #META 
@ObjectModel.usageType.serviceQuality: #A 
@ObjectModel.usageType.sizeCategory: #S 
@ObjectModel.supportedCapabilities: [ #LANGUAGE_DEPENDENT_TEXT, #CDS_MODELING_ASSOCIATION_TARGET, #SQL_DATA_SOURCE, 
                                      #CDS_MODELING_DATA_SOURCE, #SEARCHABLE_ENTITY]
@ObjectModel.modelingPattern: [ #LANGUAGE_DEPENDENT_TEXT ]
@EndUserText.label: 'Purchase Confirmation Status - Text'
@VDM.viewType: #BASIC
@AccessControl.authorizationCheck:#NOT_REQUIRED
@AbapCatalog.sqlViewName: 'ISDPURCONFSTST'
@Metadata.ignorePropagatedAnnotations:true
@Search.searchable: true

define view I_PurchaseConfirmationStatusT  
as select from dd07t 

association[0..1] to I_PurchaseConfirmationStatus as _PurchaseConfirmationStatus on $projection.PurchaseConfirmationStatus = _PurchaseConfirmationStatus.PurchaseConfirmationStatus
association[0..1] to I_Language as _Language on $projection.Language = _Language.Language
{
    @ObjectModel.foreignKey.association: '_PurchaseConfirmationStatus'
    key SUBSTRING(dd07t.domvalue_l, 1, 1) as PurchaseConfirmationStatus,
    
    @Semantics.language: true
    @ObjectModel.foreignKey.association: '_Language'
    key ddlanguage as Language,
    
    @Semantics.text: true
    @Search.defaultSearchElement: true
    @Search.fuzzinessThreshold: 0.9    
    ddtext as PurchaseConfirmationStatusDesc,
    
    //Associations

    _PurchaseConfirmationStatus,
    _Language        
}
where (dd07t.domname = 'COSTA') and (dd07t.as4local = 'A');
   
 /*+[internal] {
"BASEINFO":
{
"FROM":
[
"DD07T"
],
"ASSOCIATED":
[
"I_LANGUAGE",
"I_PURCHASECONFIRMATIONSTATUS"
],
"BASE":
[],
"ANNO_REF":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/