I_PurReqnExtApprovalStsText_2

@AbapCatalog.sqlViewName: 'IPREAPPRSTST2'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #NOT_REQUIRED
@Analytics.dataExtraction.enabled: true
@ClientHandling.algorithm: #SESSION_VARIABLE
@EndUserText.label: 'Purchase Req Ext Approval Status - Text'
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.dataCategory: #TEXT
@ObjectModel.representativeKey: 'ExternalApprovalStatus'
@ObjectModel.usageType.serviceQuality: #A
@ObjectModel.usageType.dataClass: #META
@ObjectModel.usageType.sizeCategory: #S
@Search.searchable: true
@VDM.lifecycle.contract.type: #PUBLIC_LOCAL_API
@VDM.viewType: #BASIC
define view I_PurReqnExtApprovalStsText_2
  as select from dd07t 
  association to parent I_PurReqnExtApprovalStatus as _PurReqnExtApprovalStatus
    on $projection.ExternalApprovalStatus = _PurReqnExtApprovalStatus.ExternalApprovalStatus
  association [0..1] to I_Language as _Language      
    on $projection.Language = _Language.Language
{
      @ObjectModel.foreignKey.association: '_Language'
      @Semantics.language: true
  key cast( dd07t.ddlanguage as spras preserving type ) as Language, 
      @ObjectModel.foreignKey.association: '_PurReqnExtApprovalStatus'
      @ObjectModel.text.element: ['ExternalApprovalStatus']
  key cast( dd07t.domvalue_l as mmpur_req_extapprvlsts ) as ExternalApprovalStatus,
      @Analytics.hidden: true
      @Consumption.hidden: true
      dd07t.domvalue_l as DomainValue,
      @Search.defaultSearchElement: true
      @Search.fuzzinessThreshold: 0.8
      @Search.ranking: #HIGH
      @Semantics.text: true
      dd07t.ddtext  as ExternalApprovalStatusText,
      _PurReqnExtApprovalStatus,
      _Language
} 
where dd07t.domname  = 'MMPUR_REQ_EXTAPPRVLSTS'
  and dd07t.as4local = 'A'
  and dd07t.as4vers  = '0000'
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"DD07T"
],
"ASSOCIATED":
[
"I_LANGUAGE",
"I_PURREQNEXTAPPROVALSTATUS"
],
"BASE":
[],
"ANNO_REF":
[],
"VERSION":0
}
}*/