I_PurContrCriticalityStatus

@AbapCatalog.sqlViewName: 'IMMPCTRCRTCLTSTS'
@AbapCatalog.preserveKey: true
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #NOT_REQUIRED
@EndUserText.label: 'Purchsae Contract Criticality Status'
@ClientHandling.algorithm: #SESSION_VARIABLE
@VDM.viewType: #BASIC
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #L
@ObjectModel.resultSet.sizeCategory: #XS
@ObjectModel.usageType.dataClass: #TRANSACTIONAL
@ObjectModel.semanticKey:['PurContrCriticalityStatus']
@ObjectModel.representativeKey: 'PurContrCriticalityStatus'
@Search.searchable: true

define view I_PurContrCriticalityStatus 
as select from dd07t
  association [0..1] to I_Language  as _Language  on $projection.Language = _Language.Language
{
      @ObjectModel.foreignKey.association: '_Language'
      @Semantics.language: true
  key cast( dd07t.ddlanguage as spras preserving type )                      as Language, 
      @ObjectModel.text.element: ['PurContrCriticalityStatusText']
  key cast(dd07t.domvalue_l  as mm_pur_ctr_criticality_status )              as PurContrCriticalityStatus, 
  
      cast (case domvalue_l
        when '1' then 0  
        when '2' then 1  
        when '3' then 2  
                 else 3  
      end                  as int2 )                                         as StatusCriticality,
      @Consumption.hidden: true
      dd07t.domvalue_l                                                       as DomainValue,
      @Search.defaultSearchElement: true
      @Search.fuzzinessThreshold: 0.8
      @Search.ranking: #HIGH
      @Semantics.text: true
      cast( dd07t.ddtext as val_text preserving type )                       as PurContrCriticalityStatusText,
      _Language
  
}
where
      dd07t.domname  = 'MM_PUR_CTR_CRITICALITY_STATUS'
  and dd07t.as4local = 'A'
  and dd07t.as4vers  = '0000'
  and dd07t.ddlanguage = $session.system_language
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"DD07T"
],
"ASSOCIATED":
[
"I_LANGUAGE"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/