I_ProviderContractItem

@AbapCatalog: { compiler.compareFilter:true,
                //preserveKey:true,

                sqlViewName: 'IPRVDRCONTRI' }

@AccessControl: { authorizationCheck: #CHECK,
                  personalData.blocking : #REQUIRED }

@ClientHandling.algorithm: #SESSION_VARIABLE

@EndUserText.label: 'Provider Contract Item'

@Metadata.ignorePropagatedAnnotations: true

@ObjectModel: { representativeKey: 'ProviderContractItem',
                supportedCapabilities: [ #CDS_MODELING_ASSOCIATION_TARGET,
                                         #SQL_DATA_SOURCE,
                                         #CDS_MODELING_DATA_SOURCE ],
                usageType: { dataClass: #MASTER,
                             serviceQuality: #C,
                             sizeCategory: #XL } }

@VDM.viewType: #BASIC

define view I_ProviderContractItem
  as select from dfkk_vt_i

  association [1..1] to E_CAProviderContractItem      as _PCoExtension                on  $projection.ProviderContract     = _PCoExtension.CAProviderContract
                                                                                      and $projection.ProviderContractItem = _PCoExtension.CAProviderContractItemNumber
  association [0..1] to I_CABillgPln                  as _BillgPln                    on  $projection.CABillgPlnNumber = _BillgPln.CABillgPlnNumber
  association [0..1] to I_BusinessArea                as _BusinessArea                on  $projection.BusinessArea = _BusinessArea.BusinessArea
  association [0..1] to I_CABillgCycle                as _BillgCycle                  on  $projection.CABillgCycle = _BillgCycle.CABillgCycle
  association [0..1] to I_CADunningMasterDataOrigin   as _CADunningMasterDataOrigin   on  $projection.CAOriginOfDunningMasterData = _CADunningMasterDataOrigin.CAOriginOfDunningMasterData
  association [0..1] to I_CADunningProcedure          as _CADunningProcedure          on  $projection.CADunningProcedure = _CADunningProcedure.CADunningProcedure
  association [0..1] to I_CAInvcgSchedule             as _InvcgSchedule               on  $projection.CAInvcgSchedule = _InvcgSchedule.CAInvcgSchedule
  association [0..1] to I_CAPaymentMasterDataOrigin   as _CAPaymentMasterDataOrigin   on  $projection.CAOriginOfPaymentMasterData = _CAPaymentMasterDataOrigin.CAOriginOfPaymentMasterData
  association [0..1] to I_CAPaymentMethod             as _CAPaymentMethod             on  $projection.CAPaymentMethodForIncgPayment = _CAPaymentMethod.CAPaymentMethod
                                                                                      and $projection.CAReceivingCountry            = _CAPaymentMethod.Country
  association [0..1] to I_CARevnAcctgServiceType      as _CARevnAcctgServiceType      on  $projection.CARevnAcctgRecrrgServiceType = _CARevnAcctgServiceType.CARevenueAccountingServiceType
  association [0..1] to I_CARevnAcctgTransfRecdOrigin as _CARevnAcctgTransfRecdOrigin on  $projection.CARevnAcctgTransfRecordOrigin = _CARevnAcctgTransfRecdOrigin.CARevnAcctgTransfRecordOrigin
  association [1..1] to I_CARatingArea                as _CARatingArea                on  $projection.CARatingArea = _CARatingArea.CARatingArea
  association [1..1] to I_CASubscriptionChargeType    as _CASubscriptionChargeType    on  $projection.CASubscriptionChargeType = _CASubscriptionChargeType.CASubscriptionChargeType
  association [1..1] to I_CompanyCode                 as _CompCode                    on  $projection.CompanyCode = _CompCode.CompanyCode
  association [0..1] to I_CompanyCode                 as _CompCodeSup                 on  $projection.CAIntcoCompanyCodeSupplying = _CompCodeSup.CompanyCode
  association [1..1] to I_ContractAccountHeader       as _ContrAcc                    on  $projection.ContractAccount = _ContrAcc.ContractAccount
  association [0..1] to I_Country                     as _Country                     on  $projection.CAReceivingCountry = _Country.Country
  association [0..1] to I_Division                    as _Division                    on  $projection.Division = _Division.Division
  association [1..1] to I_PaymentCondition            as _PaymentCondition            on  $projection.PaymentCondition = _PaymentCondition.PaymentCondition
  association [1..1] to I_ProviderContract            as _PrvdrContr                  on  $projection.ProviderContract = _PrvdrContr.ProviderContract
  association [1..1] to I_ProviderContractStatus      as _ProviderContractStatus      on  $projection.CAProviderContractStatus = _ProviderContractStatus.CAProviderContractStatus
  association [0..1] to I_PrvdrContrItemChgReason     as _PrvdrContrItemChgReason     on  $projection.CAPrvdrContrItmChgReason = _PrvdrContrItemChgReason.CAPrvdrContrItmChgReason
  association [0..1] to I_Segment                     as _Segment                     on  $projection.Segment = _Segment.Segment

{
      @ObjectModel.foreignKey.association: '_PrvdrContr'
  key vtkey                                                    as ProviderContract,
  key vtpos                                                    as ProviderContractItem,

      //    administration data

      erdat                                                    as CreationDate,
      cast(ertim as ttet_dt_cr_time preserving type )          as CreationTime,
      ernam                                                    as CreatedByUser,
      aedat                                                    as LastChangeDate,
      aetim                                                    as LastChangeTime,
      aenam                                                    as LastChangedByUser,

      //    General data

      vtpid                                                    as CAProviderContractItemUUID,
      papid                                                    as CAPrvdrContrParentItemUUID,
      valfr                                                    as CAPrvdrContrItmValidFromDteTme,
      valto                                                    as CAPrvdrContrItmValidToDateTime,
      cancl                                                    as CAPrvdrContrItemCanclnDateTime,
      @ObjectModel.foreignKey.association: '_ProviderContractStatus'
      status                                                   as CAProviderContractStatus,
      vtitt                                                    as CAProviderContractItemText,
      @ObjectModel.foreignKey.association: '_ContrAcc'
      vkont                                                    as ContractAccount,
      ppacc                                                    as CAPrepaidAccount,
      vttrg                                                    as CATechnicalResourceGroup,
      srvrp                                                    as CAServiceRecipient,
      adrsr                                                    as CAAddressIDOfServiceRecipient,
      prdnr                                                    as CAProduct,
      cuobj                                                    as ProductConfiguration,
      prdnr_sp                                                 as CASalesPackageProduct,
      makey                                                    as CAMasterAgreement,
      maprd                                                    as CAMasterAgreementProduct,
      ptsrl                                                    as CAPartnerSettlementRule,
      vtkrf                                                    as CASharingContract,
      txjcd                                                    as TaxJurisdiction,
      @ObjectModel.foreignKey.association: '_Country'
      landl                                                    as CAReceivingCountry,
      tax_country                                              as TaxCountry,
      @ObjectModel.foreignKey.association: '_CASubscriptionChargeType'
      charge_type                                              as CASubscriptionChargeType,

      solution_order_id                                        as BusinessSolutionOrder,
      solution_order_item_id                                   as BusinessSolutionOrderItem,
      matnr_copa                                               as SoldProduct,
      @API.element: {
        successor: 'EBRRResultAnalysisInternalID',
        releaseState: #DEPRECATED }
      @VDM.lifecycle: {
        status: #DEPRECATED,
        successor: 'EBRRResultAnalysisInternalID' }
      rev_rec_key                                              as RevenueRecognitionKey,
      rev_rec_key                                              as EBRRResultAnalysisInternalID,

      bundling                                                 as EBRRIsBundleActive,

      @Semantics.quantity.unitOfMeasure: 'CAProviderContractQuantityUnit'
      quantity                                                 as CAProviderContractQuantity,
      @Semantics.unitOfMeasure: true
      quantity_unit                                            as CAProviderContractQuantityUnit,

      //    General data 2 (Utility Fields)

      uti_dso_bp                                               as DistrSystOperatorBP,
      uti_dso_maco_id                                          as DistrSystOperatorMarketCommID,
      uti_metop_bp                                             as MeterOperatorBusinessPartner,
      uti_metop_maco_id                                        as MeterOperatorMarketCommID,
      uti_malo_id                                              as MarketLocationIdentifier,

      //    Organizational data

      vkorg                                                    as SalesOrganization,
      vtweg                                                    as DistributionChannel,
      @ObjectModel.foreignKey.association: '_CompCode'
      bukrs                                                    as CompanyCode,
      @ObjectModel.foreignKey.association: '_CompCodeSup'
      ico_bukrs_sup                                            as CAIntcoCompanyCodeSupplying,
      @ObjectModel.foreignKey.association: '_BusinessArea'
      gsber                                                    as BusinessArea,
      @ObjectModel.foreignKey.association: '_Segment'
      segmt                                                    as Segment,
      //      @ObjectModel.foreignKey.association: '_ProfitCenter'

      prctr                                                    as ProfitCenter,
      @ObjectModel.foreignKey.association: '_Division'
      spart                                                    as Division,
      vber1                                                    as CAPrvdrContrSalesAreaAttrib1,
      vber2                                                    as CAPrvdrContrSalesAreaAttrib2,
      //ps_psp_pnr                                                    as WBSElementInternalID,  //has conversion exit, not allowed anymore

      cast( ps_psp_pnr as fis_wbsint_no_conv preserving type ) as WBSElementInternalID,
      aufnr                                                    as InternalOrder,
      stdsp                                                    as CAStandardDivision,
      @Semantics.booleanIndicator                                               
      x_vt_copa                                                as PrvdrContrItmIsRlvtForPrfSgDrv,

      //    Billing and Ivoicing data

      @ObjectModel.foreignKey.association: '_BillgCycle'
      cycle                                                    as CABillgCycle,
      cycle_day                                                as CALastDayOfBillingPeriod,
      cycle_date                                               as CABillgCyclePeriodStartDate,
      @ObjectModel.foreignKey.association: '_InvcgSchedule'
      inv_schedule                                             as CAInvcgSchedule,
      @ObjectModel.foreignKey.association: '_CARatingArea'
      rating_area                                              as CARatingArea,
      @ObjectModel.foreignKey.association: '_BillgPln'
      billplanno                                               as CABillgPlnNumber,
      //    Consumption Billing

      cb_soldto                                                as CAConsumptionBillgSoldToParty,
      cb_billto                                                as CAConsumptionBillgInvoiceRcpnt,
      cb_dzterm                                                as ConsumptionBillingPaymentTerms,
      cb_bemot                                                 as CnsmpnBillgBillableControl,
      //cb_dzterm                                                     as PaymentTerms,

      //cb_bemot                                                      as BillableControl,

      cb_mndid                                                 as ConsumptionBillingSEPAMandate,
      cb_ccard_id                                              as CAConsumptionBillgPaymentCard,
      //cb_ccard_id                                                   as CAPaymentCard,



      //    Revenue Accounting data

      @Semantics.booleanIndicator
      rarel                                                    as CAIsRevenueAccountingRelevant,
      ra_mig_package                                           as CARevenueAcctgMigrationPackage,
      @VDM.lifecycle.status: #DEPRECATED
      @VDM.lifecycle.successor: 'CARevenueAccountingRefType'
      ra_reftype                                               as RevenueAccountingRefType,
      ra_reftype                                               as CARevenueAccountingRefType,
      ra_refid                                                 as RevenueAccountingReference,
      ra_srcdoc_id                                             as CARevenueAcctgDocumentItem,
      @Semantics.currencyCode: true
      trprc_curr                                               as TransactionPriceCurrency,
      @Semantics.amount.currencyCode: 'TransactionPriceCurrency'
      trprc                                                    as TransactionPrice,
      @Semantics.amount.currencyCode: 'TransactionPriceCurrency'
      trprc_total                                              as TotalTransactionPrice,
      trprc_freq_unit                                          as TransacPriceRcrrcPerdTimeUnit,
      //      @Semantics.quantity.unitOfMeasure: 'TransacPriceRcrrcPerdTimeUnit'

      trprc_freq_duration                                      as TransacPriceRcrrcPerdDuration,
      @Semantics.currencyCode: true
      ssprc_curr                                               as StandAloneSellingPriceCurrency,
      @Semantics.amount.currencyCode: 'StandAloneSellingPriceCurrency'
      ssprc                                                    as StandAloneSellingPrice,
      @Semantics.amount.currencyCode: 'StandAloneSellingPriceCurrency'
      ssprc_total                                              as TotalStandAloneSellingPrice,
      ssprc_freq_unit                                          as SSPriceRecurrencePerdTimeUnit,
      //      @Semantics.quantity.unitOfMeasure: 'SSPriceRecurrencePerdTimeUnit'

      ssprc_freq_duration                                      as SSPriceRecurrencePerdDuration,
      @ObjectModel.foreignKey.association: '_PrvdrContrItemChgReason'
      chrsn                                                    as CAPrvdrContrItmChgReason,
      valfrom_ctrterm                                          as CAStartOfDurationDateTime,
      valto_ctrterm                                            as CAEndOfDurationDateTime,
      @ObjectModel.foreignKey.association: '_CARevnAcctgServiceType'
      recurr_service_type                                      as CARevnAcctgRecrrgServiceType,
      @ObjectModel.foreignKey.association: '_CARevnAcctgTransfRecdOrigin'
      ra_oi_orig                                               as CARevnAcctgTransfRecordOrigin,

      //   Payment Data

      @ObjectModel.foreignKey.association: '_CAPaymentMasterDataOrigin'
      pay_par_active                                           as CAOriginOfPaymentMasterData,
      @ObjectModel.foreignKey.association: '_PaymentCondition'
      zahlkond                                                 as PaymentCondition,
      @ObjectModel.foreignKey.association: '_CAPaymentMethod'
      ezawe                                                    as CAPaymentMethodForIncgPayment,
      abwre                                                    as CAAlternativePayer,
      adrre                                                    as CAAddressIDOfAlternativePayer,
      ebvty                                                    as CABankIDForIncomingPayments,
      mndid                                                    as SEPAMandate,
      ccard_id                                                 as CAPaymentCardIDForIncomingPayt,
      azawe                                                    as CAPaymentMethodForOutgPayment,
      abwra                                                    as CAAlternativePayee,
      adrra                                                    as CAAddressIDOfAlternativePayee,
      abvty                                                    as CABankIDForOutgoingPayments,
      ccard_out                                                as CAPaymentCardIDForOutgoingPayt,


      //    Dunning Data

      @ObjectModel.foreignKey.association: '_CADunningMasterDataOrigin'
      dunn_par_active                                          as CAOriginOfDunningMasterData,
      @ObjectModel.foreignKey.association: '_CADunningProcedure'
      mahnv                                                    as CADunningProcedure,
      xdiscoexempt                                             as CAServiceDisconncnIsProhibited,

      //    PEPPOL

      bstkd                                                    as PurchaseOrderByCustomer,
      bstdk                                                    as CustomerPurchaseOrderDate,

      // Associations

      _BillgCycle,
      _BillgPln,
      _BusinessArea,
      _CADunningMasterDataOrigin,
      _CADunningProcedure,
      _CARatingArea,
      _CAPaymentMasterDataOrigin,
      _CARevnAcctgServiceType,
      _CARevnAcctgTransfRecdOrigin,
      _CASubscriptionChargeType,
      _ContrAcc,
      _CompCode,
      _CompCodeSup,
      _Country,
      _Division,
      _InvcgSchedule,
      _PaymentCondition,
      _CAPaymentMethod,
      _ProviderContractStatus,
      _PrvdrContr,
      _PrvdrContrItemChgReason,
      _Segment
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"DFKK_VT_I"
],
"ASSOCIATED":
[
"E_CAPROVIDERCONTRACTITEM",
"I_BUSINESSAREA",
"I_CABILLGCYCLE",
"I_CABILLGPLN",
"I_CADUNNINGMASTERDATAORIGIN",
"I_CADUNNINGPROCEDURE",
"I_CAINVCGSCHEDULE",
"I_CAPAYMENTMASTERDATAORIGIN",
"I_CAPAYMENTMETHOD",
"I_CARATINGAREA",
"I_CAREVNACCTGSERVICETYPE",
"I_CAREVNACCTGTRANSFRECDORIGIN",
"I_CASUBSCRIPTIONCHARGETYPE",
"I_COMPANYCODE",
"I_CONTRACTACCOUNTHEADER",
"I_COUNTRY",
"I_DIVISION",
"I_PAYMENTCONDITION",
"I_PROVIDERCONTRACT",
"I_PROVIDERCONTRACTSTATUS",
"I_PRVDRCONTRITEMCHGREASON",
"I_SEGMENT"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/